DataMuseum.dk

top - download

    Length: 1536 (0x600)
    Types: TextFile
    Names: »XNEWENTR.CMD«

└─⟦ea621760d⟧ Bits:30005267 dBase II - uoriginal diskette
    └─ ⟦this⟧ »XNEWENTR.CMD« 

TextFile

NOTE - EXTENDED NEWENTR COMMAND FILE TO ENTER NEW CHECKS
*   
*  - clear screen
ERASE
*  - position to bottom of database file
GO BOTTOM
*  - initialize date
STORE '01/01/81' TO CH:DAT
DO WHILE T
  * initialize memory variables so that READ will have a length to mark
  STORE '                              ' TO CH:TO
  STORE 0.00 TO M:AMT
  STORE ' ' TO CH:MEMO
  STORE NO+1 TO M:NO
  *  - this is text to read check data
  @ 5,0  SAY 'CHECK ENTRY    ENTER CHECK NUMBER OF ZERO TO EXIT'
  @ 6,0  SAY 'IF CHECK NUMBER=0, ENTER CARRIAGE RETURNS FOR OTHER ENTRIES'
  @ 7,0  SAY 'CHECK NUMBER        ' GET M:NO
  @ 8,0  SAY 'PAY TO THE ORDER OF ' GET CH:TO
  @ 9,0  SAY 'AMOUNT OF CHECK     ' GET M:AMT
  @ 10,0 SAY 'DATE WRITTEN        ' GET CH:DAT PICTURE '99/99/99'
  @ 11,0 SAY 'PURPOSE OF CHECK'
  @ 13,0 SAY 'A - ADVERTISING           B - BANK CHARGES      C - CAR + TRUCK'
  @ 14,0 SAY 'D - DUES + PUBLICATIONS   F - FREIGHT           I - INSURANCE'
  @ 15,0 SAY 'L - LEGAL EXPENSES        S - OFFICE SUPPLIES   P - POSTAGE'
  @ 16,0 SAY 'R - RENT                  T - TELEPHONE         X - TAXES'
  @ 18,0 SAY 'ENTER PURPOSE LETTER' GET CH:MEMO
  READ
  IF M:NO=0
    RETURN
  ENDIF
  *  - put blank card into database file
  APPEND BLANK
  *  - put check data into database file
  REPLACE NO WITH M:NO,TO WITH CH:TO,AMT WITH M:AMT;
    DATE WITH CH:DAT,CAN WITH F,MEMO WITH !(CH:MEMO)
ENDDO
«eof»