DataMuseum.dk

top - download

    Length: 1536 (0x600)
    Types: TextFile
    Names: »HURKLE.BAS«

└─⟦69a509965⟧ Bits:30005211 CR8 BASIC Games
    └─ ⟦this⟧ »HURKLE.BAS« 

TextFile

1  REM PROGRAM HURKLE.BAS
10 REM *** CONVERTED TO RSTS/E BY DAVID AHL, DIGITAL
20 REM HURKLE - PEOPLE'S COMPUTER COMPANY, MENLO PARK CA
30 RANDOMIZE
40 N=5
50 G=10
60 PRINT 
70 PRINT "A HURKLE IS HIDING ON A";G;"BY";G;"GRID. HOMEBASE"
80 PRINT "ON THE GRID IS POINT	0,0  AND ANY GRIDPOINT IS A"
90 PRINT "PAIR OF WHOLE NUMBERS SEPARATED BY A COMMA. TRY TO"
100 PRINT "GUESS THE HURKLE'S GRIDPOINT. YOU GET";N;"TRIES."
110 PRINT "AFTER EACH TRY, I WILL TELL YOU THE APPROXIMATE"
120 PRINT "DIRECTION TO GO TO LOOK FOR THE HURKLE."
130 PRINT 
140 A=INT(G*RND)
150 B=INT(G*RND)
160 FOR K=1 TO N
170 PRINT "GUESS #";K;
180 INPUT X,Y
190 IF ABS(X-A)+ABS(Y-B)=0 THEN 360 
200 REM PRINT INFO 
210 GOSUB 410 
220 PRINT 
230 NEXT K
240 PRINT 
250 PRINT "SORRY, THAT'S";N;"GUESSES."
260 PRINT "THE HURKLE IS AT ";A;",";B
270 PRINT 
280 PRINT "WOULD YOU LIKE TO PLAY AGAIN"
290 INPUT Q$
300 IF Q$="YES" THEN 330
310 GOTO 540
320 PRINT
330 PRINT "THE HURKLE IS HIDING"
340 PRINT 
350 GOTO 140 
360 REM 
370 PRINT 
380 PRINT "YOU FOUND HIM IN";K;"GUESSES!"
390 FOR I=1 TO 10:PRINT CHR$(7);:NEXT I:PRINT 
400 GOTO 270 
410 PRINT "GO ";
420 IF Y=B THEN 470 
430 IF Y<B THEN 460 
440 PRINT "SOUTH";
450 GOTO 470 
460 PRINT "NORTH";
470 IF X=A THEN 520 
480 IF X<A THEN 510 
490 PRINT "WEST";
500 GOTO 520 
510 PRINT "EAST";
520 PRINT 
530 RETURN
540 PRINT "GAME FINISHED"
550 PRINT
560 PRINT "BYE"
570 RUN "MENU"
600 END
«eof»