⟦3d394179b⟧

TextFile


; *** FLOAD ***      LOAD AF FCOPY-ERET FIL
; LOADPARAMETRE:     FLOAD DOMUSFILNAVN FCOPYFILNAVN
; DEFAULT => UDSKRIFT AF SAMTLIGE FILNAVNE PÅ FCOPY-DISKETTEN

; PL 25.1.85 (INDTASTNING PÅBEG) FF - 27-28-29.1
; DE BERØMTE FEJL ER VIST FUNDET: LAS2-LAS4 (SZR/SNR ) ETC 29.1 AFTEN
; 30.1.: DET HJALP / NU NOK SNART FÆRDIG ?!
; 31.1.85 TÆLLEJUSTERING	OG TESUDSKRIFTER FJERNES // PRØVEKØRT OK
; 1.2 JUSTERINGER FØR FÆRDIG OG VISTNOK NU I ORDEN (AFTEN KL CA 25)


	.TITL FLOAD
	.NREL
	.RDXO 	16
	.RDX	10
	.TXTM	1
	.TXTN	1
PGDS:	1B0+1B5+1B15
	LAB00
	0
	PCDS-PGDS
	.TXT "FLOAD"
LAB00:	.+1*2
	.TXT "LOAD AF FCOPY-FIL<13><10>PL 26.1.85 REV 0.0<0>"


; FØLGENDE RUTINER HÆNGER SAMMEN
; INDTASTET 25-26.1.85 PL

;IN	HENTER PARAM IND FRA LOADKOMMANDO *
;				 FRAADR=BLOKADR=ADR PÅ BYTECOUNT FOR BLOK
		; ü	TILADR	FRAADR	CUR
		;LAST W	NÆSTE	NÆSTE	=	

;TRA	VÆLGER TRACK PÅ DISKETTEN * TRACK ER DEF I TRA8
		; ü	ü	0/INCR	CUR
		; =	TRACK	=	=

;SEC	LÆSER SECTOR TIL BUFFER   * SECTOR DEFINERET I SEC8
		; ü	ü	0/INCR	CUR
		;SECT	TRACK	=	=	TRACK KALDES EVT

;LAS	LÆSER FILENTRY OG CHECKER DET; DEFINERER ANTAL SECTORER I LAS5
		; ü	ü	ü	CUR
		;ANTALS	SIDSTE	0/OK	=	LÆSER IKKE SECT!!

;SPR	TÆLLER ANTALSECTORER FREM OG DEF TRACK OG LÆSER SECTOR
		;ANTALS	ü	ü	CUR
		;SECT	TRACK	=	=	KALDER TRA & SEC FØR RETURN

;LOO	UDSKRIVER FILNAVN PÅ AKTUEL TRACK/SECTOR (HÅBER DET ER RIGTIGT)
		;ü	ü	ü	CUR
		;SECT	TRACK	0	=	BEG MED TRA & SEC SLUT MED SEC

	.DUSR FD1=52

«ff»
.MSG SIDE 2 SELVE RUTINERNE OG HOVEDPROGRAM AFPUDSET 1.2.85

LOO7:0
LOO8:0
LOO9:0
LOO1:	STA 3,.-1
	LDA 3,CUR
	SUB 2,2
	TRA
	SEC	;LÆS IGEN
	OUTHX
	OSP
	MOV 0,1
	OUTHX
	OSP
	OSP
	OSP
	OSP
	LDA 1,.5
	STA 1,LOO8
LOO2:	DIB 1,FD1
		SNZ 1,1
		LDA 1,.32
	OCH	;	OUT	; MIDL // SENERE IGEN OCH
	DSZ LOO8
	JMP LOO2
	OSP
	OSP
	OSP
	OSP
	OSP
;	ONL
	SUB 2,2
	SEC	;FYLD BUFFER IGEN
	JMP @ LOO9


SPR7: 0
SPR81:	0	; COUNTGEMME
SPR8: 0	; COUNT ANTAL SECT
SPR9: 0
SPR1: 	STA 3,.-1
	STA 0,SPR8
	STA 0,SPR81
	STA 2,SPR7
	
SPR2:	LDA 0,SEC8
	LDA 3,SEC7
	ADD 3,0
	LDA 3,SEC6
	SLE 0,3
	SUB 3,0
	STA 0,SEC8
	LDA 3,.1
	SUB # 0,3,SNR 	; BERØMTE SEJE FEJL: SNR /// Ø V 29.1. AFTEN
	ISZ TRA8
		LDA 3,CUR
