DataMuseum.dk

Presents historical artifacts from the history of:

DKUUG/EUUG Conference tapes

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about DKUUG/EUUG Conference tapes

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download
Index: T g

⟦bb534127e⟧ TextFile

    Length: 1192 (0x4a8)
    Types: TextFile
    Names: »grind2a-2f.bnf«

Derivation

└─⟦3d0c2be1b⟧ Bits:30001254 ISODE-5.0 Tape
    └─⟦eba4602b1⟧ »./isode-5.0.tar.Z« 
        └─⟦d3ac74d73⟧ 
            └─⟦this⟧ »isode-5.0/doc/manual/grind2a-2f.bnf« 
└─⟦2d1937cfd⟧ Bits:30007241 EUUGD22: P.P 5.0
    └─⟦35176feda⟧ »EurOpenD22/isode/isode-6.tar.Z« 
        └─⟦de7628f85⟧ 
            └─⟦this⟧ »isode-6.0/doc/manual/grind2a-2f.bnf«

TextFile

<presentation-address> ::=
		[[[ <psel> "/" ] <ssel> "/" ] <tsel> "/" ]
		<network-address-list>

<network-address-list> ::=
		<network-address> "|" <network-address-list>
	      | <network-address>

<psel> ::=	<selector>
<ssel> ::= 	<selector>
<tsel> ::= 	<selector>

<selector> ::=
		'"' <otherstring> '"'		-- IA5
						-- (for other chars use hex)
	      | "#" <digitstring>		-- US GOSIP
	      | "'" <hexstring> "'H"		-- hex
	      | ""				-- empty but present

<network-address> ::=
		"NS" "+" <hexstring>		-- concrete binary
						-- this is the compact
						--   encoding
	      | <afi> "+" <idi> [ "+" <dsp> ]


<afi>		::= "X121" | "DCC" | "TELEX" | "PSTN" | "ISDN"
			| "ICD" | "LOCAL"

<idi>		::= <digitstring>

<dsp>  ::=	"d" <digitstring>		-- abstract decimal
	      | "x" <hexstring>			-- abstract binary
	      | "l" <otherstring>		-- IA5: local form only
	      | "RFC-1006" "+" <prefix> "+" <ip>
			[ "+" <port> [ "+" <tset> ]]
	      | "X.25(80)" "+" <prefix> "+" <dte>
			[ "+" <cudf-or-pid> "+" <hexstring> ]
	      | "ECMA-117-Binary" "+" <hexstring> "+" <hexstring>
			"+" <hexstring>
	      | "ECMA-117-Decimal" "+" <digitstring> "+" <digitstring>
			"+" <digitstring>