DataMuseum.dk

top - download

    Length: 8320 (0x2080)
    Types: TextFile
    Names: »CIVIL.BAS«

└─⟦69a509965⟧ Bits:30005211 CR8 BASIC Games
    └─ ⟦this⟧ »CIVIL.BAS« 

TextFile

1  REM PROGRAM CIVIL.BAS
10 L=0:W=0:R1=0:P1=0:Q1=0:M3=0:M4=0:P2=0:T1=0:T2=0
20 REM RKABLE PROGRAM BY L. CRAM , L. GOODIE , AND D. HIBBARD 
30 PRINT "DO YOU WANT DESCRIPTIONS (0=YES, 1=NO)";
40 INPUT Z
50 FOR U=1 TO 6
60 PRINT 
70 NEXT U
80 IF Z=1 THEN 310 
90 PRINT "THIS IS A CIVIL WAR SIMULATION."
100 PRINT "TO PLAY, TYPE A RESPONSE WHEN THE COMPUTER ASKS."
110 PRINT "REMEMBER THAT ALL FACTORS ARE INTERRELATED AND THAT YOUR"
120 PRINT "RESPONSES COULD CHANGE HISTORY. FACTS AND FIGURES USED ARE"
130 PRINT "BASED ON THE ACTUAL OCCURENCE. MOST BATTLES TEND TO RESULT"
140 PRINT "AS THEY DID IN THE CIVIL WAR, BUT IT ALL DEPENDS ON YOU!!"
150 PRINT 
160 PRINT "THE OBJECT OF THE GAME IS TO WIN AS MANY BATTLES AS POSSIBLE"
170 PRINT 
180 PRINT "YOUR CHOICES FOR DEFENSIVE STRATEGY ARE:"
190 PRINT "	  (1) ARTILLERY ATTACK"
200 PRINT "	  (2) FORTIFICATION AGAINST FRONTAL ATTACK"
210 PRINT "	  (3) FORTIFICATION AGAINST FLANKING MANUEVERS"
220 PRINT "	  (4) FALLING BACK"
230 PRINT "YOUR CHOICES FOR OFFENSIVE STRATEGY ARE:"
240 PRINT "	  (1) ARTILLERY ATTACK"
250 PRINT "	  (2) FRONTAL ATTACK"
260 PRINT "	  (3) FLANKING MANUEVERS"
270 PRINT "	  (4) ENCIRCLEMENT"
280 PRINT "YOU MAY SURRENDER BY TYPING A '5' FOR YOUR STRATEGY."
290 PRINT 
300 PRINT "YOU ARE THE CONFEDERACY.	  GOOD LUCK!"
310 READ M1,M2,C1,C2,M,A,U
320 LET I1=10+(L-W)*2
330 LET I2=10+(W-L)*2
340 LET D1=100*INT((M1*(100-I1)/2000)*(1+(R1-Q1)/(R1+1))+.5)
350 LET D2=100*INT(M2*(100-I2)/2000+.5)
360 LET F1=5*M1/6
370 LET A1=Z
380 FOR U=1 TO 4
390 PRINT 
400 NEXT U
410 PRINT "THIS IS THE BATTLE OF ";
420 GOSUB 1420 
430 PRINT " ","CONFEDERACY","  UNION"
440 PRINT "MEN"," ";INT(M1*(1+(P1-T1)/(M3+1)))," ";
450 PRINT INT(M2*(1+(P2-T2)/(M4+1)))
460 PRINT "MONEY","$";D1,"$";D2
470 PRINT "INFLATION"," ";I1+15;"%"," ";I2;"%"
480 PRINT 
490 PRINT "HOW MUCH DO YOU WISH TO SPEND FOR FOOD";
500 INPUT F
510 IF F<0 THEN 1370 
520 PRINT "HOW MUCH DO YOU WISH TO SPEND FOR SALARIES";
530 INPUT S
540 IF S<0 THEN 1370 
550 PRINT "HOW MUCH DO YOU WISH TO SPEND FOR AMMUNITION";
560 INPUT B
570 IF B<0 THEN 1370 
580 PRINT 
590 IF F+S+B<=D1 THEN 620 
600 PRINT "THINK AGAIN!   YOU HAVE ONLY $";D1
610 GO TO 480 
620 LET O=((2*F^2+S^2)/F1^2+1)
630 IF O<10 THEN 660 
640 PRINT "MORALE IS HIGH"
650 GO TO 700 
660 IF O<5 THEN 690 
670 PRINT "MORALE IS FAIR"
680 GO TO 700 
690 PRINT "MORALE IS POOR"
700 IF M<>3 THEN 730 
710 PRINT "YOU ARE ON THE OFFENSIVE"
720 GO TO 770 
730 IF M<>1 THEN 760 
740 PRINT "YOU ARE ON THE DEFENSIVE"
750 GO TO 770 
760 PRINT "BOTH SIDES ARE ON THE OFFENSIVE"
770 PRINT 
780 PRINT "YOUR STRATEGY";
790 INPUT Y
800 IF Y=5 THEN 2270 
810 IF ABS(Y-3)<3 THEN 840 
820 PRINT "YOU JERK!  USE THE OTHER SET OF STRATEGIES!!"
830 GO TO 770 
840 PRINT 
850 PRINT " ","CONFEDERACY","UNION"
860 LET C5=(2*C1/5)*(1+1/(2*(ABS(INT(4*RND+1)-Y)+1)))
870 LET C5=INT(C5*(1+1/O)*(1.28+F1/(B+1))+.5)
880 IF C5+100/O<M1*(1+(P1-T1)/(M3+1)) THEN 930 
890 LET C5=INT(13*M1/20*(1+(P1-T1)/(M3+1)))
900 LET E=7*C5/13
910 LET U=1
920 GO TO 940 
930 LET E=100/O
940 PRINT "CASUALTIES",C5,INT(17*C2*C1/(C5*20)+.5)
950 PRINT "DESERTIONS",INT(E),INT(5*O)
960 PRINT 
970 IF C5-C1>=0 THEN 1000 
980 PRINT "YOUR CASUALTIES WERE";INT(100*(C1-C5)/C1+.5);"% LESS THAN"
990 GO TO 1010 
1000 PRINT "YOUR CASUALTIES WERE";INT(100*(C5-C1)/C1+.5);"% MORE THAN"
1010 PRINT "THE ACTUAL CASUALITIES AT ";
1020 LET A1=1
1030 GOSUB 1420 
1040 IF U=1 THEN 1060 
1050 IF C5+E<17*C2*C1/(C5*20)+5*O THEN 1090 
1060 PRINT "YOU LOSE ";
1070 LET L=L+1
1080 GO TO 1110 
1090 PRINT "YOU WIN ";
1100 LET W=W+1
1110 GOSUB 1420 
1120 IF W=8 THEN 2290 
1130 LET T1=T1+C5+E
1140 LET T2=T2+17*C2*C1/(C5*20)+5*O
1150 LET P1=P1+C1
1160 LET P2=P2+C2
1170 LET Q1=Q1+(F+S+B)
1180 LET R1=R1+M1*(100-I1)/20
1190 LET M3=M3+M1
1200 LET M4=M4+M2
1210 IF A=14 THEN 2300 
1220 GO TO 310 
1230 DATA 18000,18500,1967,2708,1,1,0
1240 DATA 40000,44894,10699,13047,3,2,0
1250 DATA 95000,115000,20614,15849,3,3,0
1260 DATA 54000,63000,10000,14000,2,4,0
1270 DATA 40000,50000,10000,12000,3,5,0
1280 DATA 75000,120000,5377,12653,1,6,0
1290 DATA 38000,45000,11000,12000,1,7,0
1300 DATA 32000,90000,13000,17197,2,8,0
1310 DATA 50000,70000,12000,19000,1,9,0
1320 DATA 72500,85000,20000,23000,3,10,0
1330 DATA 66000,60000,18000,16000,2,11,0
1340 DATA 37000,60000,6700,5800,2,12,0
1350 DATA 62000,110000,17723,18000,2,13,0
1360 DATA 65000,100000,8500,3700,1,14,0
1370 PRINT "GO TO JAIL."
1380 PRINT "GO DIRECTLY TO JAIL."
1390 PRINT "DO NOT PASS GO."
1400 PRINT "DO NOT COLLECT $200"
1410 GO TO 380 
1420 IF A<>1 THEN 1490 
1430 PRINT "BULL RUN"
1440 IF A1=1 THEN 2250 
1450 PRINT "JULY 21,1861    GEN. BEAUREGARD COMMANDING THE SOUTH MET THE"
1460 PRINT "UNION FORCES WITH GEN MCDOWELL IN A PREMATURE BATTLE AT BULL"
1470 PRINT "RUN.  GEN. JACKSON HELPED PUSH BACK THE UNION ATTACK."
1480 GO TO 2250 
1490 IF A<>2 THEN 1550 
1500 PRINT "SHILOH"
1510 IF A1=1 THEN 2250 
1520 PRINT "APRIL 6-7,1862    THE CONFEDERATE SURPRISE ATTACK AT SHILOH"
1530 PRINT "FAILED DUE TO POOR ORGANIZATION."
1540 GO TO 2250 
1550 IF A<>3 THEN 1620 
1560 PRINT "SEVEN DAYS"
1570 IF A1=1 THEN 2250 
1580 PRINT "JUNE 25-JULY 1,1862    GENERAL LEE (CSA) UPHELD THE OFFENSIVE"
1590 PRINT "THROUGHOUT THE BATTLE AND FORCED GEN. MCCLELLAN AND THE UNION"
1600 PRINT "FORCES AWAY FROM RICHMOND."
1610 GO TO 2250 
1620 IF A<>4 THEN 1680 
1630 PRINT "THE SECOND BULL RUN"
1640 IF A1=1 THEN 2250 
1650 PRINT "AUG 29-30,1862    THE COMBINED CONFEDERATE FORCES UNDER LEE AND"
1660 PRINT "JACKSON DROVE THE UNION FORCES BACK INTO WASHINGTON."
1670 GO TO 2250 
1680 IF A<>5 THEN 1740 
1690 PRINT "ANTIETAM"
1700 IF A1=1 THEN 2250 
1710 PRINT "SEPT 17,1862    THE SOUTH FAILED TO INCORPORATE MARYLAND INTO"
1720 PRINT "THE CONFEDERACY."
1730 GO TO 2250 
1740 IF A<>6 THEN 1800 
1750 PRINT "FREDERICKSBURG"
1760 IF A1=1 THEN 2250 
1770 PRINT "DEC 13,1862 THE CONFEDERACY UNDER LEE SUCESSFULLY REPULSED"
1780 PRINT "AN ATTACK BY THE UNION UNDER GEN. BURNSIDE."
1790 GO TO 2250 
1800 IF A<>7 THEN 1850 
1810 PRINT "MURFREESBORO"
1820 IF A1=1 THEN 2250 
1830 PRINT "DEC 31,1862    THE SOUTH UNDER GEN. BRAGG WON A CLOSE BATTLE"
1840 GO TO 2250 
1850 IF A<>8 THEN 1910 
1860 PRINT "CHANCELLORSVILLE"
1870 IF A1=1 THEN 2250 
1880 PRINT "MAY 1-6,1863    THE SOUTH HAD A COSTLY VICTORY AND LOST ONE"
1890 PRINT "OF THEIR OUTSTANDING GENERALS, 'STONEWALL' JACKSON."
1900 GO TO 2250 
1910 IF A<>9 THEN 1970 
1920 PRINT "VICKSBURG"
1930 IF A1=1 THEN 2250 
1940 PRINT "JULY 4,1863    VICKSBURG WAS A COSTLY DEFEAT FOR THE SOUTH"
1950 PRINT "BECAUSE IT GAVE THE UNION ACCESS TO THE MISSISSIPPI."
1960 GO TO 2250 
1970 IF A<>10 THEN 2030 
1980 PRINT "GETTYSBURG"
1990 IF A1=1 THEN 2250 
2000 PRINT "JUNE 30,1863    A SOUTHERN MISTAKE BY GEN. LEE AT GETTYSBURG"
2010 PRINT "COST THEM ONE OF THE MOST CRUCIAL BATTLES OF THR WAR."
2020 GO TO 2250 
2030 IF A<>11 THEN 2090 
2040 PRINT "CHICKAMAUGA"
2050 IF A1=1 THEN 2250 
2060 PRINT "NOV 25,1863    AFTER THE SOUTH HAD SIEGED GEN. ROSENCRANS'"
2070 PRINT "ARMY FOR THREE MONTHS, GEN. GRANT BROKE THE SIEGE."
2080 GO TO 2250 
2090 IF A<>12 THEN 2150 
2100 PRINT "CHATTANOOGA"
2110 IF A1=1 THEN 2250 
2120 PRINT "SEPT 15,1863    CONFUSION IN A FOREST NEAR CHICKAMAUGA LED"
2130 PRINT "TO A COSTLY SOUTHERN VICTORY."
2140 GO TO 2250 
2150 IF A<>13 THEN 2210 
2160 PRINT "SPOTSYLVANIA"
2170 IF A1=1 THEN 2250 
2180 PRINT "MAY 5,1864	  GRANT'S PLAN TO KEEP LEE ISOLATED BEGAN TO FAIL"
2190 PRINT "HERE, AND CONTINUED AT COLD HARBOR AND PETERSBURG."
2200 GO TO 2250 
2210 PRINT "ATLANTA"
2220 IF A1=1 THEN 2250 
2230 PRINT "AUGUST, 1864   SHERMAN AND THREE VETERAN ARMIES CONVERGED ON"
2240 PRINT "ATLANTA AND DEALT THE DEATH BLOW TO THE CONFEDERACY."
2250 PRINT 
2260 RETURN
2270 PRINT "THE CONFEDERACY HAS SURRENDERED"
2280 GO TO 2300 
2290 PRINT "THE UNION HAS SURRENDERED"
2300 PRINT 
2310 PRINT "YOU HAVE WON";W;"BATTLES AND LOST";L;"BATTLES."
2320 IF Y=5 THEN 2360 
2330 IF W<=L THEN 2360 
2340 PRINT "THE CONFEDERACY HAS WON THE WAR"
2350 STOP
2360 PRINT "THE UNION HAS WON THE WAR"
2370 END
«eof»