|
DataMuseum.dkPresents historical artifacts from the history of: CR80 Hard and Floppy Disks |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about CR80 Hard and Floppy Disks Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - download
Length: 2034 (0x7f2)
Types: TextFile
Names: »MS5210.S«
└─⟦b5acf5c79⟧ Bits:30005104 8" CR80 Floppy CR80FD_0063 ( VOL: SCC.V MSS Directory: MS2.D )
└─⟦f918199fd⟧
└─ ⟦this⟧ »MS2.D!MS5210.S«
MESSAGE <:MS5210.S V810325:>
;-----------------------------------------------------------------------
; SUBROUTINE MS5210
; CLOSE BINARY HEADERS.
;
; REGISTERS CALL EXIT
; R0,R1,R2,R5 - DEST
; R4 LINK DEST
; R3,R6,R7 NOT USED
;
; INPUT: AXXXXX VARIABLES (UNPACKED VALUES RELATIVE TO START OF ASCII)
; OUTPUT: OBINHD DATA (PACKED OBJECT BINARY HEADER)
; EXIT TO: LINK+0 (OK)
;-----------------------------------------------------------------------
MS5210: ; CLOSE BINARY HEADERS:
MOV R4 RL5000 ; SAVE RETURN LINK
MOVC OBINHD R5 ; GET OBJECT BINARY HEADER
MOVC ACTIME R4 ; GET ACCEPTANCE TIME
MOV X4 R01 ;
MOVL R01 BHRLT/2. X5; SAVE
MOVC AROUM R4 ; GET ROUTING MASK
MOVL X4 R01 ;
SLL R01 BHBROM ; POSITION
ADDC 0<BHBORC R0 ; INCLUDE ORBIT CONTROL
MOVL R01 BHROM/2. X5; SAVE
MOV AIDREF R0 ; GET MSG_ID REFERENCE
MOV R0 BHIREF/2.X5; SAVE
MOV AADREF R0 ; GET ADDRESS LIST OFFSET
ADDC BHELGT R0 ; (ABSOLUTE)
MOV R0 BHALO/2. X5; SAVE
MOV AMSGRF R0 ; GET SIGNAL HEADER LENGTH
MOV R0 BHSHL/2. X5; SAVE
MOV AMSGLT R0 ; GET MESSAGE LENGTH
ADDC BHELGT R0 ; (ABSOLUTE)
MOV R0 BHMLGT/2.X5; SAVE
MOV R5 R4 ; GET OBJECT BINARY HEADER
SLL R4 1 ; BYTE ADDR
MOV APRECE R0 ; GET ACTION PRECEDENCE
MOVB R0 BHAPRC.X4 ; SAVE
MOV ASECUR R0 ; GET SECURITY
MOVB R0 BHCLAS.X4 ; SAVE
JMPI RL5000 ;R RETURN -