;		LDA 1,TRA8
;		OUTHX
;		LDA 1,SEC8
;		OUTHX
;		OSP
	DSZ SPR8
	JMP SPR2
	SUB 2,2	;IKKE NÆSTE
	JSR TRA1 ; TRA
	JSR SEC1 ; SEC
	LDA 2,SPR7
	JMP @ SPR9

IN7: DEFAU
IN8:0
IN9:0
IN1:	STA 3,.-1
	MOV 1,3
	LDA 0,0,2
	MOVR 0,0,SNR
	JMP IN3
	STA 0,IN8
	DSZ IN8
	DSZ IN8
IN2:	LDA 0,2,2
	STA 0,0,3
	INC 2,2
	INC 3,3
	DSZ IN8
	JMP IN2
	INC 2,2
	INC 2,2
	MOV 3,1
	LDA 3,CUR
	JMP @ IN9
IN3:	SUB 2,2
	STA 2,CMP08
	LDA 3,CUR
	JMP @ IN7


TRA51: 0
TRA5: DEAD
TRA6: 76
TRA7: 1B6+1B7
TRA8: 1
TRA9: 0
TRA1: STA 3,.-1
	STA 0,TRA51
	SZ 2,2
	ISZ TRA8	;NÆSTE TRACK ! HVIS AC2 EJ 0
	LDA 1,TRA8 ; FØDES MED 1
	LDA 0,TRA6
	SLE 1,0
	JMP @ TRA5
	LDA 0,TRA7
	ADD 1,0
	DOAS 0,FD1
	SKPBZ FD1
	JMP .-1
	LDA 3,CUR
;	LDA 0,.1
;	STA 0,SEC8	; SE SEC !!!!
	LDA 0,TRA51
	JMP @ TRA9

SEC51: 0
SEC8: 1	;DEF FRA TRA
SEC7: 7
SEC6: 26
SEC9: 0
SEC1:	STA 3,.-1
	STA 2,SEC51
	SNZ 2,2
	JMP SEC2 	; EJ NÆSTE
	LDA 3,SEC7
	ADD 3,0
	LDA 3,SEC6
	SLE 0,3
	SUB 3,0
	STA 0,SEC8
	LDA 2,.1
	LDA 3,CUR			; ØV!!
	SNE 0,2		; EJ NÆSTE TRACK
	TRA		; NÆSTE TRACK
SEC2:	LDA 1,TRA8	; I ALLE TILFÆLDE
	LDA 2,SEC51	; AC2 UÆNDRET
	LDA 0,SEC8
	DOAS 0,FD1
	SKPBZ FD1
	JMP .-1
	LDA 3,.128
	STA 3,LAS8	;NB
	LDA 3,CUR
	JMP @ SEC9

LAS55: .+1
.TXT "WWWWWWLAS:"
LAS66:	0	;FLAG TIL AC2 // 0=SPRING // ELLERS LÆS
LAS6: 16 ;  IND TIL REG SIZE
LAS7: 3
LAS8: 128 ; BEGGE COUNT
LAS9: 0
LAS1: STA 3,.-1
	LDA 2,.16	; SKAL EVT RETTES H E R
	STA 2,LAS6
	SUB 2,2
	STA 2,LAS66
	LDA 3,.3
	STA 3,LAS7
	LDA 3,CMP08
		LDA 2,LAS55
LAS2:	DIB 0,FD1
	MOVS 0,0
	DIB 1,FD1
	ADD 1,0
		STA 0,0,2
		INC 2,2
	DSZ LAS6
	DSZ LAS6
	LDA 1,2,3
	SE 0,1
	JMP LAS4 ; IKKE RIGTIGT NAVN
	INC 3,3
	DSZ LAS7
	JMP LAS2
	LDA 0,.1	; MANGLEDE / Ø V
	STA 0,LAS66	; FLAG  FOR OK
			; NU LÆSE SPRING/SIZE TIL AC0

LAS4:	; EVT SUB 2,2 // JSR SEC1 ; SEC// LDA 2,.16 // STA 2,LAS6 !!
	DIB 0,FD1
	DSZ LAS6
	JMP LAS4
	LDA 3,CUR
		OUTW
	INC 0,0
	MOVZL 0,0
	MOVZL 0,0	; ?+1)*4=ANTAL SECT
	STA 0,LAS5
