|
DataMuseum.dkPresents historical artifacts from the history of: RegneCentralen RC3600/RC7000 |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about RegneCentralen RC3600/RC7000 Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - download
Length: 14336 (0x3800)
Types: TextFile
Names: »DUM30«
└─⟦033e255c7⟧ Bits:30001790 SG0010 Floppy
└─ ⟦this⟧ »/DUM30«
└─⟦8ae3926ab⟧ Bits:30001789 SG0009 Floppy
└─ ⟦this⟧ »/DUM30«
; BYTE-DUMP AF CORE REV. 2.08 OLIVETTI FÆRDIG 26.1.83 /PL
; SOM TIDL - DOG
; NYT:
; COREITEMS HOVED HENTES KORREKT I DOMUS PRG DESCR
; LIGE STARTADR => SMAL SKRIFT OG OP TIL 31 KOLONNER
; ULIGE => NORMAL SKRIFT *** PAS SELV PÅ HØJST 18 KOLONNER
; SIDETAL -1 => SAMME SIDE GENTAGES UBEGRÆNSET!
; DUMP VERS. 2.08 FÆRDIG AFPUDSET 25.1.83
; 2.08 AFSLUTTES 24.1.83 ; 24.1.83 UFÆRDIG
; BDUMP REV 2.08 23.1.83 CORE FRA DOMUS/ OUTPUT TIL OLIVETTE (27.62.27.48 OG MXKO)
; OLIVETTE VERSION 21.1.83
; BDUMP VERS. 2.07 RETTET MHT CAP/CAPXX-IKKE-FUNDET: LDA 2,ZONAD //IØVR UÆNDR
; DETTE RETTET 16.1.83 OG FIL PÅ PL-FÆRD-NR 3
; FILNAVN HEREFTER BDA27 (BDUMP ASCII VERSION 2.07)
; RETTET 11.1.83 PÅ NY DIABLO CAPXX ERSTATTET MED CAP !!
; BDUMP 2.05 ÆGTE ENDELI 18.4.82 /FILPÅDISK/COREKÆDE/TIME
; BDUMP 18.4.82 AFTEN /PL FILPÅDISKETTE OG COREKÆDE LØST
; BDUMP 2.05 18.4.82 /FILPÅDISKETTEPROBLEM
; BDUMP 2.04 PL 14.4.82 / PRG KØRER KORREKT UNDT NÅR FILER PÅ DISKETTER (RETTELSE EJ LAVET)
; BDUMP REV 2.04 PÅPEB 12.4.82
; BDUMP /P1AD3/ REV 2.03 FÆRDIGJUSTERET (ESS.) 10.4.82 - TIME IKKE INCL I VERSIONEN
; 8 ELLER 5 PROCESSER MARKERES I HOVED - FARE VED FILPROC P
; PÅ DISKETTER (10=> LINIESKIFT, FX)
; BDUMP REDIGERINGER / P1AD3 / 8.4.82 PL
; BDUMP/P1AD3 VERS. 2.02 PL 7.4.82 NULBYTE ÆNDRET & FLERE PCD
; BDUMP / P1AD3 REV.2.01 / KALDES BDUMP MED INGEN EL. 3 PARAM /PL
; BDUMP BYTE-DUMP AF CORE /// REV. 2.01 5.4.82 KL 14
; KALDES MED 3 PARAM ELLER UDEN SOM CDUMP
; PL 5.4.82 EFTERM; PL 5.4.82 MORGEN
; ATRAT VESRION 2 BYTE-UDSKRIFT PL 4.4.82
; CDUMP VERS 1.03 (4.4.82) PL TILFØJET @-BIT FØR PSEUD
; PL CORE DUMP PROGRAM / FÆRDIG 31.3.82 KL 22 / UDSKRIVER OP TIL 22 KOLONNER
; KALDES CDUMP STARTADR SIDETAL KOLONNER
; ELLER CDUMP (UDEN PARAMETRE)
; HVIS INGEN PARAMETRE STARTES PÅ ADR 0, 26 SIDER, 20 KOLONNER (BREDT PAPIR)
; PROGRAMMETS FORHISTORIE ER BAGVENDT FORTALT:
; HENTET FRA P1ADT HVOR TESTSTOP ER FJERNET PL 29.3.82
; RETTET PL 29.3.82
; RETTET VERSION 28.3.82 AFTEN / ALLE TIDL VÆK / TEST HERI VÆK !
; TESTVERSION 28.3.82 AF CDUMP / SKAL KASSERES ?
; CDUMP RETTET SØ 28.3.82 / PL
; CDUMP 1.02 PL 27.3.82 EFTERM SAMLET AF 23.3. OG 27.3.MORGEN OG PKH-REACM UDDAG
; CDUMP REV 1.2 CORELAGER-DUMP VED PL 23.3.82 EFTER IDE I PHK LAGUD (REV 3.02)
; 27.3.82 0.30 BEG
.TITL DUM28
.NREL
.RDXO 10
.RDX 10
.TXTM 1
.TXTN 1
PGDS: 1B0+1B5+1B15 ;PSPEC
TX06 ;PSTAR
0 ;CHAIN
PCDS-PGDS ;SIZE
.TXT 'BDUMP<0>' ;NAME
TX06: .TXT 'CORE DUMP REV 2.08O /PL 183/ <0>'
«ff»
; HOVEDDEL AF PRG / KOLONNEADMIN
; PL INDTASTET OPR 27.3.82 / RETTET LØBENDE - 8.4.82
NOL: 0
BIRTH:
MOV 1,2
LDA 0,14,2 ; CHECK OM 3 PARAM (ADR,SIDER,KOLONNER)
LDA 1,15,2
LDA 3,.4
SNE 3,1
MOV 0,0,SZR
JMP DEFAU ; ELLERS BRUG DEFAULT-VÆRDIER
LDA 1,7,2
LDA 0,.255
MOVS 0,0
MOVZR 0,0 ; 0111 1111 1000 0000
AND 0,1
STA 1,SIDEB
STA 1,LADR
LDA 1,7,2
MOVZR 1,1,SZC
STA 1,NOL
LDA 0,10,2
INC # 0,0,SNR
STA 0,SIDER
LDA 3,.32
SUBZ # 3,0,SNC
STA 0,SIDER ; ALTSÅ KUN HVIS SIDER > INPUTDATA
LDA 0,13,2
LDA 3,MAXK1
SUBZ # 3,0,SNC
STA 0,MAXKO ; ALTSÅ KUN HVIS MAXKOLONNER = 22 ER > INPUTDATA
LDA 0,.3
LDA 2,13,2
INC 2,2
LDA 3,MAXK1
SUB # 3,2,SNR
STA 0,UT
DEFAU:
LDA 2,ZONA4
LDA 0,.3
OPEN
LDA 0,T2762
LDA 1,NOL
MOV 1,1,SZR
LDA 0,T2748
OUTTEXT ; VÆLG SMAL SKRIFT HVIS ADR INPUT ER LIGE
; TILFØJET 21.1.83
SIDES:
LDA 2,MAXKO
STA 2,KINDX
; TIME FLYTET TIL BEGGE
JSR @ BEGG1
LDA 0,SIDEB
STA 0,LADR
STA 0,ADR
HOV2:
LDA 1,BUAD2
LDA 2,CUR
BINDEC
LDA 2,ZONA4
LDA 0,BUAD2
OUTTEXT
OUTSPACE
OUTSPACE
LDA 0,.64
LDA 1,ADR
ADD 1,0
STA 0,ADR
DSZ KINDX
JMP HOV2
OUTNL
LDA 2,MAXKO
STA 2,KINDX
LDA 0,SIDEB
STA 0,LADR
HOV3:
MOVZL 0,0
MOVZR 0,0
STA 0,ADR
MOVS 0,0
LDA 1,.255
AND 1,0
STA 0,AXDR
LDA 1,BUAD2
LDA 2,CUR
BINDEC
LDA 2,ZONA4
LDA 0,BUAD3 ; KUN 3 BYTE
; JMP NNNN ; TÆNKE...
LDA 3,BUAD1
LDA 1,.48
INCS 1,1
SUBZ # 1,3,SZC
JMP .+7 ; RETTET HERI 10.4.82
LDA 3,BUAD1
LDA 0,1,3
LDA 1,.32
ADD 1,0
STA 0,1,3
LDA 0,BUAD4
NNNN:
OUTTEXT
OUTSP
LDA 0,.32
LDA 1,AXDR
SL 0,1
LDA 1,.32
LDA 0,GRNS2
SL 1,0
LDA 1,.32
OUTCHAR
OUTSP
OUTSP
LDA 0,.64
LDA 1,ADR
ADD 1,0
DSZ KINDX
JMP HOV3
OUTNL
OUTNL
; NU BEGYNDER SELVE SIDEUDSKRIFTEN
LDA 1,SIDEB
STA 1,LADR
LDA 0,.64
STA 0,LINDX
JMP LINIE
T2762: .+1*2
.TXT *<27>>* ; NÆSTE ER <0>
MAXK1: 32
T2748: .+3*2
T1248: .+1*2
.TXT * <12><27><60>* ; NÆSTE ER <0>
MAXKO: 30
LINDX: 64
KINDX: 18
LADR: 0
ADR: 0
MRKE: 33
ADRMK: 1
SIDEB: 10368
SIDER: 12
BEGG1: BEGGN
ZONA4: LPZON
TX6B: TX06*2
BUAD1: BUAD+1
BUAD2: BUAD*2
BUAD3: BUAD*2+2
BUAD4: BUAD*2+3
UT: 6
AXDR: 0
LINIE:
LDA 0,MAXKO
STA 0,KINDX
LDA 0,LADR
STA 0,ADR
KOLO:
LDA 2,CUR
LDA 1,.10
DIVIDE ; DIVISIONSREST I ACC 3
LDA 0,MRKE
STA 0,ADRMK
LDA 0,.120
MOV # 3,3,SNR
STA 0,ADRMK
LDA 3,ADR
LDA 0,.255
AND 3,0
DIVIDE
LDA 0,PLUS
MOV # 3,3,SNR
STA 0,ADRMK
LDA 1,ADRMK
LDA 2,ZONAD
OUTCHAR
LDA 3,ADR ; NU ANALYSE OG UDSKRIFT AF DATA
MOVL 3,3
MOVZR 3,3
LDA 1,0,3
JSR @ DISA1
LDA 0,.64
LDA 3,ADR
ADD 3,0
STA 0,ADR
DSZ KINDX
JMP KOLO
LDA 0,FORST
LDA 1,34
SE 0,1
JSR PCSKF
OUTNL
ISZ LADR
DSZ LINDX
JMP LINIE
LDA 1,MAXKO
STA 1,KINDX
LDA 0,SIDER
INC # 0,0,SNR
JMP @ SIDE2
LDA 0,.64
MULTIPLY
LDA 0,SIDEB
ADD 0,1
STA 1,SIDEB
DSZ SIDER
JMP @ SIDE2
LDA 0,TX6B
LDA 2,ZONAD
OUTTEXT
DEAD:
LDA 2,ZONAD
LDA 0,T1248
OUTTEXT
LDA 1,.1
CLOSE
LDA 1,MESAD
LDA 2,NADR
SENDMESS
LDA 2,CUR
STOPPROC
JMP .-2
TT27: 27
MESAD: .+1
1B8
0
0
0
NADR: .+1
.TXT 'S<0><0><0><0><0>'
BUAD8: BUAD*2
ZONAD: LPZON
BUAD: 0
0
0
0
0
GRNS2: 96
SIDE2: SIDES
DISA1: DISAS
PLUS: 43
GRNS1: 61
PRCD: 34
FORST: 0
«ff»
; PÅ DENNE SIDE ER 7.4.82 TILFØJET PCD-CHAIN I HEAD & NULL-BYTE-UDSK
TLBA1: TILBA
BEGGN:
STA 3,TLBA1 @
LDA 2,ZONAD
LDA 1,.12
OUTCHAR
LDA 0,TX6B
OUTTEXT
LDA 0,.10
STA 0,NO
LDA 0,.2
STA 0,NO3
; COREKÆDE TILFØJET I VERSION 2.05 (2) (FORUDEN UDFEM (1)):
LDA 1,34
LDA 2,TINAM
SEARCHITEM
MOV # 2,2,SNR
JMP NN
LDA 0,-2,2
MOVZL 0,0
LDA 3,-1,2
LDA 1,TIBL0
STA 1,-1,3
LDA 1,NITT
JSR UDFEM
LDA 0,COREK
OUTTEXT
NN: ; REV 2.08 FLG MODIF (CORE FRA DOMUS)
LDA 2,ZONA4
LDA 1,.40
LDA 2,CAPBG ; GÆTTER AT CAPXX ER 1. PRG I EGEN CORE
SEARCHITEM
MOV # 2,2,SNR
JMP KADE2
STA 2,HER1
LDA 2,13,2
LDA 3,-1,2 ; 1.COREITEM ADR
STA 2,HER2
STA 3,HER3
KAEDE: ; NU OPR KAEDE:
STA 3,PRCD
LDA 0,.4
ADDZL 3,0 ;NAME BY ADR
LDA 1,.6
JSR UDFEM
LDA 1,GRNS1
OUTEND
LDA 0,PRCD
LDA 1,BUAD8
LDA 2,CUR
BINDEC
LDA 0,BUAD8
LDA 2,ZONAD
OUTTEXT
OUTSP
LDA 3,PRCD
LDA 3,2,3
DSZ NO
MOV # 3,3,SNR
JMP .+2
JMP KAEDE
KADE2:
STA 0,HER2
STA 1,HER3
STA 2,HER4
LDA 2,ZONAD ; RETTET 16.1.83 - VERSION 2.07 - OSSE 218 NEWCA NEDENFOR
OUTNL
LDA 0,.16
STA 0,NO
LDA 3,34
STA 3,FORST
DSZ NO3
JMP KAEDE
JMP @ TILBA
NULBY: .+1*2
.TXT ' <96> <0>'
PCSKF:
STA 3,TILBA
STA 1,FORST
LDA 0,.4
ADDZL 1,0
LDA 1,UTT @
JSR UDFEM
JMP @ TILBA
UTT: UT
TILB2: 0
UDFEM:
STA 3,TILB2
STA 1,NO2
FEM2:
MOVZR 0,3
LDA 1,0,3
INC 0,0,SNC
MOVS 1,1
LDA 3,.255
DSZ NO2
AND 3,1,SNR
JMP @ TILB2
LDA 2,ZONAD
OUTCHAR
JMP FEM2
CAPBG: .+1
; /////////////////// RETTET (ENESTE) I VERS. 2.05.B83
.TXT 'DOMUS'
NO3: 0
COREK: .+1*2
.TXT ' COREITEMS: <0>'
NULUD:
LDA 0,NULBY
LDA 2,ZONAD
OUTTEXT
JMP BYUD2
HER1: 63
HER2: 63
HER3: 63
HER4: 63
.TXT *TEST2*
TINAM: .+1
.TXT *TIME<0><0>*
TIBL0: .TXT " "
NITT: 19
; HER BURDE VÆRE SIDESKIFT
; BYTEDUMP-VERSION /START PL 4.4.82
; PL 23.3.82 FÆRDIG RÅINDTASTNING AF DEL AF DOMUS DUMP PROGRAM
; RETTET EN DEL (P1ADT) 28.3.82 REDIG OG RETTET 31.3.82 TIL ENDEL PRG
; FILNAVN FOR PL RÅFIL ER P1DUM/1/2/3/4/5
BYAD3: BYAD*2+2
BYAD2: BYAD*2
BYAD1: BYAD ;
BYAD: 0 ; TAL I DEC TIL UDSKRIFT
0
0
0
0
KONTR: 0
NO: 0
NO2: 0
ABADR: 0
AADR: 0
BADR: 0
AKTR: 0
BKTR: 0
GRNS: 96
TILBA: 0
; SUBR SOM TESTER OM BYTE ER TEXT-BYTE & ELLERS ÆNDRER TIL 32
; AC0 ? AC1 BY AC2 ? AC3 ()
; 0=ASC = = TILBAADR
TEST1:
LDA 0,.255
AND 0,1
SUB 0,0
STA 0,KONTR
LDA 0,GRNS
SL 1,0
ISZ KONTR ; IF BY >= 96 ... ELSE
LDA 0,.48 ; ÆNDRET TIL 48 I DENNE VERSION 2.01
SLE 0,1
ISZ KONTR ; IF 32 > BY ... ELSNE:
LDA 0,.32 ; TILFØJET DA 32 BLEV ÆNDRET TIL 48
SE 0,1
JMP .+3
SUB 0,0
STA 0,KONTR
LDA 0,KONTR
JMP 0,3 ; TILBA
DISAS: ; HOVEDRUTINE TIL TEST FOR ASCII-TEGN:
; AC0 AC1 1C2 AC3
; ADR/PHK /? WORD/PL /? ? LINK
; ? ? ZONAD ?
LDA 0,.0
STA 0,NO
STA 3,TILBA
STA 1,ABADR
MOVS 1,1
JSR TEST1 ; 1. BYTE ÆNDRES TIL ASCII-TEGN 32 HVIS IKKE OK
STA 1,AADR
STA 0,AKTR
«ff»
STA 0,AKTR
LDA 1,ABADR
JSR TEST1
STA 1,BADR
STA 0,BKTR ; BØR UDELADES HVIS IKKE DER ÆNDRES I TEST1-RUTINEN
; KONTROL FOR OM JMP @ DIS,0 ELLER JSR @ DIS,0
LDA 0,AADR
LDA 1,.12
COM 1,1
AND # 0,1,SZR
JMP BYUD ; EJ JMP/JSR ,0
LDA 1,.4 ; FLG 3 SÆTN TILFØJET 4,4,82
AND # 0,1,SNR
JMP BYUD ; EJ @
LDA 3,TABEL
LDA 1,BADR
LDA 2,0,3
LOOP1:
MOV 3,0
SUB # 2,1,SNR
JMP PSEUD ; FUNDET!
INC 3,3
INC 3,3
INC 3,3
INC 3,3
LDA 2,0,3
MOV # 2,2,SZR
JMP LOOP1 ; SØG NÆSTE
; HVIS PSE-INSTR IKKE FUNDET SKRIVES TALLET:
BYUD:
LDA 1,AADR
LDA 0,AKTR
BYNR2:
STA 1,KONTR
MOV 0,0,SZR
JMP TALUD
LDA 2,ZONA2
LDA 0,NO
MOV 0,0,SZR
OUTCHAR
OUTSP
OUTSP
MOV 0,0,SZR
JMP BYUD2
LDA 1,KONTR
OUTCHAR
BYUD2:
LDA 3,NO
LDA 0,BKTR
LDA 1,BADR
ISZ NO
MOV # 3,3,SNR
JMP BYNR2
JMP @ TILBA
TALUD:
MOV 1,0,SNR
JMP NULUD
LDA 1,BYAD2
LDA 2,CUR
BINDEC
LDA 3,BYAD1
LDA 0,1,3
LDA 1,.48
LDA 2,103 ;255*256
ANDS 0,2
SUB 1,2
LDA 1,TEGN
ADD 1,2
LDA 1,0,2
LDA 2,.255
ANDS 2,0
ADDS 1,0
STA 0,1,3
LDA 0,BYAD3
LDA 2,ZONA2
OUTTEXT
JMP BYUD2
ZONA2: LPZON
PSEUD:
INCZL 0,0
LDA 2,ZONA2
OUTTEXT
OUTSP
JMP @ TILBA
TABEL: PZJMP ; H U S K
; PL 23.3.82 SLUT
TEGN: .+1
32
46
58
63
63
PZJMP: 2
.TXT 'WAIT <0>'
3
.TXT 'WAITI<0>'
4
.TXT 'SENDM<0>'
5
.TXT 'WAITA<0>'
6
.TXT 'WAITE<0>'
7
.TXT 'SENDA'
8
.TXT 'SEARC'
9
.TXT 'CLEAN'
10
.TXT 'BREAK'
11
.TXT 'STOPP'
12
.TXT 'START'
13
.TXT 'RECHA'
116
.TXT 'NEXTO'
117
.TXT 'RETUR'
118
.TXT 'CLEAR'
119
.TXT 'WAITO'
120
.TXT 'SETIN'
121
.TXT 'SETRE'
122
.TXT 'SETCO'
123
.TXT 'CONBY'
124
.TXT 'GETBY'
125
.TXT 'PUTBY'
126
.TXT 'MULTI'
127
.TXT 'DIVID'
128
.TXT 'GETRE'
129
.TXT 'PUTRE'
130
.TXT 'WAITT'
131
.TXT 'REPEA'
132
.TXT 'TRANS'
133
.TXT 'INBLO'
134
.TXT 'OUTBL'
135
.TXT 'INCHA'
136
.TXT 'FREES'
137
.TXT 'OUTSP'
138
.TXT 'OUTCH'
139
.TXT 'OUTNL'
140
.TXT 'OUTEN'
141
.TXT 'OUTTE'
142
.TXT 'OUTOC'
143
.TXT 'SETPO'
144
.TXT 'CLOSE'
145
.TXT 'OPEN '
146
.TXT 'WAITZ'
147
.TXT 'INNAM'
148
.TXT 'MOVE '
149
.TXT 'INTPR'
150
.TXT 'INTGI'
152
.TXT 'INTBR'
156
.TXT 'MZSTA'
157
.TXT 'IRETU'
158
.TXT 'TAKEA'
159
.TXT 'TAKEV'
218
.TXT 'NEWCA'
219
.TXT 'FREEC'
220
.TXT 'CDELA'
221
.TXT 'WAITS'
222
.TXT 'WAITC'
223
.TXT 'CWANS'
224
.TXT 'CTEST'
225
.TXT 'CPRIN'
226
.TXT 'CTOUT'
227
.TXT 'SIGNA'
228
.TXT 'SIGCH'
229
.TXT 'CPASS'
230
.TXT 'CREAT'
231
.TXT 'LOOKU'
232
.TXT 'CHANG'
233
.TXT 'REMOV'
234
.TXT 'INITC'
235
.TXT 'SETEN'
236
.TXT 'COMON'
237
.TXT 'CALL '
238
.TXT 'GOTO '
239
.TXT 'GETAD'
240
.TXT 'GETPO'
244
.TXT 'CSEND'
245
.TXT 'SIGGE'
246
.TXT 'WAITG'
154
.TXT 'BINDE'
155
.TXT 'DECBI'
160
.TXT 'EXECU'
161
.TXT 'RET0 '
162
.TXT 'RET1 '
163
.TXT 'RET2 '
164
.TXT 'ERROR'
0
0
0
0
0
0
«ff»
LPZON:.TXT 'LPT<0><0>' ;ZNAME
Z ;SIZE
0 ;ZMODE
1 ;ZKIND
65535 ;ZMASK
DEAD ;GIVE
1 ;ZFILE
1 ;ZBLOC
0 ;ZCONV
LPS0 ;ZBUFF
117 ;ZSIZE (132/2+SSIZE)
0 ;ZFORM
0 ;ZLENG
LPB0*2 ;ZFIRS
LPB0*2 ;ZTOP
LPS0
220
0
.BLK ZAUX
LPS0: 0
0
0
0
LPS0
0
LPB0*2
LPB0: .BLK 110
«ff»
BUFF1:.+0
.-1
BUFF2
10
PCDS
0
0
0
0
0
BUFF2:.+0
.-1
0
10
PCDS
0
0
0
0
0
PCDS: .+0
.-1
0
0
.TXT 'BDUMP<0>'
.+0
.-1
BUFF1
PGDS
0
0
65500
DEAD
0
0
0
0
BIRTH*2
.BLK 6
.END PCDS
; FILENS INDH FRA PAGEZERO-PSE-TABEL ER HENTET FRA REACM
; PL 23.3.82
«ff»
«ff»
«nul»