DataMuseum.dk

top - download

    Length: 1792 (0x700)
    Types: TextFile
    Names: »RENTE.BAS«

└─⟦a2831e659⟧ Bits:30004217 MBASIC r5.21 og BASIC programmer
    └─ ⟦this⟧ »RENTE.BAS« 

TextFile

10	PRINT
12	PRINT "=============="
15	PRINT "Et laans rente"
18	PRINT "=============="
20	PRINT
30	INPUT "Fast ydelse ";R
50	INPUT "Antal aar, Maaneder ";YO,M
64 REM beregn antal aar udfra aar og maaneder
65	Y=(12*YO+M)/12
70	INPUT "Hovedstol ";P
90	INPUT "Antal ydelser pr. aar ";N
105 REM saet startrenten til 10%
110	I=10
114 REM variablen I2 indeholder den forrige
117 REM startrente (start altid med 0)
120	I2=0
124 REM beregn den faste ydelse under
127 REM anvendelse af startrenten
130	R1=(I*P/N)/(1-1/((I/N+1)^(N*Y)))
135 REM afrund til naermeste hundrededel
140	R1=INT(R1*100+.5)/100
144 REM variablen I3 anvendes til at tilnaerme
147 REM startrenten til den reelle rente
150	I3=ABS(I-I2)/2
155 REM gem nuvaerende startrente
160	I2=I
166 REM sammenlign den netop beregnede ydelse (R1)
167 REM med den reelle ydelse (R). Hvis ydelserne
168 REM er taet nok paa at vaere lige store, saa er
169 REM startrenten lig med laanets reelle rente
170	IF ABS(R1-R)<.0001 THEN GOTO 230
180	IF R1>R THEN GOTO 210
188 REM hvis R1<R, maa renten vaere
189 REM storre end startrenten
190	I=I+I3
198 REM gentag beregning med denne
199 REM storre startrente
200	GOTO 130
208 REM hvis R1>R, maa renten vaere
209 REM mindre end startrenten
210	I=I-I3
218 REM gentag beregning med denne
219 REM mindre startrente
220	GOTO 130
228 REM beregn, afrund og udskriv
229 REM laanets reelle rente
230	I=((INT((I*1000)*100+.5))/100)/1000
240	PRINT "          Aarlige rente =";I*100;"%"
250	PRINT
260	PRINT "Vil du køre programmet igen ? (J/N)"
270	SVAR$=INKEY$
280	IF SVAR$="" THEN GOTO 270
290	IF SVAR$="J" THEN GOTO 20
300	IF SVAR$="j" THEN GOTO 20
310	CHAIN "LAAN"
«eof»