;		OUTW
		ONL
	LDA 2,LAS66
	JMP @ LAS9

LAS5: 0 ; ANTAL SECTORER

;---------------------------

TTZO1:	TTZON
FIZO1: FIZON
CMP08: 0 ; ADR PÅ NAVN PÅ HENTEFIL FRA BACK

BIRTH:	MOV 1,2		; FLG PRG FORUDSÆTTER OVENST RUTINER SAMT 
	LDA 1,.5	; I/O-RUTINERNE FRA SIDE 8A-8B I AED8
	ADD 1,2
	LDA 1,FIZO1
	LDA 3,CUR
	IN
	STA 2,CMP08
DEFAU:	LDA 0,.1B6
	DOAS 0,FD1
	SKPBZ FD1
	JMP .-1
	LDA 2,TTZO1
	LDA 0,.3
	OPEN
	LDA 3,CUR
	SUB 2,2
	TRA
	SEC
NSTE:	LOO
	LAS
	SZ 2,2
	JMP OK
	SPR
	JMP NSTE
OK:	LDA 2,FIZO1
	LDA 1,.0
	LDA 0,.1
	CREATE
; ???	SETPOS ; GÆTTER AC0/1 = BL/FILE OK
	LDA 0,.3
	OPEN
	LDA 3,CUR
	LDA 0,.4
	SPR
		LDA 0,LAS5
		LDA 2,.4
		SUB 2,0
		MOVZL # 0,0,SNC
		STA 0,LAS5
FORT2:	LDA 2,TTZO1
	ONL
	OUTHX
	MOV 0,1
	OUTHX
	ONL
FORT1:	DIB 1,FD1
	OUT
	OUO
	DSZ LAS8
	JMP FORT1
	LDA 0,FOR98 @
	SUBZL 2,2	; NÆSTE SECT, EVT NÆSTE TRACK
	SEC
	DSZ LAS5
	JMP FORT2

DEAD:	LDA 2,FIZO1
	LDA 1,.1
	CLOSE
	LDA 1,AAS1
	LDA 2,AAS2
	SENDM
	LDA 2,CUR
	STOPP
	JMP .-1
AAS1:	.+1
	1B8
	0
	0
	0
AAS2:	.+1
	.TXT "S<0><0><0><0><0>"

FOR98: SEC8
;----------------------------------



;	SIDE 2 SLUT NU SIDE 8A:

«ff»
.MSG  SIDE 8A		308/4060	14.5.84  
; GEN RUTINER:   NORMAL I/O

; GEN RUTINER FORTSAT


;--------------------------

; INTW * INPUT WORD FRA TTY I HEXKODE (4 TEGN) (TTY ÅBNET FORUDS)
	;CALL:	.	.	.	CUR
	;RETU:	WORD	HØJRBY	=	CUR

IW02:0
IW03:0
IW1:	STA 2,IW02
	STA 3,IW03
	LDA 3,CUR
	INTHX
	MOVS 1,0
	INTHX
	ADD 1,0
	LDA 2,IW02
	JMP @ IW03


;--------------------------

; INTHX * INPUT FRA TTY (EVT HEXKODE, EVT SPACETASTKODE, EVT TASTKODE)
; INT * INPUT FRA TTY (TASTKODE)
; INI * INPUT FRA INPUTFIL

	;CALL:	.	.	.	CUR
	;RETU:	=	BYTE	ZON/0	CUR
	;			0 HVIS HX 1.BY < 32 ONLY

RTH00:0
RTH01:0
RTH02:0
RTH03:0
RTHFL:  0	; SÆTTES VED I_ OG RESETTES
RTHFG:  95	; PIL LEFT
RTHG1: 70
RTHG2: 9
RTHG3: 27
RTHD:  0
RTHC:  3
RTH1:	STA 0,RTH00
	STA 1,RTH01
	STA 2,RTH02
	STA 3,RTH03
	LDA 2,TTADR
	LDA 3,RTHFL
	MOV 3,3,SZR
	JMP RTH4

	LDA 2,.2
	STA 2,RTHC
