DataMuseum.dk

top - download

    Length: 2432 (0x980)
    Types: TextFile
    Names: »ASEYDU.BAS«

└─⟦69a509965⟧ Bits:30005211 CR8 BASIC Games
    └─ ⟦this⟧ »ASEYDU.BAS« 

TextFile

1  REM PROGRAM ASEYDU.BAS
10 REM *** GAME OF ACEY-DUCEY WRITTEN BY BILL PALMBY
20 REM *** ADLAI STEVENSON HIGH SCHOOL, PRAIRE VIEW, ILL
30 REM *** TRANSLATED TO RSTS/E BY DAVE AHL, DIGITAL
40 RANDOMIZE
50 PRINT "ACEY-DUCEY IS PLAYED IN THE FOLLOWING MANNER:"
60 PRINT "THE DEALER (COMPUTER) DEALS TWO CARDS FACE UP."
70 PRINT "YOU HAVE THE OPTION TO BET OR NOT TO BET DEPENDING"
80 PRINT "ON WHETHER OR NOT YOU FEEL THE NEXT CARD WILL HAVE"
90 PRINT "A VALUE BETWEEN THE FIRST TWO."
100 PRINT "IF YOU DO NOT WANT TO BET, INPUT A 0."
110 PRINT 
120 N=100:Q=100
130 PRINT "YOU NOW HAVE";Q;"DOLLARS."
140 PRINT 
150 GO TO 200 
160 Q=Q+M
170 GO TO 130 
180 Q=Q-M
190 GO TO 130 
200 PRINT "HERE ARE YOUR NEXT TWO CARDS..."
210 A=INT(14*RND)+2
220 IF A<2 THEN 210 
230 IF A>14 THEN 210 
240 B=INT(14*RND)+2
250 IF B<2 THEN 240 
260 IF B>14 THEN 240 
270 IF A>=B THEN 210 
280 IF A<11 THEN 330 
290 IF A=11 THEN 350 
300 IF A=12 THEN 370 
310 IF A=13 THEN 390 
320 IF A=14 THEN 410 
330 PRINT A
340 GO TO 420 
350 PRINT "JACK"
360 GO TO 420 
370 PRINT "QUEEN"
380 GO TO 420 
390 PRINT "KING"
400 GO TO 420 
410 PRINT "ACE"
420 IF B<11 THEN 470 
430 IF B=11 THEN 490 
440 IF B=12 THEN 510 
450 IF B=13 THEN 530 
460 IF B=14 THEN 550 
470 PRINT B
480 GO TO 560 
490 PRINT "JACK"
500 GO TO 560 
510 PRINT "QUEEN"
520 GO TO 560 
530 PRINT "KING"
540 GO TO 560 
550 PRINT "ACE"
560 PRINT 
570 PRINT "WHAT IS YOUR BET";:INPUT M
580 IF M<>0 THEN 610 
590 PRINT "CHICKEN!!":PRINT 
600 GO TO 200 
610 IF M<=Q THEN 650 
620 PRINT "SORRY, MY FRIEND, BUT YOU BET TOO MUCH"
630 PRINT "YOU HAVE ONLY";Q;"DOLLARS TO BET."
640 GO TO 560 
650 C=INT(14*RND)+2
660 IF C<2 THEN 650 
670 IF C>14 THEN 650 
680 IF C<11 THEN 730 
690 IF C=11 THEN 750 
700 IF C=12 THEN 770 
710 IF C=13 THEN 790 
720 IF C=14 THEN 810 
730 PRINT C
740 GO TO 820 
750 PRINT "JACK"
760 GO TO 820 
770 PRINT "QUEEN"
780 GO TO 820 
790 PRINT "KING"
800 GO TO 820 
810 PRINT "ACE"
820 IF C>A THEN 840 
830 GO TO 870 
840 IF C>=B THEN 870 
850 PRINT "YOU WIN!!!"
860 GO TO 160 
870 PRINT "SORRY, YOU LOSE."
880 IF M<Q THEN 180 
890 PRINT 
900 PRINT "SORRY, FRIEND, BUT YOU BLEW YOUR WAD."
910 PRINT "TRY AGAIN (YES OR NO)";:INPUT A$
920 IF A$="YES" THEN 110 
930 PRINT :PRINT "O.K. HOPE YOU HAD FUN!!"
940 END
«eof»