DataMuseum.dk

top - download

    Length: 2048 (0x800)
    Types: TextFile
    Names: »GUNNER.BAS«

└─⟦69a509965⟧ Bits:30005211 CR8 BASIC Games
    └─ ⟦this⟧ »GUNNER.BAS« 

TextFile

1  REM PROGRAM GUNNER.BAS;1
10 REM *** MODIFIED AND CONVERTED TO RSTS/E BY DAVID AHL, DIGITAL
20 RANDOMIZE
30 PRINT "THIS COMPUTER DEMONSTRATION SIMULATES THE"
40 PRINT"RESULTS OF FIRING A FIELD ARTILLERY WEAPON."
50 PRINT
60 PRINT"YOU ARE THE OFFICER-IN-CHARGE, GIVING ORDERS TO THE GUN"
70 PRINT"CREW, TELLING THEM THE DEGREES OF ELEVATION YOU ESTIMATE"
80 PRINT"WILL PLACE THE PROJECTILE ON TARGET.  A HIT WITHIN 100 YARDS"
90 PRINT "OF THE TARGET WILL DESTROY IT.  TAKE MORE THAN 5 SHOTS,"
100 PRINT "AND THE ENEMY WILL DESTROY YOU!":PRINT
110 PRINT"MAXIMUM RANGE OF YOUR GUN IS 46500 YARDS."
120 Z=0
130 PRINT
140 S1=0
150 LET T=43000-30000*RND
160 LET S=0
170 GO TO 350
180 PRINT"MINIMUM ELEVATION OF GUN IS ONE DEGREE."
190 GO TO 370
200 PRINT"MAXIMUM ELEVATION OF GUN IS 89 DEGREES."
210 GO TO 370
220 PRINT"OVER TARGET BY";ABS(E);"YARDS."
230 GO TO 370
240 PRINT "SHORT OF TARGET BY";ABS(E);"YARDS."
250 GO TO 370
260 GO TO 270
270 PRINT"***TARGET DESTROYED***   ";S;"ROUNDS OF AMMUNITION EXPENDED"
280 GOSUB 560
290 S1=S1+S
300 IF Z=4 THEN 510
310 Z=Z+1
320 PRINT
330 PRINT"THE FORWARD OBSERVER HAS SIGHTED MORE ENEMY ACTIVITY."
340 GO TO 150
350 PRINT"     DISTANCE TO THE TARGET IS";INT(T);"YARDS....."
360 PRINT
370 PRINT
380 PRINT"ELEVATION:";
390 INPUT B
400 IF B>89 THEN 200
410 IF B<1 THEN 180
420 LET S=S+1
430 IF S<6 THEN 470
440 PRINT:PRINT "BOOM !!!  YOU HAVE JUST BEEN DESTROYED ";
450 GOSUB 560
460 PRINT "BY THE ENEMY":PRINT:PRINT:GOTO 530
470 LET B2=2*B/57.3:LET I=46500*SIN(B2):LET X=T-I:LET E=INT(X)
480 IF ABS(E)<100 THEN 260
490 IF E>100 THEN 240
500 IF E<-100 THEN 220
510 PRINT:PRINT:PRINT "TOTAL ROUNDS EXPENDED WERE";S1
520 IF S1>15 THEN 530 ELSE PRINT "NICE SHOOTING !!":GOSUB 560:GOTO 540
530 PRINT "BETTER GO BACK TO FORT SILL FOR REFRESHER TRAINING!"
540 PRINT:PRINT "THANK YOU FOR PLAYING!"
550 PRINT:PRINT "TRY AGAIN.....":PRINT:GOTO 110
560 FOR N=1 TO 10:PRINT CHR$(7);:NEXT N
570 RETURN
580 END
«eof»