RTH3:	LDA 2,TTADR
	INCHAR
		LDA 0,.32
		SGE 1,0
		JMP RTH5
		LDA 0,RTHFG
		SUB # 1,0,SZR
		JMP .+3
		ISZ RTHFL
		JMP RTH4
	LDA 0,.48
	LDA 3,RTHG1
	SG 1,3
	SGE 1,0
	JMP RTH4
	SUB 0,1 ; !!
	LDA 3,.9
	LDA 0,.7
	SLE 1,3
	SUB 0,1
	LDA 0,RTHC
	LDA 3,.2
	SNE 0,3
	STA 1,RTHD
	DSZ RTHC
	JMP RTH3

	LDA 0,RTHD
	MOVZL 0,0
	MOVZL 0,0
	MOVZL 0,0
	MOVZL 0,0
	ADD 0,1
RTH2:	LDA 0,RTH00
	LDA 3,CUR
	JMP @ RTH03
RTH4:	LDA 2,TTADR
	INCHA
		LDA 0,RTHG3
		SUB 1,0,SNR
		SUB 2,2
	JMP RTH2
RTH5:	LDA 0,RTH00
	SUB 2,2	; AC2=0 IF CONTROL I 1.HEXTEGN AF BYTE
	LDA 3,CUR
	JMP @ RTH03


RT:	LDA 2,TTADR
	JMP R1
RI:	LDA 2,INADR
	JMP R1
R00:0
R01:0
R02:0
R03:0
R1:	STA 0,R00
	STA 3,R03
	INCHA
	LDA 0,R00
	LDA 3,CUR
	JMP @ R03


;:::::::
INADR: TTZON		;*** INZON FJERNET
FIADR: FIZON
TTADR: TTZON
LPADR: TTZON		;*** LPZON FJERNET
;:::::::
;---------------------------

; OULHX * OUTPUT BYTE TIL LPT UDEN TEXTOPTION
; OUTHX * OUTPUT BYTE TIL TTY UDEN TEXTOPTION
; OUT * OUTPUT BYTE TIL TTY EVT HEXKODE, EVT SPACETASTKODE  "HH ", " A ", "A"
; OUL * OUTPUT BYTE TIL LPT EVT HEXKODE, EVT SPACETASTKODE
; OUO * OUTPUT BYTE TIL OUTPUTFIL
		; OUT & OUL KAN ÆNDRES VED KOMMANDO @A, @C

	;CALL:	.	BYTE	.	CUR
	;RETU:	=	=	ZON	CUR

WLHX:	STA 0,W00
	STA 1,W01
	STA 2,W02
	STA 3,W03
	LDA 2,LPADR
	JMP WHX2
WTHX:	STA 0,W00
	STA 1,W01
	STA 2,W02
	STA 3,W03
	LDA 2,TTADR
	JMP WHX2
WHX1:	STA 0,W00
	STA 1,W01
	STA 2,W02
	STA 3,W03
WHX2:	LDA 3,.255
	AND 3,1
	JMP W3
WT:	LDA 2,TTADR
	JMP W2
WL:	LDA 2,LPADR
	JMP W2
WO:	LDA 2,FIADR
	JMP W1
W00:0
W01:0
W02:0
W03:0
	;*** FHERNET	WLPFL:	LPFLG
W93: 93
W1:	STA 0,W00
	STA 1,W01
	STA 2,W02
	STA 3,W03
W21:	LDA 0,LPADR
	SE 0,2
	JMP .+3
		SUB 0,0	;*** TILFØJET
		;*** FJERNET 		LDA 0,WLPFL @
	SNZ 0,0	; FLAG FOR LPTFORBUD
	OUTCH
W22:	LDA 0,W00	; LPDW SÆTTER LPTDEAD ADR HER
	LDA 1,W01
	LDA 3,CUR
	JMP @ W03

W2:	STA 0,W00
	STA 1,W01
	STA 2,W02
	STA 3,W03
	LDA 3,.255
	AND 3,1
		LDA 3,W93
		LDA 0,.32
		SG 1,3
		SGE 1,0
		JMP W3
		LDA 3,CUR
		OSP
		OUTCH
		LDA 3,CUR
		JMP W4
W3:	LDA 3,.15
	MOV 1,0
	AND 3,1
	MOVZR 0,0
	MOVZR 0,0
	MOVZR 0,0
	MOVZR 0,0
	AND 3,0
	LDA 3,CUR
	OH	; AC2=TT EL. LP
	MOV 1,0
	OH
W4:	DSZ -2,2
	JMP .+2
	ONL
	OSP
	JMP W22


; OUTA * OUTPUT TIL TTY SOM ALM ASCIIFIL
; OUTL * OUTPUT TIL LPT SOM ALM ASCIIFIL

