|
DataMuseum.dkPresents historical artifacts from the history of: CP/M |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about CP/M Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - download
Length: 1280 (0x500)
Types: TextFile
Names: »LINREG.BAS«
└─⟦016ef1d53⟧ Bits:30005210 BASIC Demo
└─ ⟦this⟧ »LINREG.BAS«
10 PRINT "LINEAR REGRESSION"
20 PRINT
30 INPUT "NUMBER OF POINTS";N
40 DIM X(N):DIM Y(N)
50 PRINT
60 J=0:K=0:L=0:M=0:R2=0
70 REM LOOP TO ENTER COORDINATES
80 PRINT SPC(10);"X","Y"
90 FOR I=1 TO N
100 PRINT "POINT";I;:INPUT X(I),Y(I)
110 REM ACCUMULATE INTERMEDIATE SUMS
120 J=J+X(I)
130 K=K+Y(I)
140 L=L+X(I)^2
150 M=M+Y(I)^2
160 R2=R2+X(I)*Y(I)
170 NEXT I
180 REM COMPUTE CURVE COEFFICIENT
190 B=(N*R2-K*J)/(N*L-J^2)
200 A=(K-B*J)/N
210 PRINT
220 PRINT "F(X)=";A;"+ (";B;"*X)"
230 REM COMPUTE REGRESSION ANALYSIS
240 J=B*(R2-J*K/N)
250 M=M-K^2/N
260 K=M-J
270 PRINT
280 R2=J/M
290 PRINT "COEFFICIENT OF DETERMINATION (R^2)=";
300 PRINT USING "#.########";R2
310 PRINT "COEFFICIENT OF CORRELATION=";
320 PRINT USING "#.########";SQR(R2)
330 PRINT "STANDARD ERROR OF ESTIMATE=";
340 PRINT USING "#.########^^^^";SQR(K/(N-2))
350 PRINT
360 REM ESTIMATE Y COORDINATES OF POINTS WITH ENTERED X COODINATE
370 PRINT "INTERPOLATION: (ENTER X=0 TO END PROGRAM)"
380 INPUT "X=";X
390 REM RESTART OR END PROGRAM
400 IF X=0 THEN 450
410 PRINT "Y=";
420 PRINT USING "#.########^^^^";A+B*X
430 PRINT
440 GOTO 370
450 PRINT:PRINT
460 INPUT "MENU";A$
470 RUN "MENU"