DataMuseum.dk

top - download

    Length: 3200 (0xc80)
    Types: TextFile
    Names: »BACKUP.MOD«, »BANK.MOD«

└─⟦6ae1c04a5⟧ Bits:30004364 SW1656 IFPS/Personal Version 2.10 release 1.1
    └─ ⟦this⟧ »BACKUP.MOD« 
    └─ ⟦this⟧ »BANK.MOD« 

TextFile

COLUMNS 1985..1989,AVERAGE,BASIS,ACCEPT
PERIODS 12
ØØ
ØØ  This model calculates a generic set of ratios for analysis of
ØØ  a new loan.  The basis for the ratios is a cash flow analysis
ØØ  assuming the loan is granted and a balance sheet of either 
ØØ  a corporate or individuals net worth.  The ratios are then
ØØ  tested against pre-defined acceptance levels to determine whether
ØØ  or not the loan should be granted.
ØØ
ØØ    CASH FLOW STATEMENT
ØØ
SALES PROJECTIONS=SALES IN 1984 * SALES GROWTH RATE,'
    PREVIOUS * SALES GROWTH RATE
SALES GROWTH RATE=INDUSTRY GROWTH RATE
SALES IN 1984=DATA  
INDUSTRY GROWTH RATE=DATA
COMPANIES PROJECTED GROWTH RATE=DATA
ØØ
SALES EXPENSES=COST OF SALES PCT * SALES PROJECTIONS
LOAN PAYMENT=PAYMENT
OTHER PAYMENTS=DATA 
OTHER EXPENSES=DATA,PREVIOUS * INFLATION RATE
TOTAL EXPENSES=SUM(SALES EXPENSES THRU OTHER EXPENSES)
ØØ
COST OF SALES PCT=DATA
INFLATION RATE=DATA
AMORT(LOAN AMOUNT REQUESTED,0,INTEREST RATE,1,1,1; '
      PAYMENT,INTEREST,PRINCIPAL,BALANCE)
LOAN AMOUNT REQUESTED=DATA 
INTEREST RATE=DATA
ØØ
CASH FLOW=SALES PROJECTIONS - TOTAL EXPENSES
ØØ
ØØ    BALANCE SHEET
ØØ
CASH=BEG CASH,PREVIOUS ENDING CASH
BEG CASH=DATA    
ENDING CASH=BEG CASH + CASH FLOW
ACCOUNTS RECIEVABLES=RECIEVABLES PCT * SALES PROJECTIONS
RECIEVABLES PCT=DATA
INVENTORY=DATA 
FIXED ASSETS=DATA  
OTHER ASSETS=DATA 
TOTAL ASSETS=CASH + ACCOUNTS RECIEVABLES + INVENTORY + '
             FIXED ASSETS + OTHER ASSETS
ØØ
CURRENT LIAB PCT=DATA
CURRENT LIABILITIES=CURRENT LIAB PCT * SALES PROJECTIONS
LONG TERM LIABILITIES=300000,PREVIOUS - OTHER PAYMENTS
OTHER LIABILITIES=DATA
TOTAL LIABILITIES=SUM(CURRENT LIABILITIES THRU OTHER LIABILITIES)
ØØ
CAPITAL STOCK=DATA 
RETAINED EARNINGS=TOTAL ASSETS - (CAPITAL STOCK + TOTAL LIABILITIES)
NET WORTH=CAPITAL STOCK + RETAINED EARNINGS
TOTAL LIABILITIES AND NW=TOTAL LIABILITIES + NET WORTH
ØØ
ØØ    RATIO ANALYSIS
ØØ
CASH TO CURRENT DEBT=CASH / CURRENT LIABILITIES 
QUICK ACID RATIO=(CASH + ACCOUNTS RECIEVABLES) / CURRENT LIABILITIES
DEBT TO WORTH=TOTAL LIABILITIES / NET WORTH
DEBT TO TOTAL ASSETS=TOTAL LIABILITIES / TOTAL ASSETS
RETURN ON EQUITY=CASH FLOW / ((NET WORTH + PREVIOUS NET WORTH) / 2)
ØØ
ØØ     DECISION CRITERION
ØØ
CASH TO CURRENT DEBT TEST=.75
QUICK ACID TEST=1.20
DEBT TO WORTH TEST=.40
DEBT TO TOTAL ASSETS TEST=.40
RETURN ON EQUITY TEST=8%
ØØ
ØØ     AVERAGE COLUMN DEFINIITIONS
ØØ
REDEFINE AVERAGE FOR SALES PROJECTIONS THRU RETURN ON EQUITY= '
      SUM(Æ1985Å THRU Æ1989Å) / 5
REDEFINE BASIS FOR CASH TO CURRENT DEBT=CASH TO CURRENT DEBT TEST
REDEFINE BASIS FOR QUICK ACID RATIO=QUICK ACID TEST
REDEFINE BASIS FOR DEBT TO WORTH=DEBT TO WORTH TEST
REDEFINE BASIS FOR DEBT TO TOTAL ASSETS=DEBT TO TOTAL ASSETS TEST
REDEFINE BASIS FOR RETURN ON EQUITY=RETURN ON EQUITY TEST
REDEFINE ACCEPT FOR CASH TO CURRENT DEBT THRU QUICK ACID RATIO = '
      IF ÆBASISÅ - ÆAVERAGEÅ >= .25 THEN 0 ELSE 1
REDEFINE ACCEPT FOR DEBT TO WORTH THRU DEBT TO TOTAL ASSETS = '
      IF ÆBASISÅ - ÆAVERAGEÅ <= .10 THEN 0 ELSE 1
REDEFINE ACCEPT FOR RETURN ON EQUITY = '   
      IF ÆBASISÅ - ÆAVERAGEÅ >= .03 THEN 0 ELSE 1
«eof»