OUA91: 125 ; (LILLE Å)

OUTA1:	LDA 2,TTADR
	JMP .+2
OULA1:	LDA 2,LPADR
	STA 0,W00
	STA 1,W01
	STA 2,W02
	STA 3,W03
	LDA 0,.32
	LDA 3,OUA91 ; (Å)
	SG 1,3
	SGE 1,0
	JMP OUA3
	JMP W21		; OUTCHAR & RETURN
OUA3:	LDA 3,.127
	SE 1,0
	SNZ 1,1
	JMP W22	; IGN <0> OG <127>
	LDA 3,.13
	LDA 0,.10
	SE 1,3
		JMP .+4
		LDA 3,CUR
		OCH	; EVT UDELADES ?!
		MOV 0,1
	SNE 1,0
	JMP W21		; NORMAL NL
	LDA 3,.127
	LDA 0,.9
	SE 1,3		
	SNE 1,0
	JMP W21		; <9>, <127>
	LDA 3,.12
	SNE 1,3
	JMP OUA4	;  SÆRL. <12>
	LDA 1,OUA91
	INC 1,1		; ü
	JMP W21		; ELLERS "ü"

OUA4:	LDA 0,OUA44
	LDA 3,CUR
	OUTXT
	JMP W22

OUA44: .+1*2
	.TXT "<13><10><10>SIDESKIFT<13><10><10><0>"

;---------------------

; OUTW * OUTPUT WORD TIL TTY /HEX
; OULW * OUTPUT WORD TIL LPT /HEX
	;CALL:	WORD	.	.	CUR
	;RETU	=	=	ZON	CUR

OWW00:0
OWW01:0
OWW03:0
OUTW1:	LDA 2,TTAD8
	JMP .+2
OULW1:	LDA 2,LPAD8
	STA 0,OWW00
	STA 1,OWW01
	STA 3,OWW03
	LDA 3,.255
	MOVS 0,1
	AND 3,0
	AND 3,1
	LDA 3,CUR
		WHX
	MOV 0,1
		WHX
	LDA 0,OWW00
	LDA 1,OWW01
	LDA 3,CUR
	JMP @ OWW03



;::::::::::::
TTAD8:	TTZON
LPAD8: TTZON	;*** FJERENET: 	LPZON
;::::::::::::

;SIDE 8A SLUT
«ff»
.MSG  SIDE 8B		148/1753	12.5.84
 




;--------------------------
;                FLG. OUTPUTRUTINER FORUDSÆTTER FORUDG. DEF AF ZONE

;--------------------------

; OH * OUTPUT HEXTEGN

	;CALL:	TGN	.	ZON	CUR
	;RETU:	=	=	=	CUR
H00: 0
H01: 0
H02: 0
H03: 0
H1:	STA 0,H00
	STA 1,H01
	STA 2,H02
	STA 3,H03
		LDA 1,.15
		AND 1,0
	LDA 1,H9
	ADD 0,1
	GETBYTE
	LDA 2,H02
	MOV 0,1
	LDA 3,CUR
	OCH
	LDA 0,H00
	LDA 1,H01
	JMP @ H03
H9:	.+1*2
	.TXT "0123456789ABCDEFG"

 
;-------------------------

; OSP * OUTPUT SPACE (ZON)
; ONL * OUTPUT NL   (ZON)
; OCH * OUTPUT CHAR (ZON)

	;CALL: .	.	ZON(!)	CUR
	;RETU:	=	=	=	CUR
O00:0
O01:0
O02:0
O03:0
O2TTA:	TTZON
O2LG:	22	; EVT ÆNRES AF W
O1:	STA 0,O00
	STA 1,O01
	LDA 1,.32
	JMP O3
O2:	STA 0,O00
	STA 1,O01
	LDA 1,O2LG
		LDA 0,O2TTA
		SE 0,2
		JMP O2F
		LDA 0,.24
		SLE 1,0
		MOVZR 1,1
O2F:	STA 1,-2,2
	LDA 1,.10
	JMP O3
O3:	STA 2,O02
	STA 3,O03
	LDA 3,CUR
	LPD
	OUTEND
	LDA 3,CUR
	LPDW
	LDA 0,O00
	LDA 1,O01
	LDA 3,CUR
	JMP @ O03

O4:	STA 0,O00
	STA 1,O01
	JMP O3


