DataMuseum.dk

top - download

    Length: 2688 (0xa80)
    Types: TextFile
    Names: »LISTAID.PRG«

└─⟦71c82d5c0⟧ Bits:30004214 LISTAID - Partslist management system
    └─ ⟦this⟧ »LISTAID.PRG« 

TextFile

*******************************************************************************
*  DESIGN: NIF/ASD/SEPTEMBER 1985                                             *
*******************************************************************************
*                                                                             *
* THIS COMMANDFILE CONSTITUTES THE MAIN_PROGRAM IN THE                        *
* ASD PARTS MANAGEMENT SYSTEM                                                 *
*                                                                             *
*******************************************************************************

*RESET SYSTEM PARAMETERS

SELECT SECO
USE
SELECT PRIM
USE
CLEAR
RELEASE ALL
SET TALK OFF
SET ESCAPE ON
STORE 'E:' TO PRGDISK
STORE 'E' TO UDISK
STORE 'E' TO PDISK
SET DEFAULT TO &PRGDISK
STORE 0 TO MLOOP
ERASE
@ 10,5 SAY "DET ER PÅ DET STRENGESTE FORBUDT AT ÆNDRE I PPL'EN !!!!!"
@ 20,5 SAY "TYG LIDT PÅ DET"
DO WHILE MLOOP<400
   STORE MLOOP+1 TO MLOOP
ENDDO

*INITIALIZE DATO,UNITNAME AND CONFIGURATION FILE POINTER
ERASE
@ 1,10 SAY "WELCOME TO THE 'LISTAID' PARTSLIST GENERATOR"
STORE '00/00/00' TO DATO
STORE '                    ' TO UNITNAME
STORE 'E:FILE' TO CONFIGNAME
STORE 'E:ERS1' TO PPLNAME

SET CONFIRM ON
SET COLON OFF
DO UNIT

*SHOW MENU AND ACCEPT COMMAND

STORE 'COMM' TO COMMAND
STORE 'READY' TO STATUS
DO WHILE COMMAND#'STOP'
   STORE F TO CALL
   SET COLON OFF
   SET CONFIRM ON
   IF STATUS#'SYSTEM'
      SET FORMAT TO CMDMENU
   ENDIF
   READ
   STORE !(COMMAND) TO COMMAND
   DO CASE
      CASE COMMAND='COMM'
           STORE 'READY' TO STATUS
      CASE COMMAND='STOP'
           SET FORMAT TO SCREEN
           STORE N TO ANSWER
           @ 4,5 SAY 'ARE YOU SURE? (Y/N)'
           @ 4,26 GET ANSWER
           READ
           IF .NOT.ANSWER
              SET FORMAT TO SYSMENU
              STORE 'SYSC' TO COMMAND
              STORE 'SYSTEM' TO STATUS
           ENDIF
           RELEASE ANSWER
      CASE COMMAND='SYSC'
           SET FORMAT TO SYSMENU
           STORE 'SYSTEM' TO STATUS
      OTHERWISE
           STORE PRGDISK-COMMAND-'.PRG' TO PRGFILE
           IF FILE(PRGFILE)
              ERASE
              DO &PRGFILE
              IF STATUS='SYSTEM'
                 SET FORMAT TO SYSMENU
              ENDIF
           ELSE
              STORE 'INVALID ENTRY' TO STATUS
           ENDIF
   ENDCASE
ENDDO

*STOP SEQUENCE

ERASE
SELECT SECO
USE
SELECT PRIM
USE
RELEASE ALL
CLEAR
RETURN

«eof»