DataMuseum.dk

top - download

    Length: 2176 (0x880)
    Types: TextFile
    Names: »HAMURS.BAS«

└─⟦69a509965⟧ Bits:30005211 CR8 BASIC Games
    └─ ⟦this⟧ »HAMURS.BAS« 

TextFile

1  REM PROGRAM HAMURS.BAS
10 PRINT "YOU ARE THE RULER OF THE ANCIENT KINGDOM OF SUMERIA."
20 PRINT "YOUR PEOPLE CALL YOU 'HAMURABI THE WISE'. YOUR TASK IS"
30 PRINT "TO DEVELOP A STABLE ECONOMY BY THE WISE MANAGEMENT OF"
40 PRINT "YOUR RESOURCES. YOU WILL BE BESET FROM TIME TO TIME"
50 PRINT "BY NATURAL EVENTS. THE ONLY HELP I CAN GIVE YOU IS THE "
60 PRINT "FACT THAT IT TAKES 2 BUSHELS OF GRAIN AS SEED TO PLANT"
70 PRINT "AN ACRE. MAY YOU JUDGE WELL, ALKNOWING HAMURABI."
80 PRINT "***********HAMURABI IS HERE***********"
90 P=95
100 S=2800
110 H=3000
120 E=H-S
130 Y=3
140 A=H/Y
150 I=5
160 Q=1
170 D=0
180 PRINT 
190 PRINT "LAST YEAR";D;"PEOPLE STARVED,";I;"CAME TO THE CITY"
200 P=P+I
210 IF Q>0 THEN 240 
220 P=INT(P/2)
230 PRINT "HALF DIED OF THE PLAGUE"
240 PRINT "POPULATION IS NOW";P
250 PRINT "CITY OWNS";A;"ACRES,";Y;"BUSHELS HARVESTED PER ACRE"
260 PRINT "RATS DESTROYED";E;"BUSHELS,";S;"BUSHELS IN STORE"
270 PRINT :PRINT "DO YOU WISH TO ABDICATE";
280 INPUT B$:PRINT 
290 IF B$="NO" THEN 320  
300 IF B$<>"YES" THEN 270
310 STOP
320 C=INT(10*RND)
330 Y=C+17
340 PRINT "LAND COSTS";Y;"BUSHELS PER ACRE"
350 PRINT "BUY";
360 INPUT Q
370 IF Y*Q<S THEN 400 
380 GOSUB 840 
390 GO TO 350 
400 IF Q=0 THEN 450 
410 A=A+Q
420 S=S-Y*Q
430 C=0
440 GO TO 530 
450 PRINT "SELL";
460 INPUT Q
470 IF Q<A THEN 500 
480 GOSUB 840 
490 GO TO 450 
500 A=A-Q
510 S=S+Y*Q
520 C=0
530 PRINT "BUSHELS FOR FOOD";
540 INPUT Q
550 IF Q<=S THEN 580 
560 GOSUB 840 
570 GO TO 530 
580 S=S-Q
590 C=1
600 PRINT "ACRES TO PLANT";
610 INPUT D
620 IF D<A THEN 660 
630 IF INT(D/2)<S THEN 660 
640 GOSUB 840 
650 GO TO 600 
660 IF D>=10*P THEN 640 
670 S=S-INT(D/2)
680 GOSUB 870 
690 Y=C
700 H=D*Y
710 E=0
720 GOSUB 870 
730 IF INT(C/2)<>C/2 THEN 750 
740 E=INT(S/C)
750 S=S-E+H
760 GOSUB 870 
770 I=INT(C*(20*A+S)/P/100+1)
780 C=INT(Q/20)
790 Q=INT(10*(2*RND-1))
800 IF P<C THEN 170 
810 D=P-C
820 P=C
830 GO TO 180 
840 PRINT "THINK AGAIN, YOU HAVE"
850 PRINT A;"ACRES,";P;"PEOPLE,";S;"BUSHELS"
860 RETURN
870 C=INT(RND*5)+1
880 RETURN
890 END
«eof»