⟦002702e3a⟧

Text

0100 DIM FNAVN$(25),FMKODE$(1),FUKODE$(1),DAT$(8),STREG$(71),VTAB2(5)
0110 DIM FMDEBET$(12),FMKREDIT$(12),FÅDEBET$(12),FÅKREDIT$(12),FSALDO$(12)
0120 DIM N$(6),BLANK$(77),A$(1),TAL4$(14),TAH$(12),OP1$(12),OP2$(12)
0130 DIM RES$(14),KTN$(7),BLB2$(12),UBLB2$(14),UD1$(14),UD2$(14),UD3$(14)
0140 DIM UD4$(14),K4$(17),K5$(17),T1(9),T2(9),K3$(17),K1$(17),K2$(17)
0150 PROC CALC(AT,B1,B2,ES)
0160 RES$=ES$;OP1$=B1$;OP2$=B2$;SI=0;FLAG=0;ART=AT
0170 CALL "P641210:REGN"
0180 ES$=RES$
0190 IF FLAG THEN STOP 
0200 ENDPROC 
0210 PROC FEJL(NR1,NR2,NR3)
0220 IF STATUS(NR3$)<>0 THEN 
0230 PRINT STATUS(NR3$),NR1,NR2,NR3$
0240 STOP 
0250 ENDIF 
0260 ENDPROC 
0270 PROC DKRTEST
0280 EXEC CALC(4,FÅDEBET$,FÅKREDIT$,TAL4$)
0290 IF SI<>0 THEN TEST=1
0300 IF FLAG<>0 THEN STOP 
0310 ENDPROC 
0320 PROC INDTAB(T,MANTAL,K10)
0330 J=MANTAL DIV 32+1
0340 FOR I=J TO MANTAL DIV 4+J-1
0350 H=(I-J)*4+1;J2=H+1;J3=H+2;J4=H+3
0360 GET K10$,I:T(H,1),T(H,2),T(J2,1),T(J2,2),T(J3,1),T(J3,2),T(J4,1),T(J4,2)
0370 EXEC FEJL(1,1,K10$)
0380 NEXT I
0390 ENDPROC 
0400 PROC UDTAB(U,MANTAL1,K9)
0410 J=MANTAL1 DIV 32+1
0420 FOR I=1 TO J-1
0430 H=(I-1)*32+1;J1=H+4;J2=H+8;J3=H+12;J4=H+16;J5=H+20;J6=H+24;J7=H+28
0440 PUT K9$,I:U(H,1),U(J1,1),U(J2,1),U(J3,1),U(J4,1),U(J5,1),U(J6,1),U(J7,1)
0450 EXEC FEJL(2,1,K9$)
0460 NEXT I
0470 FOR I=J TO MANTAL1 DIV 4+J-1
0480 H=(I-J)*4+1;J1=H+1;J2=H+2;J3=H+3
0490 PUT K9$,I:U(H,1),U(H,2),U(J1,1),U(J1,2),U(J2,1),U(J2,2),U(J3,1),U(J3,2)
0500 EXEC FEJL(2,2,K9$)
0510 NEXT I
0520 ENDPROC 
0530 PROC FINDPOST(TAB1,MANT1,NØGL1,PIL3)
0540 PIL1=MANT1 DIV 2;PIL3=PIL1;CEKS=1
0550 REPEAT 
0560 IF NØGL1=TAB1(PIL3,1) THEN 
0570 CEKS=0
0580 ELSE 
0590 IF PIL1=1 THEN PIL1=0
0600 PIL1=INT((PIL1+1)/2)
0610 IF NØGL1>TAB1(PIL3,1) THEN 
0620 PIL3=PIL3+PIL1
0630 ELSE 
0640 PIL3=PIL3-PIL1
0650 ENDIF 
0660 IF PIL3<1 THEN PIL3=1
0670 IF PIL3>MANT1 THEN PIL3=MANT1
0680 ENDIF 
0690 UNTIL CEKS=0 OR PIL1=0
0700 ENDPROC 
0710 PROC INDSÆT(TAB2,ANTAL2,NØGL2,PIL4)
0720 IF CEKS=1 THEN 
0730 POSTNR=TAB2(ANTAL2+1,2)
0740 IF NØGL2>TAB2(PIL4,1) AND TAB2(PIL4,1)<>1000000 THEN PIL4=PIL4+1
0750 FOR I=ANTAL2+1 TO PIL4+1 STEP -1
0760 TAB2(I,1)=TAB2(I-1,1)
0770 TAB2(I,2)=TAB2(I-1,2)
0780 NEXT I
0790 TAB2(PIL4,1)=NØGL2
0800 TAB2(PIL4,2)=POSTNR
0810 ANTAL2=ANTAL2+1
0820 ENDIF 
0830 ENDPROC 
0840 PROC SLETPOST(TAB3,ANTAL3,NØGL3,PIL5)
0850 IF CEKS=0 THEN 
0860 POSTNR=TAB3(PIL5,2)
0870 FOR I=PIL5 TO ANTAL3-1
0880 TAB3(I,1)=TAB3(I+1,1)
0890 TAB3(I,2)=TAB3(I+1,2)
0900 NEXT I
0910 TAB3(ANTAL3,1)=1000000
0920 TAB3(ANTAL3,2)=POSTNR
0930 ANTAL3=ANTAL3-1
0940 ENDIF 
0950 ENDPROC 
0960 PROC SLETFPOST(NØGLE3)
0970 EXEC FINDPOST(FTAB,MFANTAL,NØGLE3,FPIL3)
0980 IF CEKS=1 THEN STOP 
0990 FNR=0;FNAVN$=BLANK$(1:25);FMKODE$=" ";FUKODE$=" ";FMDEBET$="0+"
1000 FMKREDIT$="0+";FÅDEBET$="0+";FÅKREDIT$="0+"
1010 EXEC GEMFPOST
1020 EXEC SLETPOST(FTAB,AFIN,NØGLE3,FPIL3)
1030 ENDPROC 
1040 PROC HENTPOST
1050 S=FTAB(FPIL3,2)
1060 GET K3$,S:FNR,FNAVN$
1070 EXEC FEJL(3,2,K3$)
1080 IF FNR<>FTAB(FPIL3,1) THEN STOP 
1090 GET K3$,S+1:FMKODE$,FMDEBET$,FMKREDIT$
1100 EXEC FEJL(3,3,K3$)
1110 GET K3$,S+2:FUKODE$,FÅDEBET$,FÅKREDIT$
1120 EXEC FEJL(3,4,K3$)
1130 ENDPROC 
1140 PROC GEMFPOST
1150 S=FTAB(FPIL3,2)
1160 PUT K3$,S:FNR,FNAVN$
1170 EXEC FEJL(4,3,K3$)
1180 PUT K3$,S+1:FMKODE$,FMDEBET$,FMKREDIT$
1190 EXEC FEJL(4,4,K3$)
1200 PUT K3$,S+2:FUKODE$,FÅDEBET$,FÅKREDIT$
1210 EXEC FEJL(4,4,K3$)
1220 ENDPROC 
1230 PROC FINDTAST(FSTYR,FÆND,FNR2)
1240 IF FÆND<>1 THEN 
1250 CLEAR 
1260 CURSOR 21,1
1270 PRINT "Kontooplysninger"
1280 EXEC OVERSKRIFT
1290 CURSOR 2,3
1300 PRINT USING "1:Kontonr      : ######":FNR2
1310 ENDIF 
1320 REPEAT 
1330 CASE FSTYR OF 
1340 STOP 
1350 WHEN 2
1360 IF FÆND<>1 THEN 
1370 CURSOR 2,5
1380 PRINT "2:Kontonavn    :"
1390 FSTYR=3
1400 ENDIF 
1410 IF FÆND<>2 THEN 
1420 CURSOR 3,23
1430 PRINT "Kontonavn";BLANK$(1:29);"(max 25 tegn)";BLANK$(1:25)
1440 CURSOR 13,23
1450 INPUT FNAVN$
1460 ENDIF 
1470 CURSOR 19,5
1480 PRINT BLANK$(1:25)
1490 CURSOR 19,5
1500 PRINT FNAVN$
1510 WHEN 4
1520 IF ORD(FUKODE$)=48 THEN 
1530 IF FÆND<>1 THEN 
1540 CURSOR 2,9
1550 PRINT "4:Momskode     :"
1560 ENDIF 
1570 IF FÆND<>2 THEN 
1580 REPEAT 
1590 CURSOR 3,23
1600 PRINT "Momskode       (0:ingen moms,1:indgående afgift,";
1610 PRINT "2:udgående afgift          "
1620 CURSOR 13,23
1630 INPUT A$
1640 UNTIL (ORD(A$)>47 AND ORD(A$)<51)
1650 FMKODE$=A$
1660 ENDIF 
1670 CURSOR 19,9
1680 PRINT " "
1690 CURSOR 19,9
1700 PRINT FMKODE$
1710 ENDIF 
1720 FSTYR=5
1730 WHEN 3
1740 IF FÆND<>1 THEN 
1750 CURSOR 2,7
1760 PRINT "3:Udskriftskode:"
1770 ENDIF 
1780 IF FÆND<>2 THEN 
1790 IF FT=FNR2 OR FT1=FNR2 THEN 
1800 FUKODE$="2"
1810 ELSE 
1820 IF (FT<FNR2 AND FNR2<=FT+MKGR) OR (FT1<FNR2 AND FNR2<=FT1+MKRGR) THEN 
1830 FUKODE$="1"
1840 ELSE 
1850 REPEAT 
1860 CURSOR 3,23
1870 PRINT "Udskriftskode     (0:normal,1:undergruppe,2:hovedgruppe,3:subto";
1880 PRINT "tal)         "
1890 CURSOR 17,23
1900 INPUT A$
1910 UNTIL ORD(A$)>47 AND ORD(A$)<52
1920 FUKODE$=A$
1930 ENDIF 
1940 ENDIF 
1950 ENDIF 
1960 CURSOR 19,7
1970 PRINT " "
1980 CURSOR 19,7
1990 PRINT FUKODE$
2000 IF ORD(FUKODE$)>48 THEN 
2010 FSTYR=5
2020 ELSE 
2030 FSTYR=4
2040 ENDIF 
2050 ENDCASE 
2060 IF FÆND=1 THEN FSTYR=5
2070 UNTIL FSTYR=5
2080 IF (FT<FNR2 AND FNR2<=FT+MKGR) OR (FT1<FNR2 AND FNR2<=FT1+MKRGR) THEN 
2090 FT2=1
2100 ELSE 
2110 FT2=0
2120 ENDIF 
2130 IF FÆND<>1 AND (ORD(FUKODE$)=48 OR FT2=1) THEN 
2140 CURSOR 20,11
2150 PRINT "Debet"
2160 CURSOR 35,11
2170 PRINT "Kredit"
2180 CURSOR 53,11
2190 PRINT "Saldi"
2200 CURSOR 4,13
2210 PRINT "Månedens :"
2220 CURSOR 15,13
2230 EXEC TUD(FMDEBET$,TAL4$,0,0)
2240 CURSOR 31,13
2250 EXEC TUD(FMKREDIT$,TAL4$,0,0)
2260 CURSOR 48,13
2270 EXEC CALC(0,FMDEBET$,FMKREDIT$,FSALDO$)
2280 EXEC TUD(FSALDO$,TAL4$,1,0)
2290 CURSOR 4,15
2300 PRINT "Årets    :"
2310 CURSOR 15,15
2320 EXEC TUD(FÅDEBET$,TAL4$,0,0)
2330 CURSOR 31,15
2340 EXEC TUD(FÅKREDIT$,TAL4$,0,0)
2350 CURSOR 48,15
2360 EXEC CALC(0,FÅDEBET$,FÅKREDIT$,FSALDO$)
2370 EXEC TUD(FSALDO$,TAL4$,1,0)
2380 ENDIF 
2390 ENDPROC 
2400 PROC TUD(BLB1,UBLB1,TEGN,STØR)
2410 BLB2$=BLB1$;UBLB2$=UBLB1$
2420 EXEC CALC(5,BLB2$,TAH$,UBLB2$)
2430 UBLB1$=UBLB2$
2440 IF TEGN=0 THEN 
2450 UBLB1$=UBLB1$(1:13)
2460 ELSE 
2470 IF TEGN=1 AND UBLB1$(LEN(UBLB1$))="+" THEN 
2480 UBLB1$(LEN(UBLB1$))=" "
2490 ENDIF 
2500 IF STØR=1 THEN 
2510 UBLB1$=UBLB1$(4:LEN(UBLB1$)-3)
2520 ENDIF 
2530 ENDIF 
2540 PRINT UBLB1$
2550 ENDPROC 
2560 PROC NRTEST(NUM1)
2570 P=0;TEST2=0;KTAL=0;L=LEN(NUM1$)
2580 CASE L OF 
2590 FOR I=1 TO L
2600 P1=INT(ORD(NUM1$(I))-48)
2610 IF P1=>0 AND P1<=9 THEN 
2620 P=P*10+P1
2630 ELSE 
2640 TEST2=1
2650 ENDIF 
2660 NEXT I
2670 KTAL=P DIV 10000;KTAL9=P DIV 1000
2680 IF KTAL9=KRTAL THEN KTAL=KRTAL
2690 WHEN 0
2700 P=-1
2710 WHEN 1
2720 CASE NUM1$ OF 
2730 P=INT(ORD(NUM1$)-48)
2740 WHEN "j","J"
2750 P=-7
2760 WHEN "n","N"
2770 P=-8
2780 ENDCASE 
2790 ENDCASE 
2800 ENDPROC 
2810 PROC OVERSKRIFT
2820 CURSOR 45,1
2830 CASE TYPE OF 
2840 WHEN 1
2850 PRINT "Oprettelse"
2860 WHEN 2
2870 PRINT "Ændring"
2880 WHEN 3
2890 PRINT "Sletning"
2900 WHEN 4
2910 PRINT "Udskrift"
2920 WHEN 5
2930 PRINT "Finanskontoliste"
2940 ENDCASE 
2950 ENDPROC 
2960 K1$="P641220:SYSTEM1"
2970 OPEN K1$,R
2980 EXEC FEJL(9,1,K1$)
2990 GET K1$,1:MFANTAL
3000 EXEC FEJL(9,2,K1$)
3010 GET K1$,4:MKRMID,MFAK,MVGR,MKGR
3020 EXEC FEJL(9,3,K1$)
3030 GET K1$,5:MKRGR
3040 EXEC FEJL(9,4,K1$)
3050 GET K1$,8:DIVNR,DIVDNR,DIFNR,DTAL
3060 EXEC FEJL(9,5,K1$)
3070 GET K1$,9:KRTAL
3080 EXEC FEJL(9,6,K1$)
3090 GET K1$,10:N$
3100 EXEC FEJL(9,7,K1$)
3110 GET K1$,11:K2$
3120 EXEC FEJL(9,8,K1$)
3130 GET K1$,15:K3$
3140 EXEC FEJL(9,9,K1$)
3150 GET K1$,36:K4$
3160 EXEC FEJL(9,10,K1$)
3170 CLOSE K1$
3180 EXEC FEJL(9,11,K1$)
3190 DIM FTAB(MFANTAL,2)
3200 K4$=N$+K4$
3210 OPEN K4$,W
3220 EXEC FEJL(9,12,K4$)
3230 GET K4$,2:T1(1),T1(2),T1(3),T1(4),T1(5),T1(6),DATO
3240 EXEC FEJL(9,13,K4$)
3250 GET K4$,14:AFIN,ADEB,AKRE,VTAB2(1),VTAB2(2),VTAB2(3),VTAB2(4),VTAB2(5)
3260 EXEC FEJL(9,14,K4$)
3270 GET K4$,17:T2(1),T2(2),T2(3),T2(4),T2(5),T2(6),T2(7),T2(8),T2(9)
3280 EXEC FEJL(9,15,K4$)
3290 T2(4)=1
3300 PUT K4$,17:T2(1),T2(2),T2(3),T2(4),T2(5),T2(6),T2(7),T2(8),T2(9)
3310 EXEC FEJL(9,16,K4$)
3320 CLOSE K4$
3330 EXEC FEJL(9,17,K4$)
3340 K2$=N$+K2$
3350 OPEN K2$,W
3360 EXEC FEJL(9,18,K2$)
3370 K3$=N$+K3$
3380 OPEN K3$,W
3390 EXEC FEJL(9,19,K3$)
3400 EXEC INDTAB(FTAB,MFANTAL,K2$)
3410 BLANK$="                                      ";BLANK$=BLANK$+BLANK$+" "
3420 TAH$="0+";TAL4$="0+";FT=DTAL*10000;FT1=KRTAL*1000
3430 STREG$="-----------------------------------";STREG$=STREG$+STREG$
3440 REPEAT 
3450 CLEAR 
3460 CURSOR 21,1
3470 PRINT "Kontovedligeholdelse"
3480 CURSOR 2,3
3490 PRINT "0:Færdig"
3500 CURSOR 2,5
3510 PRINT "1:Oprettelse"
3520 CURSOR 2,7
3530 PRINT "2:Ændring"
3540 CURSOR 2,9
3550 PRINT "3:Sletning"
3560 CURSOR 2,11
3570 PRINT "4:Udskrift"
3580 CURSOR 2,13
3590 PRINT "5:Finanskontoliste"
3600 REPEAT 
3610 CURSOR 4,15
3620 PRINT "Vælg type     (0-5)"
3630 CURSOR 14,15
3640 INPUT A$
3650 EXEC NRTEST(A$)
3660 UNTIL P>-1 AND P<6
3670 TYPE=P
3680 IF TYPE=0 THEN EXIT 
3690 REPEAT 
3700 EXEC OVERSKRIFT
3710 TEST=0;KONT=1
3720 IF TYPE<5 THEN 
3730 REPEAT 
3740 REPEAT 
3750 CURSOR 3,23
3760 PRINT "Indtast nyt kontonr        (0:for færdig)";BLANK$(1:35)
3770 CURSOR 22,23
3780 INPUT KTN$
3790 EXEC NRTEST(KTN$)
3800 FT2=0
3810 IF (FT+MKGR=>P AND FT<=P) OR (FT1+MKRGR=>P AND FT1<=P) THEN FT2=1
3820 UNTIL (((KTAL<>DTAL AND KTAL<>KRTAL) OR FT2=1) AND L=5) OR P=0
3830 KONT=P
3840 IF KONT=0 THEN EXIT 
3850 EXEC FINDPOST(FTAB,MFANTAL,KONT,FPIL3)
3860 REPEAT 
3870 CURSOR 44,23
3880 IF (CEKS=0 AND TYPE<>1) OR (CEKS=1 AND TYPE=1 AND AFIN<MFANTAL) THEN 
3890 PRINT BLANK$(1:35)
3900 P=-1
3910 ELSE 
3920 IF CEKS=1 AND TYPE=1 AND AFIN=>MFANTAL THEN 
3930 CURSOR 3,23
3940 INPUT "Ikke plads til flere konti , tast RETURN                 ",A$
3950 ELSE 
3960 IF CEKS=0 THEN 
3970 INPUT "Konto eksisterer ,tast RETURN      ",A$
3980 ELSE 
3990 INPUT "Konto eksisterer ikke , tast RETURN",A$
4000 ENDIF 
4010 ENDIF 
4020 EXEC NRTEST(A$)
4030 ENDIF 
4040 UNTIL P=-1
4050 UNTIL (CEKS=0 AND TYPE<>1) OR (CEKS=1 AND TYPE=1 AND AFIN<MFANTAL)
4060 IF KONT=0 THEN EXIT 
4070 IF TYPE<>1 THEN 
4080 FNR=KONT
4090 EXEC HENTPOST
4100 IF TYPE=3 THEN EXEC DKRTEST
4110 IF TEST<>0 THEN EXIT 
4120 EXEC FINDTAST(2,2,FNR)
4130 ELSE 
4140 FNR=KONT;FNAVN$=BLANK$(1:25);FMKODE$=" ";FMDEBET$="0+";FMKREDIT$="0+"
4150 FUKODE$=" ";FÅDEBET$="0+";FÅKREDIT$="0+"
4160 EXEC FINDTAST(2,0,FNR)
4170 ENDIF 
4180 ENDIF 
4190 IF KONT=0 THEN EXIT 
4200 IF TEST=0 THEN 
4210 CASE TYPE OF 
4220 STOP 
4230 WHEN 1,2
4240 REPEAT 
4250 REPEAT 
4260 CURSOR 3,23
4270 PRINT "Hvilket felt ønskes ændret      (Indtast feltnr 2-4, ";
4280 PRINT "0:for færdig)          "
4290 CURSOR 32,23
4300 INPUT A$
4310 EXEC NRTEST(A$)
4320 UNTIL P=0 OR (P>1 AND P<5)
4330 STYR1=P
4340 IF STYR1=0 THEN EXIT 
4350 EXEC FINDTAST(STYR1,1,FNR)
4360 UNTIL STYR1=0
4370 IF TYPE=1 THEN 
4380 EXEC FINDPOST(FTAB,MFANTAL,FNR,FPIL3)
4390 EXEC INDSÆT(FTAB,AFIN,FNR,FPIL3)
4400 ENDIF 
4410 EXEC GEMFPOST
4420 WHEN 3
4430 REPEAT 
4440 CURSOR 3,23
4450 PRINT "Er det rigtigt at denne konto skal slettes";
4460 PRINT "      (J/N)";BLANK$(1:23)
4470 CURSOR 48,23
4480 INPUT A$
4490 EXEC NRTEST(A$)
4500 UNTIL P=-7 OR P=-8
4510 IF P=-7 THEN 
4520 EXEC SLETFPOST(KONT)
4530 ENDIF 
4540 WHEN 4
4550 WHEN 5
4560 REPEAT 
4570 REPEAT 
4580 CURSOR 3,23
4590 PRINT "Fra kontonr        (0: Alle)"
4600 CURSOR 15,23
4610 INPUT KTN$
4620 EXEC NRTEST(KTN$)
4630 UNTIL L=5 AND P>9999 AND TEST2=0 OR P=0
4640 IF P=0 THEN 
4650 FRA=1;TIL=AFIN
4660 ELSE 
4670 KONT=P
4680 EXEC FINDPOST(FTAB,MFANTAL,P,FPIL3)
4690 FRA=FPIL3
4700 ENDIF 
4710 UNTIL FRA<=AFIN
4720 IF P>0 THEN 
4730 REPEAT 
4740 CURSOR 3,23
4750 PRINT "Til kontonr                            "
4760 CURSOR 15,23
4770 INPUT KTN$
4780 EXEC NRTEST(KTN$)
4790 UNTIL L=5 AND P>9999 AND TEST2=0 AND P=>KONT
4800 EXEC FINDPOST(FTAB,MFANTAL,P,FPIL3)
4810 IF CEKS=1 THEN FPIL3=FPIL3-1
4820 TIL=FPIL3
4830 ENDIF 
4840 CLEAR 
4850 REPEAT 
4860 CURSOR 8,13
4870 INPUT "Monter papir til udskrift af finanskontoliste og tast RETURN",A$
4880 UNTIL ORD(A$)=255
4890 OUTPUT P
4900 SIDE=1
4910 DA1=DATO
4920 DAT$="        "
4930 FOR J=8 TO 1 STEP -1
4940 IF J MOD 3=0 THEN 
4950 DAT$(J)="."
4960 ELSE 
4970 DAT$(J)=CHR(DA1 MOD 10+48)
4980 DA1=DA1 DIV 10
4990 ENDIF 
5000 NEXT J
5010 FOR I=FRA TO TIL STEP 5
5020 PRINT TAB(10);CHR(14);"Finanskontoliste";CHR(15);TAB(36);"Dato : ";DAT$;
5030 PRINT USING "   Side :####":SIDE
5040 PRINT " "
5050 SIDE=SIDE+1
5060 FOR FPIL3=I TO I+4
5070 IF FTAB(FPIL3,1)<>0 THEN 
5080 EXEC HENTPOST
5090 EXEC CALC(5,FMDEBET$,TAH$,UD1$)
5100 EXEC CALC(5,FMKREDIT$,TAH$,UD2$)
5110 EXEC CALC(5,FÅDEBET$,TAH$,UD3$)
5120 EXEC CALC(5,FÅKREDIT$,TAH$,UD4$)
5130 PRINT TAB(9);STREG$
5140 PRINT TAB(9);"NAVN";TAB(39);"UDSKIFTSKODE";TAB(66);"MOMSKODE"
5150 PRINT " "
5160 PRINT USING "######  ":FNR;
5170 PRINT FNAVN$;TAB(45);FUKODE$;TAB(70);FMKODE$
5180 PRINT " "
5190 PRINT TAB(16);"MÅNEDENS BEVÆGELSER";TAB(59);"ÅRETS BEVÆGELSER"
5200 PRINT " "
5210 PRINT TAB(9);UD1$(1:13);"    ";UD2$(1:13);TAB(49);UD3$(1:13);"    ";
5220 PRINT UD4$(1:13)
5230 PRINT " "
5240 ENDIF 
5250 IF FPIL3=TIL THEN EXIT 
5260 NEXT FPIL3
5270 IF FPIL3=TIL THEN EXIT 
5280 PRINT " "
5290 NEXT I
5300 FOR J=FPIL3+1 TO I+4
5310 PRINT CHR(10)
5320 PRINT CHR(10)
5330 PRINT CHR(10)
5340 PRINT CHR(10)
5350 PRINT " "
5360 NEXT J
5370 PRINT " "
5380 OUTPUT T
5390 KONT=0
5400 ENDCASE 
5410 ELSE 
5420 REPEAT 
5430 CURSOR 3,23
5440 PRINT "Denne kode kan ikke slettes, da saldoen ikke er udlignet,";
5450 PRINT " tryk RETURN      "
5460 INPUT A$
5470 EXEC NRTEST(A$)
5480 UNTIL P=-1
5490 ENDIF 
5500 UNTIL KONT=0
5510 UNTIL TYPE=0
5520 EXEC UDTAB(FTAB,MFANTAL,K2$)
5530 CLOSE K2$
5540 EXEC FEJL(9,30,K2$)
5550 CLOSE K3$
5560 EXEC FEJL(9,31,K3$)
5570 OPEN K4$,W
5580 EXEC FEJL(9,32,K4$)
5590 PUT K4$,14:AFIN,ADEB,AKRE,VTAB2(1),VTAB2(2),VTAB2(3),VTAB2(4),VTAB2(5)
5600 EXEC FEJL(9,33,K4$)
5610 T2(4)=0
5620 PUT K4$,17:T2(1),T2(2),T2(3),T2(4),T2(5),T2(6),T2(7),T2(8),T2(9)
5630 EXEC FEJL(9,34,K4$)
5640 CLOSE K4$
5650 EXEC FEJL(9,35,K4$)
5660 CHAIN "P641210:OPSTART"
DataMuseum.dk

MIKADOS

⟦002702e3a⟧

Derivation

Text
