DataMuseum.dk

top - download

    Length: 2944 (0xb80)
    Types: TextFile
    Names: »BANK.BAS«

└─⟦016ef1d53⟧ Bits:30005210 BASIC Demo
    └─ ⟦this⟧ »BANK.BAS« 

TextFile

100 REM ********** PANTEBREVE **********
110 REM
120 REM *** PANTEBREVS DATA ***
130 REM PH = HOVEDSTOL
140 REM RF = RENTEFOD + BIDRAG
150 REM YY = YDELSE % P.A.
155 REM YF = FAST MAANEDLIG YDELSE I KR.
160 REM LO = LOEBETID AAR
170 REM SD = START DATO
180 REM SM = START MAANED, MAANEDS COUNTER M1-TD
182 REM SY = START AAR, AARS COUNTER
184 REM TD = AFDRAGS MDR DATO
186 REM M1 = 1. BETALINGS MDR
190 REM EM = MAANED F0R EKSTRA AFDRAG
192 REM EY = AAR F0R EKSTRA AFDRAG
194 REM PE = EKSTRA AFDRAG I KR.
200 REM
210 REM *** VARIABLE ***
220 REM AY = 1/12 AARLIG YDELSE
230 REM PA = AFDRAG
240 REM PR = RENTE
250 REM PY = YDELSE
255 REM	PF = FOERSTE YDELSE HVIS FAST YDELSE BENYTTES
260 REM PG = RESTGAELD
270 REM PI = BETALT IALT
272 REM NE = EKSTRA AFDRAG
280 REM X  = COUNTER
285 REM Z  = FLAG
290 REM
300 WIDTH 132
310 REM DOUBLE PRECISION 8 BYTE
320 DEFDBL A,N,P,R,Y
330 REM *** INTEGER 2 BYTE ***
340 DEFINT E,L,S-X,Z
350 REM
360 REM *** GET INPUT DATA ***
370 REM
380 REM
390 INPUT "HOVEDSTOL";PH
400 INPUT "RENTE+BIDRAG P.A.%, YDELSE P.A.%, FAST MAANEDLIG YDELSE I KR ";RF,YY,YF
410 INPUT "LOEBETID";LO
420 INPUT "START: DATO, MDR, AAR";SD,SM,SY
424 INPUT "MAANEDLIG BETALINGS DATO, 1.BETALINGS MAANED : ";TD,M1
430 INPUT "MAANEDLIG BATALINGS DATO FOR EKSTRA AFDRAG : MDR,AAR : ";EM,EY
432 INPUT "EKSTRA AFDRAG I KR.:";PE
439 REM
440 REM *** FIND 1. YDELSE ***
530 IF SM=M1 THEN RD=TD-SD
540 IF SM<M1 THEN RD=(30-SD) + (M1-1-SM)*30 +TD
550 SM=M1
560 GOTO 640
570 REM
630 REM
640 PRINT
641 PRINT "RENTE DAGE TIL 1. YDELSE";RD
642 PF=(YF)*(RD/30!)
644 PRINT
645 PRINT "1. YDELSE BEREGNET UD FRA 'DEN FASTE YDELSE I KR':";PF
650 REM *** 1. YDELSE ***
660 AY=(PH/100!)*(YY/12!)
670 PY=AY*(RD/30!)
674 PRINT "1.YDELSE BEREGNET UD FRA YDELSEN I % :";PY
675 PRINT
676 INPUT "OENSKES FAST YDELSE I KR(0) ELLER I %(#0) BENYTTET, SET 0 ELLER #0 :";Z
677 IF Z=0 THEN PY=PF
678 IF Z=0 THEN AY=YF
680 PR=(PH/36000!)*RF*RD
690 PA=PY-PR
700 PG=PH-PA
710 PI=PY
720 PRINT
730 PRINT "  DATO          RENTE     AFDRAG     YDELSE  RESTGAELD     BETALT
740 PRINT
750 GOSUB 910
760 REM
770 REM *** FOELGENDE TERMINER ***
780 PY=AY
790 FOR X=1 TO LO*12
800    PR=PG*(RF/1200!)
810    PA=PY-PR
820    PG=PG-PA
830    PI=PI+PY
840    SM=SM+1
845    IF SM=13 THEN SM=1
850    IF SM=1 THEN SY=SY+1
860    GOSUB 910
865    IF PG<0 THEN GOTO 880
868    IF SM=EM AND SY=EY THEN GOSUB 975
870 NEXT X
880 END
890 REM
900 REM *** SUBRUTINE PRINT 1 DATA LINE ***
910 PRINT USING "## "; TD;
920 PRINT USING "##"; SM;
930 PRINT " ";
940 PRINT USING "####"; SY;
950 PRINT USING "########.##"; PR, PA, PY, PG, PI
960 RETURN
962 REM
969 REM
974 REM NY SUM FOR BETALT IALT
975 PI=PI+PE
977 REM NY RESTGAELD EFTER BETALT EKSTRA AFDRAG
978 PG=PG-PE
990 PRINT "EKSTRA AFDRAG : ";PE
995 PRINT "YDELSEN FORBLIVER UFORANDRET."
997 GOTO 910




«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»«nul»