DataMuseum.dk

top - metrics - download

    Length: 2560 (0xa00)
    Types: TextFile
    Names: »MAKR1«

└─⟦5dd5f096f⟧ Bits:30001768 R DOMUS unit $FD0
    └─⟦this⟧ »/MAKR1« 
└─⟦bb117111c⟧ Bits:30001806 SG0103 Floppy
    └─⟦this⟧ »/MAKR1« 

TextFile

; MACRO CONST ACC,VALUE
;
; LOADER VALUE I ACC
;
; EKS:  CONST 0,34
;
; GIVER LDA 0,.34
;
.MACRO  CONST
        LDA ^1,.+2
        JMP .+2
        ^2
        %
; MACRO MSG TEXT
;
; PRINTER TEXT PÅ TTY   --> DER SKAL VÆRE MESSAGEBUFFERE FRI <--
; ADVARSEL: SPACE ==> <32>
;      TAB ==> <9>
;     KOMMA ==> <44>
; PAS PÅ RADIX !
; HUSK LINIESKIFT
; EKS: MSG 'DETTE<32>ER<32>EN<32>TEST<10><13>'
;
.MACRO  MSG
        STA   0,.+19
        STA   1,.+19
        STA   2,.+19
        STA   3,.+19
        LDA   1,.+19
        LDA   2,.+10
        SENDM
        MOVZL # 2,2,SZC
        JMP   .-4
        WAITA
        LDA   0,.+9
        LDA   1,.+9
        LDA   2,.+9
        LDA   3,.+9
        JMP   MS$
        .+1
        .TXT  @TTY<0><0>@
        0
        0
        0
        0
        .+1
        3
        80
        .+2*2
        0
        .TXT  ^1
        0
MS$:
        %
; MACRO LDABS ACC,LABEL
;
; LDA ABSOLUT
;
; EKS: LDABS 0,BEGIN
;
.MACRO  LDABS
        LDA ^1,@.+2
        JMP .+2
        ^2
        %
; MACRO STABS ACC,LABEL
;
; STA ABSOLUT
;
; EKS STABS 0,BEGIN
;
.MACRO  STABS
        STA ^1,@.+2
        JMP .+2
        ^2
        %
;
; MACRO PROC LABEL
;
; DEF SUBROUTINEHOVED OG GEM ACC'S
;
;  EKS PROC GPARM
;
.MACRO PROC
       0
       0
       0
       0
       0
?PROC=.
^1:    STA 0,^1-5
       STA 1,^1-4
       STA 2,^1-3
       STA 3,^1-2
       INC 3,3
       STA 3,^1-1
%
;
; MACRO ENDP
;
; REETABLER ACC'S OG RETUR FRA SUBR.
;
;  EKS: ENDP
;
.MACRO ENDP
       LDA @ 0,.+5
       LDA @ 1,.+4
       LDA @ 2,.+3
       LDA @ 3,.+2
       JMP .+2
       ?PROC
%
;
; MACRO GOSUB LABEL
;
; EKSEKVER SUBR.
;
;  EKS: GOSUB GETPAR
;
.MACRO GOSUB
       JSR @ .+1
       ^1
%
;
; MACRO RESUL ACCFRA ACCTIL
;
; PUT ACCINDHOLD SÅLEDES AT ACCTIL FÅR VÆRDI
;     MED TILBAGE VED KALD AF MACRO ENDP
;
; EKS: RESUL 1,2
;
.MACRO RESUL
       STA 2,.+4
       LDA 2,.+4
       STA ^1,+^2,2
       JMP .+3
       0
       ?PROC-5
%


       .EOT
«ff»
«nul»