DataMuseum.dk

top - download

    Length: 5056 (0x13c0)
    Notes: Mikados TextFile, Mikados_K
    Names: »SKOPI«

└─⟦ec8c1e0b0⟧ Bits:30007442 8" floppy ( MIKPROG vol. 1-3, MIKREL vol. 1-3, PCSE 4.7.80 vol 1-3, GL.SYS )
    └─⟦this⟧ »SKOPI« 

Text

0100 DIM A$(3),DREVFRA$(2),DREVTIL$(2),TYPE$(1),K1$(17),PL1$(3),PL2$(3)
0110 DIM K$(26,11),NAVNFRA$(8),FRANAVN$(29,8),TILNAVN$(29,8),NAVNTIL$(8)
0120 PROC COPY
0130 FLAG=0
0140 CALL "P641215:CFCOPY"
0150 ENDPROC 
0160 PROC FEJL(NR1,NR2,NR3)
0170 IF STATUS(NR3$)<>0 THEN 
0180 PRINT STATUS(NR3$),NR1,NR2,NR3$
0190 STOP 
0200 ENDIF 
0210 ENDPROC 
0220 PROC NRTEST(NUM1)
0230 P=0;TEST2=0;KTAL=0;L=LEN(NUM1$)
0240 IF L>6 THEN EXIT 
0250 CASE L OF 
0260 FOR I=1 TO L
0270 P1=INT(ORD(NUM1$(I))-48)
0280 IF P1<0 OR P1>9 THEN TEST2=1
0290 P=P*10+P1
0300 NEXT I
0310 KTAL=P DIV 10000
0320 WHEN 0
0330 P=-1
0340 WHEN 1
0350 CASE NUM1$ OF 
0360 P=INT(ORD(NUM1$)-48)
0370 WHEN "d","D"
0380 P=-2
0390 WHEN "a","A"
0400 P=-3
0410 WHEN "m","M"
0420 P=-4
0430 WHEN "j","J"
0440 P=-7
0450 WHEN "n","N"
0460 P=-8
0470 ENDCASE 
0480 ENDCASE 
0490 ENDPROC 
0500 K1$="P641220:SYSTEM1"
0510 OPEN K1$,R
0520 EXEC FEJL(9,1,K1$)
0530 FOR I=1 TO 26
0540 GET K1$,I+10:K$(I)
0550 EXEC FEJL(9,2,K1$)
0560 NEXT I
0570 CLOSE K1$
0580 EXEC FEJL(9,3,K1$)
0590 DREVFRA$="P1";DREVTIL$="P2";TYPE$="K"
0600 REPEAT 
0610 REPEAT 
0620 OUTPUT T
0630 CLEAR 
0640 CURSOR 20,1
0650 PRINT "Sikkerhedskopiering"
0660 CURSOR 15,4
0670 PRINT "Det gælder nu om at udvise stor omhyggelighed"
0680 CURSOR 15,5
0690 INPUT "Og gøre nøjagtigt som angivet ; tast RETURN",A$
0700 CURSOR 15,6
0710 INPUT "Fjern alle plader fra løbeværkerne og tast RETURN",A$
0720 REPEAT 
0730 CURSOR 15,8
0740 PRINT "Hvilken plade ønskes kopieret fra      (10-33,0:færdig)"
0750 CURSOR 49,8
0760 INPUT PL1$
0770 EXEC NRTEST(PL1$)
0780 UNTIL (P=0 OR (P MOD 10<4 AND P DIV 10>0 AND P DIV 10<4)) AND TEST2=0
0790 P2=P DIV 10
0800 IF P=0 THEN EXIT 
0810 CURSOR 15,10
0820 PRINT "Isæt plade nr ";PL1$;" i løbeværk nr 1(øverst) og tast RETURN"
0830 CURSOR 70,10
0840 INPUT " ",A$
0850 REPEAT 
0860 CURSOR 15,12
0870 PRINT "Hvilken plade ønskes kopieret til      (10-33)"
0880 CURSOR 49,12
0890 INPUT PL2$
0900 EXEC NRTEST(PL2$)
0910 P3=P DIV 10
0920 UNTIL P MOD 10<4 AND P3>0 AND P3<4 AND TEST2=0 AND P3=P2
0930 CURSOR 15,14
0940 PRINT "Isæt plade nr ";PL2$;" i løbeværk nr 2 og tast RETURN"
0950 CURSOR 62,14
0960 INPUT " ",A$
0970 REPEAT 
0980 CURSOR 15,16
0990 PRINT "Ønskes kopieret fra plade nr ";PL1$;" til plade nr ";PL2$;
1000 PRINT " (J/N)"
1010 CURSOR 70,16
1020 INPUT A$
1030 EXEC NRTEST(A$)
1040 UNTIL P=-7 OR P=-8
1050 UNTIL P=-7
1060 IF P=0 THEN EXIT 
1070 J=0;FLAG=0
1080 FOR I=1 TO 26
1090 IF K$(I,1)=PL1$(1) THEN 
1100 J=J+1
1110 FRANAVN$(J)=K$(I,4:LEN(K$(I))-3);TILNAVN$(J)=FRANAVN$(J)
1120 IF PL1$(2)<>"0" THEN FRANAVN$(J)=FRANAVN$(J)+PL1$(2)
1130 IF PL2$(2)<>"0" THEN TILNAVN$(J)=TILNAVN$(J)+PL2$(2)
1140 ENDIF 
1150 NEXT I
1160 IF P2=2 THEN J=J+1;FRANAVN$(J)="SYSTEM1";TILNAVN$(J)=FRANAVN$(J)
1210 CURSOR 15,18
1220 IF J=0 THEN 
1230 PRINT "Der er ingen data på plade nr ";PL1$;
1240 PRINT " der kan kopieres,tast RETURN"
1250 CURSOR 76,18
1260 INPUT " ",A$
1270 ELSE 
1280 FOR I=1 TO J
1290 NAVNFRA$=FRANAVN$(I);NAVNTIL$=TILNAVN$(I)
1300 EXEC COPY
1310 IF FLAG THEN EXIT 
1320 NEXT I
1330 CASE FLAG OF 
1340 PRINT "Uidentificeret fejl tilkald hjælp.Fejlkode: ";FLAG
1350 STOP 
1360 WHEN 0
1370 WHEN 1
1380 PRINT "Pladen i løbeværk nr 1 er ikke den opgivne eller"
1390 CURSOR 15,19
1400 PRINT "Pladen indeholder ingen data"
1410 WHEN 3,14
1420 PRINT "Pladen i løbeværk nr 2 er ikke den opgivne"
1430 WHEN 40
1440 PRINT "Et af løbeværkerne er ikke klar"
1450 CURSOR 15,19
1460 PRINT "Klappen åben, mangler pladen eller pladen vendt forkert"
1470 ENDCASE 
1480 ENDIF 
1490 CURSOR 15,21
1500 INPUT "Ønskes ny kopiering (J/N)",A$
1510 EXEC NRTEST(A$)
1520 UNTIL P=-8
1530 CURSOR 15,23
1540 INPUT "Kopieringen er afsluttet isæt plade 10,20 og 30, tast RETURN",A$
1550 CHAIN "P641210:OPSTART"