;-------------------------

		;*** LPZON FJERNET OG DERFOR OSSE LPD

;; LPD  * LPT-DEAD POINT DEF = .+2
;; LPDW * LPT-DEAD POINT IN OUL-RUTINEN
;		; CALL:	.	.	.	CUR
;		; RETU:	=	=	=	CUR
;
;LPD00:0
;LPFLG: 0 	; FORBUDSFLAG (SE @E, @F)
;LPD03: 0
;LPD04: W22
;LPLPA: LPZON
;LPD05: LPTD9
;LPD1:	STA 3,LPD03
;	INC 3,3
;	STA 0,LPD00
;	LDA 0,LPLPA
;	SE 2,0
;	JMP LPD11
;	LDA 0,LPFLG
;	SZ 0,0
;	ISZ LPD03
;LPD11:	LDA 0,LPD00
;	STA 3,LPD05 @
;	LDA 3,CUR
;	JMP @ LPD03
;LPDW1:	STA 0,LPD00
;	STA 3,LPD03
;	LDA 3,LPD04
;	JMP LPD11





;-------------------

; OUTXT **** NY

	;CALL:	BYAD	.	ZON	CUR
	;RETU:	=	=	=	CUR
OUX00:0
OUX01:0
OUX02:0
OUX03:0
OUTX1:	STA 0,OUX00
	STA 1,OUX01
	STA 2,OUX02
	STA 3,OUX03
	LDA 3,CUR
	LPD
	OUTTEXT  ; !!
	LDA 3,CUR
	LPDW
	LDA 0,OUX00
	LDA 1,OUX01
	LDA 2,OUX02
	LDA 3,CUR
	JMP @ OUX03


;SIDE 8B SLUT
.MSG 8A-8B INTAKT BORTSET FRA ÆNDR MRK ;***
«ff»
; DENNE BLB BRUGES IKKE // SIDSTE DEL AF SIDE 10 I AED8


;-------------------------

; BLB * BLOCKBEREGNING AF TRACK/SECTOR
	
	;CALL:	BLOCK	.	.	CUR
	;RETU:	TRACK	SECT	=	CUR

BLB00:0
BLB01:0
BLB02:0
BLB03:0
BLB1:	STA 0,BLB00
	STA 1,BLB01
	STA 2,BLB02
	STA 3,BLB03
	LDA 3,CUR 
	MOVZL 0,0
	MOVZL 0,0
	LDA 1,.3
	SUB 1,0
	LDA 1,.25
	INC 1,1
	DIVID
	MOV 3,1
	LDA 2,BLB02
	LDA 3,CUR
	JMP @ BLB03
	

;SIDE 10 SLUT
«ff»
; FLG SIDE ER HENTET FRA AED8 OG OMREDIG TIL FLOAD 26.1.85
.MSG  SIDE 11		285/3255	15.5.84
; ZONER, BUFFERE, PRCD OG FKT-TABEL
; PROCESNAVN NU 'F'


.TXT "TIL "

FIZON:.TXT 'FIL<0><0><0>'	;ZNAME
	Z		;SIZE 
	0		;ZMODE 
	1B14+1B13+1B12+1B11
65535
DEAD
1
1
0
FIS0
263
0
0
FIB0*2
FIB0*2
FIS0
512
0
.BLK ZAUX
FIS0: 0
0
0
0
FIS0
0
FIB0*2
FIB0:	.BLK 256



24
0
TTZON:.TXT 'LPT<0><0><0>'		;ZNAME 
	Z		;SIZE 
	0		;ZMODE 
	1		;ZKIND 
	65535		;ZMASK 
	DEAD		;GIVE 
	1		;ZFILE 
	1		;ZBLOC 
	0		;ZCONV 
	TTS0		;ZBUFF 
	117		;ZSIZE (132/2+SSIZE) 
	0		;ZFORM 
	0		;ZLENG 
	TTB0*2		;ZFIRS 
	TTB0*2		;ZTOP 
	TTS0		;ZUSED 
	220		;ZSHAR 
	0		;ZREM 
	.BLK ZAUX		;AUXILIARY WORDS IN ZONE 
	
TTS0:	0		;SOPER 
	0		;SCOUN 
	0		;SADDR 
	0		;SSPEC 
	TTS0		;SNEXT 
	0		;SSTAT 
	TTB0*2		;S
 
