DataMuseum.dk

top - download

    Length: 1664 (0x680)
    Types: TextFile
    Names: »MMIND.BAS«

└─⟦016ef1d53⟧ Bits:30005210 BASIC Demo
    └─ ⟦this⟧ »MMIND.BAS« 

TextFile

10 REM GAME OF MASTERMIND
20 REM
25 RANDOMIZE
30 INPUT "INSTRUCTIONS? (YES OR NO)";A$
40 IF LEFT$(A$,1)<>"Y" THEN 1000
50 PRINT "THIS IS THE GAME OF MASTERMIND"
60 PRINT
70 PRINT "THE COMPUTER WILL CHOSE A FIVE DIGIT NUMBER. YOUR JOB
80 PRINT "IS TO GUESS WHAT THAT NUMBER IS. YOU DO THAT BY SUPPLYING
90 PRINT "A FIVE DIGIT GUESS NUMBER. THE COMPUTER WILL RESPOND BY
100 PRINT "TELLING YOU HOW MANY DIGITS OF YOUR GUESS NUMBER MATCH
110 PRINT "THE CHOSEN NUMBER AND ARE IN THE CORRECT POSITION. IT
120 PRINT "WILL ALSO TELL YOU HOW MANY NUMBERS MATCH BUT ARE IN THE
130 PRINT "INCORRECT COLUMN.
135 PRINT
140 PRINT "GOOD LUCK"
1000 PRINT
1010 PRINT
1015 MOVE=0
1020 FOR I=1 TO 5
1030	ANS$(I)=CHR$(RND*10+47.5)
1040	NEXT
1050 INPUT "GUESS";G$
1055 MOVE=MOVE+1
1060 IF LEN(G$)>5 THEN PRINT "NUMBER TOO BIG" : GOTO 1050
1070 IF LEN(G$)<5 THEN PRINT "NUMBER TOO SMALL": GOTO 1050
1080 NM=0
1090 FOR I=1 TO 5
1100	IF MID$(G$,I,1)=ANS$(I) THEN NM=NM+1 :
		GG$(I)="X"
		ELSE GG$(I)=MID$(G$,I,1)
1110	NEXT
1120 IF NM=5 THEN GOTO 2000
1125 NN=0
1130 FOR I=1 TO 5
1135	IF GG$(I)="X" THEN 1165
1140	FOR J=1 TO 5
1150		IF ANS$(I)=GG$     (J) THEN NN=NN+1
		: GG$(J)="Y"
		:GOTO 1165
1160	NEXT J
1165    NEXT I
1170 PRINT NM;"MATCH AND";NN;"OTHERS ARE CORRECT FOR  ";G$
1180 GOTO 1050
2000 PRINT "CORRECT IN ";MOVE;" MOVES"
2005 PRINT
2010 IF MOVE<9 THEN PRINT "YOU ARE A MASTERMIND!" 
	ELSE IF MOVE<11 THEN PRINT "ABOUT AVERAGE - TRY HARDER"
	ELSE PRINT "NOT TOO GOOD"
2020 PRINT: INPUT "TRY AGAIN? (YES OR NO)";A$
2030 IF MID$(A$,1,1)="Y" THEN 1015
2040 PRINT "BYE"
2050 RUN "MENU"