DataMuseum.dk

top - download

    Length: 3072 (0xc00)
    Types: TextFile
    Names: »CRAPS.BAS«

└─⟦69a509965⟧ Bits:30005211 CR8 BASIC Games
    └─ ⟦this⟧ »CRAPS.BAS« 

TextFile

1  REM PROGRAM CRAPS.BAS
10 PRINT "CRAP GAME"
20 PRINT "WITH THE COMPUTER AS YOUR OPPONENT. THE RULES ARE SIMPLE:"
30 PRINT "   *A 7 OR 11 ON THE FIRST ROLL WINS"
40 PRINT "   *A 2, 3, OR 12 ON THE FIRST ROLL LOSES"
50 PRINT 
60 PRINT "ANY OTHER NUMBER ROLLED BECOMES YOUR 'POINT' . YOU CONTINUE"
70 PRINT "TO ROLL...IF YOU GET YOUR POINT, YOU WIN. IF YOU ROLL A 7,"
80 PRINT "YOU LOSE. THE DICE CHANGE HANDS WHEN THIS HAPPENS."
90 PRINT 
100 PRINT 
110 PRINT "WHAT NUMBER BETWEEN 1 AND 711 IS LUCKY FOR YOU TODAY";
120 INPUT N
130 FOR I=1 TO N
140 LET X=RND
150 NEXT I
160 LET Z=5*INT(10+11*RND)
170 PRINT "SPLENDID.....YOU ARE GIVEN ";Z;"DOLLARS TO PLAY WITH."
180 PRINT 
190 PRINT 
200 REM IF N IS EVEN 'YOU' ROLL FIRST, IF N IS ODD 'I' ROLL FIRST.
210 IF N-2*INT(N/2)=0 THEN 270
220 LET W=-1
230 PRINT "I'LL ROLL FIRST....."
240 PRINT 
250 PRINT 
260 GOTO 310
270 LET W=1
280 PRINT "YOU ROLL FIRST....."
290 PRINT 
300 PRINT 
310 LET Q=0
320 PRINT "HOW MUCH DO YOU BET ($$) ";
330 INPUT B
340 IF B>=0 THEN 390
350 PRINT 
360 PRINT "WISE GUY EH! NO CREDIT AT THIS CASINO"
370 PRINT 
380 GOTO 320
390 PRINT "OK....."
400 PRINT 
410 IF B=INT(B) THEN 460
420 PRINT 
430 PRINT "NO COINS PERMITTED..JUST BILLS, PLEASE!"
440 PRINT 
450 GOTO 320
460 IF B=0 THEN 1150
470 IF B<Z+1 THEN 510
480 PRINT "DON'T TRY TO BET MORE THAN YOU HAVE, PLEASE!!"
490 PRINT 
500 GOTO 320
510 LET D1=INT(6*RND+1)
520 LET D2=INT(6*RND+1)
530 LET Q=Q+1
540 LET S=D1+D2
550 IF W>0 THEN 580
560 PRINT "  I ROLL";D1;"AND";D2;
570 GOTO 590
580 PRINT "YOU ROLL";D1;"AND";D2;
590 IF Q<>1 THEN 910
600 IF (S-2)*(S-3)*(S-12)=0 THEN 690
610 IF (S-7)*(S-11)=O THEN 760
620 IF W>0 THEN 650
630 PRINT "SO MY POINT IS";S;
640 GOTO 660
650 PRINT "SO YOUR POINT IS";S;
660 PRINT ".....LET'S ROLL 'EM AGAIN....."
670 LET P=S
680 GOTO 510
690 PRINT "AND CRAP OUT..."
700 LET C=1
710 IF W>0 THEN 740
720 LET Z=Z+B
730 GOTO 820
740 LET Z=Z-B
750 GOTO 820
760 PRINT "AND PASS....."
770 LET C=1
780 IF W>0 THEN 810
790 LET Z=Z-B
800 GOTO 820
810 LET Z=Z+B
820 PRINT 
830 IF Z<1 THEN 1110
840 PRINT "YOU NOW HAVE ";Z;"DOLLARS LEFT....."
850 IF C>0 THEN 880
860 PRINT "CHANGE DICE NOW....."
870 PRINT 
880 LET W=W*C
890 LET Q=0
900 GOTO 320
910 IF S<>7 THEN 990
920 PRINT "AND LOSE....."
930 LET C=-1
940 IF W>0 THEN 970
950 LET Z=Z+B
960 GOTO 820
970 LET Z=Z-B
980 GOTO 820
990 IF S=P THEN 1020
1000 PRINT "...ROLL AGAIN....."
1010 GOTO 510
1020 IF W>0 THEN 1070
1030 PRINT "AND MAKE MY POINT....."
1040 LET C=1
1050 LET Z=Z-B
1060 GOTO 820
1070 PRINT "AND MAKE YOUR POINT....."
1080 LET C=1
1090 LET Z=Z+B
1100 GOTO 820
1110 PRINT 
1120 PRINT "YOU HAVE RUN OUT OF MONEY....SORRY ABOUT THAT....."
1130 PRINT "THANKS FOR THE GAME.....BETTER LUCK NEXT TIME, PARDNER!"
1140 GOTO 1170
1150 PRINT "THANKS FOR THE GAME.....AND CONGRATULATIONS"
1160 PRINT "FOR BEING ABLE TO QUIT WHILE YOU WERE AHEAD."
1170 PRINT "BYE"
1180 RUN "MENU"
«eof»