TTB0:	.BLK 110		;DATA BUFFER 

		; BUFFERE DER ER NØDV NÅR FX. DOMUS-FIL-FUNKTIONER BRUGES!
BUFF1:	.+0 
	.-1 
	BUFF2 
	10 
	PCDS 
	0 
	0 
	0 
	0 
	0 
BUFF2:	.+0 
	.-1 
	BUFF3 
	10 
	PCDS 
	0 
	0 
	0 
	0 
	0 
BUFF3:	.
	.-1
	BUFF4
	10
	PCDS
	0
	0
	0
	0
	0
BUFF4:	.
	.-1
	0
	10
	PCDS
	0
	0
	0
	0
	0
	0
		; PROCES-DESCRIPTOR:
PCDS:	.+0 
	.-1 
	0 
	0 
	.TXT 'FLOAD'
	.+0 
	.-1 
	BUFF1 
	PGDS 
	0 
	0 
	33 
	DEAD 
	0 
	0 
	0 
	0 
	BIRTH*2 
	0
	1
	2
	3
	4
	5
	6
	7
	8
	9
	
.DUSR GOP  = JSR @ 30,3
CX ;OP1
.DUSR INTHX= JSR @ 31,3
RTH1
.DUSR INT  = JSR @ 32,3
RT
.DUSR INI  = JSR @ 33,3
RI
.DUSR OUT  = JSR @ 34,3
WT
.DUSR OUL  = JSR @ 35,3
WL
.DUSR OUO  = JSR @ 36,3
WO
.DUSR OH   = JSR @ 37,3
H1
.DUSR OSP  = JSR @ 38,3
O1
.DUSR ONL  = JSR @ 39,3
O2
.DUSR OCH  = JSR @ 40,3
O4
.DUSR INTK = JSR @ 41,3
CX	;INTK1
.DUSR OPERA= JSR @ 42,3
CX	;OPER1
.DUSR LPD  = JSR @ 43,3
CX	;LPD1
.DUSR LPDW = JSR @ 44,3
CX	;LPDW1
.DUSR FEJL = JSR @ 45,3
CX	;FEJL1
.DUSR OUTXT= JSR @ 46,3
OUTX1
.DUSR SEBYT= JSR @ 47,3
CX	;SEBY1
.DUSR INTFI= JSR @ 48,3
CX	;RTF1
.DUSR OUTFI= JSR @ 49,3
CX	;OUTF1
.DUSR OULFI= JSR @ 50,3
CX	;OULF1
.DUSR OUFI = JSR @ 51,3
CX	;OUF1
.DUSR BLB  = JSR @ 52,3
CX	;BLB1
.DUSR HARD = JSR @ 53,3
CX	;HM1
.DUSR HARDO= JSR @ 54,3
CX	;HM5
.DUSR OUTHX= JSR @ 55,3
WTHX
.DUSR OULHX= JSR @ 56,3
WLHX
.DUSR FLYT = JSR @ 57,3
CX	;FLYT1
.DUSR TYPE = JSR @ 58,3
CX	;TYP1
.DUSR HARDR= JSR @ 59,3
CX	;HM6
.DUSR HARDY=JSR @ 60,3
CX	;HM7
.DUSR LMV  = JSR @ 61,3
CX	;LMV1
.DUSR INTW = JSR @ 62,3
IW1
.DUSR OUTW = JSR @ 63,3
OUTW1
.DUSR OULW = JSR @ 64,3
OULW1
.DUSR LTL  = JSR @ 65,3
CX	;LTL1
.DUSR WHX  = JSR @ 66,3
WHX1
	; FLG ER SPEC TIL FLOAD-PROGRAMMET
.DUSR IN	= JSR @ 67,3
IN1
.DUSR TRA	= JSR @ 68,3
TRA1
.DUSR SEC	= JSR @ 69,3
SEC1
.DUSR LAS	= JSR @ 70,3
LAS1
.DUSR SPR	= JSR @ 71,3
SPR1
.DUSR LOO	= JSR @ 72,3
LOO1

CX9:	0
CX8:	0
CX7: 0
.TXT "CXCX"
CX:	ISZ CX8
	STA 3,CX9
	LDA 3,CUR
	JMP @ CX9



-1
	.END PCDS 
	

;SIDSTE SIDE SLUT / FIL SLUT
«ff»
«nul»
DataMuseum.dk

RegneCentralen RC3600/RC7000

⟦3d394179b⟧ TextFile

Derivation

TextFile
