|
DataMuseum.dkPresents historical artifacts from the history of: CR80 Hard and Floppy Disks |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about CR80 Hard and Floppy Disks Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - download
Length: 2138 (0x85a)
Types: TextFile
Names: »MSASA.S«
└─⟦93791531c⟧ Bits:30005105 8" CR80 Floppy CR80FD_0064 ( VOL:SCC.V MSS Directory: MS1.D )
└─⟦185cc4db7⟧
└─ ⟦this⟧ »MS1.D!MSASA.S«
MESSAGE <: MSASA.S V810214:>
;-----------------------------------------------------------------------
; SUBROUTINES A SERIES
; THESE SUBROUTINES ARE CALLED BY ACTION PROCEDURES A SERIES
;
; ASA10: MOVE PP WINDOW. IF COUNTOUT THEN INTERCEPT.
;
; REGISTERS CALL EXIT
; R0 CHAR UNCH
; R4 UNCH
; R6 LINK
; R2 - ERROR CODE (INTERCEPT)
; R1,R7 - DEST
;
; INPUT: PRCWND,PRCCNT
; OUTPUT: PRCWND,PRCCNT
; EXIT TO: LINK+0 (OK)
;-----------------------------------------------------------------------
ASA10: ; ACTION SUBROUTINE A10:
MOV PRCWND R7 ; GET WINDOW CONTENTS
IEQ R7 -1 ; IF PRECEDENCE DETECTED
JMP 0. X6 ;R THEN RETURN
MOVC PRCCNT R7 ; GET COUNTER ADDRESS
JON X7 ASA10A ; IF COUNTOUT THEN BEGIN
MOVC ERCPRC R2 ; GET ERROR CODE
JMP AS000 ; CALL INTERCEPT
; (USE LINK FOR RETURN)
ASA10A: ; END COUNTOUT
DEC X7 ; COUNT DOWN
MOV R0 R1 ; DUPLICATE CHAR
XTR R1 7 ; REMOVE POSSIBLE 8TH BIT
SRL R1 2 ; GET TABLE ENTRY NUMBER
MOD R1 ; USE IT AS INDEX
MOV PVT R1 ; TO GET PRECEDENCE CODE
MOV R0 R7 ; DUPLICATE CHAR
XTR R7 2 ; GET SUBENTRY NUMBER
SLL R7 2 ; POSITION TO SHIFT ENTRY
MOD R7 ;
SRL R1 0 ; RIGHT ADJUST ENTRY
XTR R1 4 ; ISOLATE CODE
MOVC PRCWND R7 ; GET WINDOW ADDRESS
SLL X7 8 ; MOVE WINDOW
IOR R1 X7 ; INCLUDE NEW CODE
JMP 0. X6 ;R RETURN R