|
DataMuseum.dkPresents historical artifacts from the history of: CR80 Hard and Floppy Disks |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about CR80 Hard and Floppy Disks Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - download
Length: 2106 (0x83a)
Types: TextFile
Names: »MS1030.S«
└─⟦b5acf5c79⟧ Bits:30005104 8" CR80 Floppy CR80FD_0063 ( VOL: SCC.V MSS Directory: MS2.D )
└─⟦f918199fd⟧
└─ ⟦this⟧ »MS2.D!MS1030.S«
MESSAGE <:MS1030.S V810311:>
;-----------------------------------------------------------------------
; SUBROUTINE MS1030
; WRITE FIKS RECORD.
;
; CALL TO: MON STREAM, OUTREC
;
; REGISTERS CALL EXIT
; R4 LINK DEST
; R6 REF(IOCB) REF(IOCB)
; R0,R1,R2,R7 - DEST
; R3,R5 - UNCHANGED
;
; INPUT: IOCB DATA, IOBUF.IOCB DATA
; OUTPUT: IOCB DATA, FILE
; EXIT TO: LINK+0 (DONE)
; MSE120 (ERROR)
;-----------------------------------------------------------------------
MS1030: ; WRITE FIKS RECORD:
MOV R4 RL1000 ; SAVE RETURN LINK
MOV R3 WK1000 ; SAVE R3
MOV IOBNX. X6 R4 ; GET INDEX
MOVC LFCHAR R0 ; WRITE 'LF' AS LAST BYTE
MOD IOBUF. X6 ;
MOVB R0 X4 ;
INC IOBNX. X6 ; AND INDICATE ONE LARGER BLOCK
MOV IOBNX. X6 R2 ; POSITION BLOCK SIZE
MOV R2 IOBLT. X6 ; SAVE
MOV IOBUF. X6 R1 ; GET BUFFER ADDRESS
MOV R2 R0 ; CALCULATE <ST><BC>
ADDC -2 R0 ; <BC>
SWP R0 ;
ADDC STCHAR R0 ; <ST><BC>
MOV R0 X1 ; SAVE AS FIRST 2 BYTES
MOV IOST. X6 R4 ; GET STREAM DESCRIPTOR
MON STREAM, OUTREC ; PERFORM BLOCKIO
JMPI & S4 MIE120 ; EXIT0-ERROR
MOD IOBLT. X6 ; IF NOT MADE WHAT REQUESTED
INE R2 0 ;
JMPI S4 MIE100 ; THEN FILE ERROR
ADD R2 IOFNX. X6 ; UPDATE FILE INDEX
MOVC 2 R1 ;
MOV R1 IOBNX. X6 ; SET INDEX TO 1ST DATABYTE
INC IOLINE.X6 ; INCREMENT CURRENT LINE
MOV WK1000 R3 ; RESTORE R3
JMPI RL1000 ; RETURN