DataMuseum.dk

top - download

    Length: 4096 (0x1000)
    Types: TextFile
    Names: »REA00«

└─⟦466f46364⟧ Bits:30001785 SG0005 Floppy
    └─⟦this⟧ 

TextFile

; XXX               XXXXXXXXXXXX      XXXXXXXXXXXXXXX
; XXX               XXXXXXXXXXXX      XXXXXXXXXXXXXXX
; XXX               XXX         XXX         XXX
; XXX               XXX         XXX         XXX
; XXX               XXX         XXX         XXX
; XXX               XXX         XXX         XXX
; XXX               XXXXXXXXXXXX            XXX
; XXX               XXXXXXXXXXXX            XXX
; XXX               XXX                     XXX
; XXX               XXX                     XXX
; XXX               XXX                     XXX
; XXX               XXX                     XXX
; XXXXXXXXXXXXXXX   XXX                     XXX
; XXXXXXXXXXXXXXX   XXX                     XXX
;
;   TIL TRODS FOR ALLE PROBLEMER FØLGER HEREFTER LPT-
; DRIVEREN TIL OLIVETTIEN.
	.EJEC
; DOMAC-SPECIFICATION
;
 	.RDXO	16		; OUTPUT I HEX
	.RDX	10		; INPUT I DEC
	.TXTM	1		; STD. TXT MODES
	.TXTN	1		;
	.TITL	RELPT		; TITEL OF PROGRAM
	.NREL			; ALM. RELOCATION
	.EJEC
; PROGRAM-DESCRIPTOR:
;
PGDS:				; PROGRAM-DESCRIPTOR
	1B0+1B1+1B7+1B15	;  SPECIFICATION
	PBREA			;  START
	0			;  CHAIN
	PCDS-PGDS		;  SIZE
	.TXT 'RELPT'		;  NAME
	.EJEC
; BREAK-PROCEDURE
;
PBREA:	SUB 1,1			; BREAK:
	MOVZL 0,0,SNC		;  IF POWERINT THEN
	STA 1,RESER,2		;  CLEAR RESERVER
	.EJEC
; MUS-INTERFACE
;
MLOOP:				; MAIN-LOOP
	NEXTO			; NEXT OPERATION:
	SETRE			;   +0 CONTROL
	JMP STA00		;   +1 INPUT (IRELEVANT)
				;   +2 OUTPUT
	.EJEC
; OUTPUT-CHARACTER-PROCEDURE
;
OCHAR:				; OUTPUT CHARACTER
	LDA 1,ADDRE,2		;  GET THE BYTEADDRESS
	GETBY			;  GET THE BYTE
	LDA 1,.127		;  MASK BYTE TO
	AND 1,0			;  CHARATER
	MOVS 0,0		
	LDA 1,.128		;  ADD STOPVALUE
	ADD 1,0
	STA 0,MES4		;  STORE THE CHARACTER
RETRY:	LDA 1,MES		;  GET THE MESSAGE
	LDA 2,AMXNM		;  GET THE RECEIVER-NAME
	SENDM			;  SEND THE MESSAGE
	MOVZL # 2,2,SZC		;  IF UNSUCCESFUL TRY AGAIN
	JMP TRYAG
	WAITA			  ; WAIT FOR THE ANSWER
	MOV 0,0,SZR		;  IF BAD STATUS TRY AGAIN
 JMP STAXX
	JMP UPDAT
TRYAG:	SUB 1,1			;  CLEAR DEVICE
	LDA 2,.64		;  DELAY APROX. 1.2 SEK
	WAITI			;  USED AS DELAY ONLY
	JMP RETRY
AMXNM:	.+1			; NAME OF AMX-PROCESS
	.TXT 'AMX<0><0><0>'
MES:	.+1			; ADDRESS OF MESSAGE
	15*256+7
	1
	.+2*2
	0
MES4:	0	
	0
	0
	.EJEC
; UPDATE VARIABELS
;
UPDAT:		; UPDATE VARIABELS
	LDA 2,CUR		;  LOAD PCDS
	ISZ ADDRE,2		;  INC ADDRESS OF CHARACTER 
	DSZ COUNT,2		;  DEC COUNT OF CHARACTERS
	JMP OCHAR		;  REPEAT UNTIL END
STA00:	SUB 0,0			;  RETURN STATUS 0
STAXX:	RETUR			;  RETURN ANSWER
	JMP MLOOP		;  JMP TO MAINLOOP
	.EJEC
; PROCESS-DESCRIPTOR
;
PCDS:				; PROCESS-DESCRIPTOR:
	0			;  NEXT
	0			;  PREV
	0			;  CHAIN
	PCDSE-PCDS		;  SIZE
	.TXT 'LPT<0><0><0>'	;  NAME
	.+0			;  FIRST EVENT
	.-1			;  LAST EVENT
	BUFF			;  BUFFER
	PGDS			;  PROGRAM
	0			;  STATE
	0			;  TIMER
	50000			;  PRIORITY
	PBREA			;  BREAK ADDRESS
	PCDS			;  AC0
	0			;  AC1
	PCDS			;  AC2
	0			;  AC3
	PBREA*2			;  PSW
	0			;  SAVE
	0			;  BUF
	0			;  ADDRESS
	0			;  COUNT
	0			;  RESERVER
	0			;  CONVERSION TABLE
	0			;  SAFETY
BUFF:				; BUFFERS:
	.+0			;  NEXT
	.-1			;  PREV
	BUFF2			;  CHAIN
	10			;  SIZE
	PCDS			;  SENDE
	0			;  MESS0
	0			;  MESS1
	0			;  MESS2
	0			;  MESS3
BUFF2:	.+0	
	.-1
	0
	10
	PCDS	
	0
	0
	0
	0
PCDSE:
.END PCDS
«ff»
«nul»