DataMuseum.dk

top - download

    Length: 4992 (0x1380)
    Types: TextFile
    Names: »APTI.BAS«

└─⟦69a509965⟧ Bits:30005211 CR8 BASIC Games
    └─ ⟦this⟧ »APTI.BAS« 

TextFile

1  REM PROGRAM APTI.BAS
10 LET Y$="YES"
20 LET N$="NO"
30 LET Z$="TYPE YES OR NO"
40 LET T=0
50 PRINT "THIS IS AN ADP APTITUDE TEST"
60 PRINT "IF YOU SCORE 30 OR MORE , YOU ARE THE TYPE I AM SEEKING"
70 PRINT "DON'T TRY AND CHEAT !!"
80 PRINT "QUESTION 1.WOT IS YORE EDUCATIONAL LEVEL?"
90 PRINT TAB(8);"1.DEGREE IN COMPUTING SCIENCE"
100 PRINT TAB(8);"2.A LEVEL SCIENCE"
110 PRINT TAB(8);"3.O LEVEL ENGLISH"
120 PRINT TAB(8);"4.OTHER"
130 PRINT "TYPE 1,2,3 OR 4",
140 INPUT A
150 IF A<1 OR A>4 THEN 170
160 ON A GO TO 190,210,240,270
170 PRINT "ERROR YOU MAY ONLY TYPE 1,2,3 OR 4"
180 GO TO 140
190 PRINT "SCORE 100%,TEST ENDS NOW,WELCOME HOME"
200 GO TO 1570
210 PRINT "YOU LOOK A POSSIBILITY,SCORE 5"
220 LET T=T+5
230 GO TO 290
240 PRINT "TESTS SHOW ENGLISH IS THE BEST ADP START POINT,SCORE 7"
250 LET T=T+7
260 GO TO 290
270 PRINT "OH GOOD I LIKE BLANK PAGES,SCORE 5"
280 LET T=T+5
290 PRINT "QUESTION 2.DO YOU PREFER"
300 PRINT TAB(8);"1.GAMES,OR"
310 PRINT TAB(8);"2.READING BOOKS"
320 PRINT "TYPE 1 OR 2",
330 INPUT A
340 IF A<1 OR A>2 THEN 430
350 ON A GO TO 360,400
360 PRINT "GAMES PLAYERS MAKE BETTER COMPUTER USERS THAN BOOKWORMS"
370 PRINT "SCORE 10"
380 LET T=T+10
390 GO TO 450
400 PRINT "GOOD YOU SHOULD ENJOY STUDYING,SCORE 5"
410 LET T=T+5
420 GO TO 450
430 PRINT "ERROR,YOU MUST TYPE 1 OR 2"
440 GO TO 330
450 PRINT "QUESTION 3. ARE YOU EXTROVERT? ";Z$,
460 INPUT A$
470 IF A$=Y$ THEN 510
480 IF A$=N$ THEN 540
490 PRINT "ERROR YOU MUST ";Z$,
500 GO TO 460
510 PRINT "GOOD EXTROVERTS MAKE THE BEST COMPUTER USERS,SCORE 10"
520 LET T=T+10
530 GO TO 570
540 PRINT "PITY ,EXTROVERTS MAKE BETTER COMPUTER USERS"
550 PRINT "SCORE 2 FOR HONESTY"
560 LET T=T+2
570 PRINT "QUESTION 4. ARE YOU MALE? ";Z$,
580 INPUT A$
590 IF A$=Y$ THEN 630
600 IF A$=N$ THEN 660
610 PRINT "ERROR ,YOU MUST MAKE UP YOUR MIND"
620 GO TO 570
630 PRINT "GOOD,MORE MEN THAN WOMEN ARE TOP ADP EXPERTS,SCORE 5"
640 LET T=T+5
650 GO TO 690
660 PRINT "PITY ,MORE MEN THAN WOMEN ARE COMPUTER WHIZZKIDS"
670 PRINT "SCORE 10 FOR GOOD LOOKS"
680 LET T=T+10
690 PRINT "QUESTION 5.WHAT IS THE NEXT NUMBER IN THE SERIES"
700 PRINT "2,4,6,8,10,12,14,  ?",
710 INPUT A
720 IF A=16 THEN 770
730 PRINT "WHO DO YOU THINK YOU ARE FOOLING?"
740 PRINT "I TOLD YOU NOT TO CHEAT,SCORE 20"
750 LET T=T+20
760 GO TO 790
770 PRINT "WELL DONE CLEVER YOU,SCORE 5"
780 LET T=T+5
790 PRINT "QUESTION 6.DO YOU UNDERSTAND GREEK? ";Z$,
800 INPUT A$
810 IF A$=Y$ THEN 850
820 IF A$=N$ THEN 870
830 PRINT "ERROR"
840 GO TO 790
850 PRINT "I DON'T BELIEVE YOU,SCORE 5 FOR CHEEK"
860 GO TO 880
870 PRINT "ME NEITHER,FORTRAN YES GREEK NO,SCORE 5"
880 LET T=T+5
890 PRINT "QUESTION 7.DO YOU LIKE KISSING?"
900 PRINT "TYPE YES ,NO OR MAYBE",
910 INPUT A$
920 IF A$=Y$ THEN 970
930 IF A$=N$ THEN 1000
940 IF A$="MAYBE" THEN 1040
950 PRINT "ERROR YOU MUST TYPE YES ,NO OR MAYBE"
960 GO TO 910
970 PRINT "WHO LOVES YA BABY,SCORE 10"
980 LET T=T+10
990 GO TO 1070
1000 PRINT "AH THE CAUTIOUS TYPE,STILL IT COULD HAVE BEEN A HIPPO"
1010 PRINT "SCORE 5"
1020 LET T=T+5
1030 GO TO 1070
1040 PRINT "ALWAYS CHECK,WE DON'T WANT TWO FELLAHS KISSING DO WE"
1050 PRINT "SCORE 7"
1060 LET T=T+7
1070 PRINT "QUESTION 8.WHAT IS THE NEXT LETTER;S,S,M,T,W ?"
1080 PRINT "TYPE YOUR ANSWER",
1090 INPUT A$
1100 IF A$="T" THEN 1130
1110 PRINT "WRONG THE ANSWER IS T,FOR THURSDAY,SCORE 0"
1120 GO TO 1150
1130 PRINT "CORRECT,SCORE 5"
1140 LET T=T+5
1150 PRINT "QUESTION 9.WHICH IS THE ODD ONE OUT?"
1160 PRINT TAB(8);"1.OTTOWA"
1170 PRINT TAB(8);"2.CANBERRA"
1180 PRINT TAB(8);"3.PARIS"
1190 PRINT TAB(8);"4.NEW YORK"
1200 PRINT TAB(8);"5.BONN"
1210 PRINT "TYPE 1,2,3,4 OR 5",
1220 INPUT A
1230 IF A=4 THEN 1300
1240 IF A<1 OR A>5 THEN 1280
1250 PRINT "WRONG IT IS NEW YORK,IT IS NOT A CAPITAL,SCORE -5"
1260 LET T=T-5
1270 GO TO 1320
1280 PRINT "ERROR YOU MUST TYPE 1,2,3,4 OR 5"
1290 GO TO 1220
1300 PRINT "WELL DONE SCORE 5"
1310 LET T=T+5
1320 PRINT "QUESTION 10.WHAT IS THE MISSING NUMBER?"
1330 PRINT "2","5","7"
1340 PRINT "4","7","5"
1350 PRINT "3","6"
1360 PRINT "TYPE THE MISSING NUMBER",
1370 INPUT A
1380 IF A=6 THEN 1420
1390 PRINT "WRONG THE ANSWER IS 6"
1400 PRINT "SCORE 0"
1410 GO TO 1440
1420 PRINT "WELL DONE SCORE 6"
1430 LET T=T+6
1440 PRINT "YOU HAVE FINISHED THE TEST"
1450 PRINT "YOUR SCORE IS ";T
1460 IF T<30 THEN 1520
1470 IF T<50 THEN 1540
1480 IF T<80 THEN 1560
1490 IF T<88 THEN 1610
1500 PRINT "YOU HAVE SCORED A POSSIBLE -YOU'RE MY SORT OF PEOPLE"
1510 GO TO 1570
1520 PRINT "TAKE YOUR HANDS OFF ME YOU	'ORRIBLE FAILURE"
1530 GO TO 1570
1540 PRINT " YOU DON'T THRILL ME BUT YOU'LL DO"
1550 GO TO 1570
1560 PRINT "I LIKE YOU - GOOD SCORE"
1570 PRINT "DO YOU WANT ANOTHER GO? ";Z$,
1580 INPUT A$
1590 IF A$=Y$ THEN 40
1600 GO TO 1630
1610 PRINT "THIS IS AN EXCELLENT SCORE,MAX. POSSIBLE IS 88"
1620 GO TO 1570
1630 END
«eof»