DataMuseum.dk

top - download

    Length: 5056 (0x13c0)
    Notes: Mikados TextFile, Mikados_K
    Names: »HESTSPIL«

└─⟦0ca3cf8fa⟧ Bits:30004600 DEMO1 - COMAL demoprogram
    └─ ⟦this⟧ »HESTSPIL« 

Text

0100 REM --  H E S T E V Æ D D E L Ø B  --
0110 REM SPC/1 COMAL.  STEEN OLSEN 20.02.80
0120 REM 
0130 REM 
0150 DIM HESTE(5),SVAR$(1)
0160 CLEAR 
0170 CURSOR 20,3
0180 ; "H E S T E V Æ D D E L Ø B  "
0190 CURSOR 20,4
0200 ; "-------------------------"
0210 CURSOR 5,20
0220 ; "I DETTE SPIL KAN DU SPILLER ET BELØB PÅ EN HEST, DER DELTAGER"
0230 CURSOR 5,21
0240 ; "I ET HESTEVÆDDELØB. UD FRA HESTENES SLUTPLACERING BEREGNES ODDS"
0250 CURSOR 5,22
0260 ; "OG DU TILDELES EVT. GEVINST."
0270 CURSOR 5,23
0280 INPUT "TAST RETURN, NÅR DU ER KLAR  ",SVAR$
0290 REPEAT 
0300 KAPITAL=1E4
0310 REPEAT 
0320 CLEAR 
0330 ODDS,SLUT,FLYTTALLER=0
0340 FOR TAL=1 TO 5
0350 HESTE(TAL)=0
0360 EXEC SKRIVSTREG(TAL)
0370 EXEC SKRIVHEST(7,TAL)
0380 NEXT TAL
0390 FOR TAL1=1 TO 20
0400 CURSOR 79,TAL1
0410 ; "<S>!"
0420 NEXT TAL1
0430 CURSOR 5,22
0440 ; "KAPITAL TIL RÅDIGHED:  ";KAPITAL;" KR."
0450 REPEAT 
0460 CURSOR 5,23
0470 SPILHEST,INDSATS=0
0480 EDIT "HVILKEN HEST SPILLER DU PÅ: ",SPILHEST
0490 UNTIL SPILHEST>0 AND SPILHEST<6 AND SPILHEST=INT(SPILHEST)
0500 REPEAT 
0510 CURSOR 40,23
0520 EDIT "HVOR MEGET (I KR.): ",INDSATS
0530 UNTIL INDSATS<=KAPITAL AND INDSATS>0
0540 KAPITAL=KAPITAL-INDSATS
0550 REPEAT ;KØR IGENNEM TIL VINDERHEST ER FUNDET
0560 TAL=0
0570 REPEAT 
0580 FLYT=RND(0);TAL=TAL+1;FLYTTALLER=FLYTTALLER+1
0590 IF FLYT<.7 THEN 
0600 HESTPOSITION=HESTE(TAL)+7
0610 EXEC SLETHEST(HESTPOSITION,TAL)
0620 HESTE(TAL)=HESTE(TAL)+1
0630 IF FLYTTALLER>50 THEN 
0640 FLYT=RND(0)
0650 IF FLYT>.7 THEN FLYTTALLER=FLYTTALLER+1;HESTE(TAL)=HESTE(TAL)+1
0660 ENDIF 
0670 HESTPOSISITION=HESTE(TAL)+7
0680 EXEC SKRIVHEST(HESTPOSITION,TAL)
0690 IF FLYTTALLER>300 THEN 
0700 TAL1=1
0710 REPEAT 
0720 IF HESTE(TAL1)=>70 THEN SLUT=1
0730 IF SLUT<>1 THEN TAL1=TAL1+1
0740 UNTIL TAL1>5 OR SLUT
0750 ENDIF 
0760 ENDIF 
0770 UNTIL TAL=>5 OR SLUT
0780 UNTIL SLUT
0790 TAL=70;OK=0
0800 REPEAT 
0810 TAL=TAL-1;TAL2=0;OK=0
0820 REPEAT 
0830 TAL2=TAL2+1
0840 IF TAL2<>TAL1 THEN IF HESTE(TAL2)=TAL THEN OK=1
0850 UNTIL OK=1 OR TAL2=>5
0860 UNTIL OK=1
0870 ODDS=INT(EXP(1/(HESTE(TAL2)-70))*20+1)
0880 IF SPILHEST=TAL1 THEN 
0890 CURSOR 5,22
0900 ; "<S>                                                            "
0910 CURSOR 5,22
0920 ; "DIN HEST (NR.";TAL1;" VANDT";CHR(7);"  MED ODDS:  ";ODDS
0930 CURSOR 5,23
0940 ; "<S>                                                            "
0950 KAPITAL=KAPITAL+ODDS*INDSATS
0960 CURSOR 5,23
0970 ; "DU VANDT:  ";ODDS*INDSATS;" KR.,  OG HAR NU :  ";KAPITAL;" KR."
0980 ELSE 
0990 CURSOR 5,22
1000 ; "<S>                                                          "
1010 CURSOR 5,22
1020 ; "DIN HEST VANDT IKKE";CHR(7);"    ODDS BLEV:  ";ODDS
1030 CURSOR 5,23
1040 ; "<S>                                                          "
1050 CURSOR 5,23
1060 ; "VINDER BLEV HEST NR.:  ";TAL1;"  DIN KAPITAL:  ";KAPITAL;" KR."
1070 ENDIF 
1080 IF KAPITAL>0 THEN 
1090 CURSOR 5,24
1100 INPUT "VIL DU SPILLE IGEN  ",SVAR$
1110 ENDIF 
1120 UNTIL SVAR$<>"J" AND SVAR$<>"j" OR KAPITAL=0
1130 CURSOR 5,24
1140 IF KAPITAL>0 THEN 
1150 INPUT "VIL DU PRØVE FORFRA  ",SVAR$
1160 ELSE 
1170 INPUT "SLUT MED PENGENE,  VIL DU PRØVE FORFRA  ",SVAR$
1180 ENDIF 
1190 UNTIL SVAR$<>"J" AND SVAR$<>"j"
1200 PROC SKRIVSTREG(I)
1210 CURSOR 1,I*4
1220 FOR J=1 TO 79
1230 ; "<S>-"
1240 NEXT J
1250 CURSOR 79,I*4-2
1260 ; I
1270 ENDPROC ;SKRIVSTREG(I)
1280 REM 
1290 PROC SKRIVHEST(K,L)
1300 FOR M=1 TO 3
1310 CURSOR K-M,L*4-2
1320 ; "<S>="
1330 NEXT M
1340 FOR M=2 TO 4 STEP 2
1350 CURSOR K-M,L*4-1
1360 ; "<S>/"
1370 NEXT M
1380 CURSOR K,L*4-3
1390 ; "<S>/"
1400 CURSOR K-4,L*4-2
1410 ; "<S>-"
1420 ENDPROC ;SKRIVHEST(K,L)
1430 REM 
1440 PROC SLETHEST(N,O)
1450 FOR P=1 TO 3
1460 CURSOR N-6,O*4-P
1470 ; "<S>        "
1480 NEXT P
1490 ENDPROC ;SLETHEST(N,O)