DataMuseum.dk

top - download

    Length: 4096 (0x1000)
    Types: TextFile
    Names: »AARPAN.BAS«, »POPANT.BAS«

└─⟦016ef1d53⟧ Bits:30005210 BASIC Demo
    └─ ⟦this⟧ »AARPAN.BAS« 
    └─ ⟦this⟧ »POPANT.BAS« 

TextFile

100 REM ********** PANTEBREVE **********
110 REM
120 REM *** PANTEBREVS DATA ***
130 REM PH = HOVEDSTOL
140 REM RF = RENTEFOD + BIDRAG
150 REM YY = YDELSE % P.A.
155 REM YF = FAST YDELSE I KR. P.A
160 REM LO = LOEBETID AAR
170 REM SD = START DATO
180 REM SM = START MAANED, MAANEDS COUNTER M1-TD
182 REM SY = START AAR, AARS COUNTER
184 REM TD = TERMINS DATA
186 REM M1 = 1. TERMINS MDR
188 REM M2 = 2. TERMINS MDR
190 REM EM = TERMINS MAANED F0R EKSTRA- ELLER EJERSKIFTE AFDRAG
192 REM EY = TERMINS AAR F0R EKSTRA- ELLER EJERSKIFTE AFDRAG
194 REM PE = EKSTRA- ELLER EJERSKIFTEAFDRAG I % AF RESTGAELD
196 REM PN = YDELSE NEDSAETTELSE I % AF EKSTRA- ELLER EJERSKIFTEAFDRAG
197 REM TM = TERMINS MAANED F0R TINGLYSNING
198 REM TY = TERMINS AAR F0R TINGLYSNING
200 REM
210 REM *** VARIABLE ***
220 REM AY = 1/2 AARLIG YDELSE
230 REM PA = AFDRAG
240 REM PR = RENTE
250 REM PY = YDELSE
255 REM	PF = FOERSTE YDELSE HVIS FAST YDELSE BENYTTES
260 REM PG = RESTGAELD
270 REM PI = BETALT IALT
272 REM NE = EKSTRA- ELLER EJERSKIFTE AFDRAG
274 REM NN = HALVAARLIG YDELSESNEDSAETTELSE
280 REM X  = COUNTER
285 REM Z  = FLAG
290 REM
300 WIDTH 132
310 REM DOUBLE PRECISION 8 BYTE
320 DEFDBL A,N,P,R,Y
330 REM *** INTEGER 2 BYTE ***
340 DEFINT E,L,S-X,Z
350 REM
360 REM *** GET INPUT DATA ***
370 REM
380 REM
390 INPUT "HOVEDSTOL";PH
400 INPUT "RENTE+BIDRAG P.A.%, YDELSE P.A.%, FAST YDELSE I KR P.A. EL. 0 ";RF,YY,YF
410 INPUT "LOEBETID";LO
420 INPUT "START: DATO, MDR, AAR";SD,SM,SY
424 INPUT "TERMINS DATO,  1.TERMINS MDR :";TD,M1
429 M2=M1+6
430 INPUT "SIDSTE TERMINS DATO F0R EKSTRA- ELLER EJERSKIFTE AFDRAG : MDR,AAR :";EM,EY
431 INPUT "SIDSTE TERMINS DATO F0R TINGLYSNING AF OVENNAEVNTE AFDRAG : MDR,AAR :";TM,TY
432 INPUT "EKSTRA- ELLER EJERSKIFTE AFDRAG %, YDELSES NEDSAETTELSE % P.A AF AFDRAGET :";PE,PN
439 REM
440 REM *** FIND 1 OR 2 HALVAAR ***
450 IF SM>M1 AND SM<M2 THEN 590
460 IF SM=M1 AND SD>TD-1 THEN 590
470 IF SM=M2 AND SD<TD THEN 590
480 REM
490 REM *** 1 HALVAAR ***
500 IF SM=M2 THEN 510 ELSE 530
510 RD=(30-SD) + (M1-1)*30 + TD
520 SY=SY+1
530 IF SM=M1 THEN RD=TD-SD
540 IF SM<M1 THEN RD=(30-SD) + (M1-1-SM)*30 +TD
550 SM=M1
560 GOTO 640
570 REM
580 REM *** 2 HALVAAR ***
590 IF SM=M2 THEN RD=TD-SD ELSE RD=(30-SD) + (M2-1-SM)*30 + TD
600 SM=M2
610 GOTO 640
620 REM
630 REM
640 PRINT
641 PRINT "RENTE DAGE TIL 1. YDELSE";RD
642 PF=(YF/2)*(RD/180!)
644 PRINT
645 PRINT "1. YDELSE BEREGNET UD FRA 'DEN FASTE YDELSE I KR':";PF
650 REM *** 1. YDELSE ***
660 AY=(PH/100!)*(YY/2!)
670 PY=AY*(RD/180!)
674 PRINT "1.YDELSE BEREGNET UD FRA YDELSEN I % :";PY
675 PRINT
676 INPUT "OENSKES FAST YDELSE I KR(0) ELLER I %(#0) BENYTTET, SET 0 ELLER #0 :";Z
677 IF Z=0 THEN PY=PF
678 IF Z=0 THEN AY=YF/2
680 PR=(PH/36000!)*RF*RD
690 PA=PY-PR
700 PG=PH-PA
710 PI=PY
720 PRINT
730 PRINT "TERMIN          RENTE     AFDRAG     YDELSE  RESTGAELD     BETALT
740 PRINT
750 GOSUB 910
760 REM
770 REM *** FOELGENDE TERMINER ***
780 PY=AY
790 FOR X=1 TO LO*2
800    PR=PG*(RF/200!)
810    PA=PY-PR
820    PG=PG-PA
830    PI=PI+PY
840    IF SM=M1 THEN SM=M2 ELSE SM=M1
850    IF SM=M1 THEN SY=SY+1
860    GOSUB 910
865    IF PG<0 THEN GOTO 880
867    IF SM=EM AND SY=EY THEN GOSUB 967
868    IF SM=TM AND SY=TY THEN GOSUB 975
870 NEXT X
880 END
890 REM
900 REM *** SUBRUTINE PRINT 1 DATA LINE ***
910 PRINT USING "## "; TD;
920 PRINT USING "##"; SM;
930 PRINT " ";
940 PRINT USING "####"; SY;
950 PRINT USING "########.##"; PR, PA, PY, PG, PI
960 RETURN
962 REM
965 REM EKSTRA- ELLER EJERSKIFTE AFDRAG
967 NE=PG/100*PE
968 RETURN
969 REM
974 REM NY SUM FOR BETALT IALT
975 PI=PI+NE
977 REM NY RESTGAELD EFTER BETALT EKSTRA- ELLER EJERSKIFTE AFDRAG
978 PG=PG-NE
980 REM NY HALVAARLIG YDELSE EFTER EKSTRA- ELLER EJERSKIFTE AFDRAG
983 NN=NE/100*PN
985 PY=PY-NN/2
990 PRINT "EKSTRA- ELLER EJERSKIFTE AFDRAG : ";NE
995 PRINT "HALVAARLIG YDELSESNEDSAETTELSE : ";NN/2
997 GOTO 910