DataMuseum.dk

top - download

    Length: 5072 (0x13d0)
    Types: TextFile
    Notes: EKONTROL, ELEVRET::EKONTROL
    Names: »EKONTROL«

└─⟦bb49f20ac⟧ Bits:30007876 (DELPROCEDURER DISKETTE 80.28.06 Områder: OPDATER, FORSØM, BREV ELEVRET, KLLISTE, FOR.LIST)
    └─⟦this⟧ 

TextFile

«ff»
  6060 REM -------------------------------------------------------------------------
  6070 PROC EKONTROL
  6080   OPEN FILE(1,0)"NR-GR-NA"
  6090   OPEN FILE(2,0)"AD-CP-TL"
  6100   OPEN FILE(3,0)"PA.NA-ST"
  6110   OPEN FILE(4,0)"PA.AD-TL"
  6120   OPEN FILE(5,0)"VALGFAG."
  6130   OPEN FILE(6,0)"NUMERISK"
  6140   OPEN FILE(7,1)"ENR-RNR."
  6150   MAT READ FILE(7)ENRRNR
  6160   LET FORTSÆT=1; SPRING=0; DELING=0
  6170   PRINT "<134>";XY$(1);XY$(3);"<31>"
  6180   PRINT "<134>";XY$(6);XY$(4);"KONTROL DATA :"
  6190   PRINT "<134>";XY$(4);XY$(5);"------------------"
  6200   WHILE FORTSÆT DO 
  6210     LET RYKKER=7; KONTROL=1; SLUT=0
  6220     PRINT "<134>";XY$(8);XY$(RYKKER);
  6230     WHILE RYKKER<=11 DO 
  6240       CASE KONTROL OF 
  6250         REM
  6260       WHEN 1
  6270         INPUT "ELEVENS NUMMER                  : ",CNR
  6280         LET KONTROL=2
  6290         IF CNR=0 THEN 
  6300           LET FORTSÆT=0; KONTROL=5; SPRING=1
  6310         ENDIF
  6320       WHEN 2
  6330         INPUT "ELEVENS CPR-NUMMER              : ",CCPR$
  6340         LET KONTROL=3; RYKKER=RYKKER+1
  6350       WHEN 3
  6360         INPUT "ELEVENS EFTERNAVN               : ",CENAVN$
  6370         LET KONTROL=4
  6380       WHEN 4
  6390         INPUT "ELEVENS FORNAVN, (MELLEMNAVN)   : ",NAVN$
  6400         LET KONTROL=5
  6410         FOR I=1 TO LEN(NAVN$)
  6420           IF NAVN$(I)="," THEN 
  6430             LET A=I-1; B=I+1; I=LEN(NAVN$); DELING=1
  6440           ENDIF
  6450         NEXT I
  6460         IF DELING THEN 
  6470           LET CFNAVN$=NAVN$(1,A); CMNAVN$=" ",NAVN$(B,LEN(NAVN$)); DELING=0
  6480         ELSE
  6490           LET CFNAVN$=NAVN$; CMNAVN$=""
  6500         ENDIF
  6510       ENDCASE
  6520       LET RYKKER=RYKKER+1
  6530       PRINT "<134>";XY$(8);XY$(RYKKER);
  6540     ENDWHILE
  6550     IF NOT SPRING THEN 
  6560       LET RNR=ENRRNR(1,CNR)
  6570       IF RNR>=1 AND RNR<=30 THEN 
  6580         READ FILE(1,RNR)NR,GREN$,ENAVN$,FNAVN$,MNAVN$
  6590         READ FILE(2,RNR)EADR$,POGBY$,CPR$,ETLF$
  6600         IF ENAVN$=CENAVN$ AND FNAVN$=CFNAVN$ AND MNAVN$=CMNAVN$ AND CPR$=CCPR$ THEN 
  6610           PRINT "<134>";XY$(6);XY$(14);"-----------------------------------------------"
  6620           PRINT "<134>";XY$(8);XY$(16);"ELEVEN ER FUNDET OG SLETTES NU AF SYSTEMET."
  6630           WRITE FILE(1,RNR)0,"@","@","@","@"
  6640           WRITE FILE(2,RNR)"@","@","@","@"
  6650           WRITE FILE(3,RNR)"@","@","@","@"
  6660           WRITE FILE(4,RNR)"@","@","@"
  6670           WRITE FILE(5,RNR)"@","@","@"
  6680           WRITE FILE(6,RNR)0,0,0,0
  6690           CLOSE FILE(7)
  6700           OPEN FILE(7,3)"ENR-RNR."
  6710           LET ENRRNR(1,CNR)=RNR*100
  6720           MAT WRITE FILE(7)ENRRNR
  6730           CLOSE FILE(7)
  6740           OPEN FILE(7,1)"ENR-RNR."
  6750           PRINT "<134>";XY$(1);XY$(6);"<31>"
  6760         ELSE
  6770           PRINT "<134>";XY$(6);XY$(14);"----------------------------------------"
  6780           PRINT "<134>";XY$(8);XY$(16);"ELEV";CNR;"HAR IKKE OVENSTÅENDE DATA"
  6790           PRINT "<134>";XY$(8);XY$(17);"OG SLETTES DERFOR IKKE."
  6800           PRINT "<134>";XY$(6);XY$(19);"(STOP),(EFEJL),(OVERSIGT) : ";
  6810           INPUT "",VALG$
  6820           LET FEJL=33
  6830           REPEAT
  6840             CASE VALG$ OF 
  6850               PRINT "<134>";XY$(FEJL);XY$(19);
  6860               INPUT "<30>",VALG$
  6870             WHEN "STOP"
  6880               LET SLUT=1; FORTSÆT=0
  6890             WHEN "EFEJL"
  6900               FOR I=7 TO 11 STEP 1
  6910                 PRINT "<134>";XY$(41);XY$(I);"                  "
  6920               NEXT I
  6930               PRINT "<134>";XY$(1);XY$(13);"<31>"
  6940               LET SLUT=1
  6950             WHEN "OVERSIGT"
  6960               LET FLYTTER=7
  6970               WHILE FLYTTER<=11 DO 
  6980                 PRINT "<134>";XY$(60);XY$(FLYTTER);"><60><30>"
  6990                 IF FLYTTER=8 THEN 
  7000                   LET FLYTTER=FLYTTER+1
  7010                 ENDIF
  7020                 LET FLYTTER=FLYTTER+1
  7030               ENDWHILE
  7040               PRINT "<134>";XY$(63);XY$(7);NR
  7050               PRINT "<134>";XY$(63);XY$(8);CPR$
  7060               PRINT "<134>";XY$(63);XY$(10);ENAVN$
  7070               PRINT "<134>";XY$(63);XY$(11);FNAVN$;", ";MNAVN$
  7080               PRINT "<134>";XY$(6);XY$(19);"(STOP),(EFEJL) :<30> ";
  7090               INPUT "<30>",VALG$
  7100               LET FEJL=23
  7110             ENDCASE
  7120           UNTIL SLUT
  7130         ENDIF
  7140       ELSE 
  7150         PRINT "<134>";XY$(6);XY$(14);"-----------------------------------"
  7160         PRINT "<134>";XY$(8);XY$(16);"ELEV NR.";CNR;"EKSISTERE IKKE I ";KLASSE$
  7170         DELAY=4
  7180       ENDIF
  7190     ENDIF
  7200   ENDWHILE
  7210   CLOSE 
  7220 ENDPROC EKONTROL