DataMuseum.dk

Presents historical artifacts from the history of:

RegneCentralen RC3600/RC7000

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about RegneCentralen RC3600/RC7000

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - download

⟦61e9608f4⟧ TextFile

    Length: 19456 (0x4c00)
    Types: TextFile
    Names: »PAABD«

Derivation

└─⟦9eac10f8c⟧ Bits:30001801 SG0021 Floppy
    └─⟦this⟧

TextFile

; DISKETTE TRACK/SECTOR ABSOLUT DISASSEMBLER  ** PAABD **
; REV. 2.01
; RETTELSER 21.3 OG 22.3 OG 23.3.84 OG 25.3 (2.01 SLUT)
; PL DISKETTE-DISASSEMBLER 17.3.84 ETABL UD FRA:

; PHK8403141519 HENSLÆNGT PÅ "GULDKORN"
; VERSION 1.13 LABELS OK. 1 PARAM: FILNAVN, UD PÅ LPT
	.TITL VAFDP
	.NREL
	.RDXO 16
	.RDX 10
	.TXTM 1
	.TXTN 1
	.NOLOC 1
PGD:	1B0+1B5+1B15
	PGD0
	0
	PCD-PGD
	.TXT @VAFDP@
PGD0:

	.MACRO SYMB
	LA$=.
	^1
	.TXT @^1@
	.DO LA$+4-.
	0
	.ENDC
	%

BUFF:	.+0
	.-1
	BUF0
	10
	PCD
	0
	0
	0
	0
	0
BUF0:	.+0
	.-1
	BUF1
	10
	PCD
	0
	0
	0
	0
	0
BUF1:	.+0
	.-1
	0
	10
	PCD
	0
	0
	0
	0
	0«ff»
.DUSR FD1=52


LZO:	.TXT @LPT<0><0>@
	Z
	0
	1
	65535
	END
	1
	1
	0
	LZO0
	47
	0
	0
	LZO1*2
	LZO1*2
	LZO0
	80
	0
	.BLK ZAUX
LZO0:	0
	0
	0
	0
	LZO0
	0
	LZO1*2
LZO1:	.BLK 40«ff»
; RETTET 23.3.84

BEG0:	LZO
BEG2:	0
BEG:	STA 1,BEG2
	LDA 0,.3
	LDA 2,BEG0
	OPEN
	LDA 2,BEG2
	LDA 0,6,2
	LDA 2,CUR

LDA 1,.1B6
DOAS 1,FD1
SKPBZ FD1
JMP .-1
LDA 2,BEG2
LDA 0,5,2
MOV # 0,0,SNR
JMP BEG4
LDA 0,7,2
LDA 3,.1B7
ADD 1,0
ADD 3,0
LDA 2,CUR
STA 0,STTRA,2
STA 0,XXTRA,2
GNTRA
LDA 2,BEG2
LDA 0,8,2
MOV # 0,0,SNR
JMP BEG4
LDA 0,10,2
LDA 3,CUR
STA 0,STSEC,3
STA 0,SECNR,3
DOAS 0,FD1
SKPBZ FD1
JMP .-1
LDA 0,11,2
MOV # 0,0,SNR
JMP BEG4
LDA 0,13,2
STA 0,SECSE,3
LDA 0,14,2
MOV 0,0,SNR
JMP BEG4
LDA 0,16,2
LDA 2,CUR
STA 0,CNT8,2 ; ANTAL SECT A 64
MOVZL 0,0
STA 0,CNT9,2 ; ANTAL A 32

BEG4:
LDA 2,CUR
OFF
GBL21
«ff»
BL21: LDA 0,.0
	STA 0,ADR,2
LDA 0,.32
STA 0,CNT,2

BL211:
LDA 0,SECNR,2
OHXB
OSP
LDA 0,ADR,2
OHXW
OSP
OSP

BL215:	IWD
	STA 0,DATA,2
BL216:	LDA 0,DATA,2
	MOVS 0,0
	OASC
	LDA 0,DATA,2
	OASC
	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.7
	AND 1,0
	LDA 1,.3
	SLS 0,1
	JMP BL217
	LDA 0,DATA,2
	MOVS 0,1
	LDA 3,.3
	AND 3,1
	LDA 3,.1
	SEQ 3,1
	JMP BL217
	LDA 1,.255
	AND 1,0
	MOVS 0,0
	MOVL # 0,0,SZC
	ADD 1,0
	MOVS 0,0
	LDA 3,ADR,2
	ADDZ 3,0
	STA 0,DATA,2
	LDA 0,AREL,2
	STA 0,DREL,2
	CLAB
BL217:	ISZ ADR,2
	DSZ CNT,2
	JMP BL215

LDA 0,.32
STA 0,CNT,2
	OLN
DSZ CNT9,2
JMP BL211
PASS2

«ff»
PAS29: 12
PAS24:	0
PAS21:	LATAB
PAS2:

OLN
OLN

ISZ PASNR,2
	LDA 1,PAS21
PAS23:	MOV 1,3
	LDA 0,+0,3
	INC # 0,0,SNR
	JMP PAS22
	STA 1,PAS24
OHXW
OSP
DSZ PAS29
JMP PAS28
OLN
LDA 3,.12
STA 3,PAS29
PAS28:

	LDA 1,PAS24
	INC 1,1
	INC 1,1
	JMP PAS23
PAS22:
LDA 0,STTRA,2
STA 0,XXTRA,2
GNTRA
LDA 0,STSEC,2
STA 0,SECNR,2
DOAS 0,FD1
SKPBZ FD1
JMP .-1
OFF
LDA 0,.0
STA 0,ADR,2
LDA 0,.32
STA 0,CNT,2
MOVZL 0,0
STA 0,SECCO,2 ; 25.3
GBLC2

«ff»
BLC2:
BLC21:	LDA 0,ADR,2
	OSP
	OHXW
	LDA 0,ADR,2
	STA 0,DATA,2
	OSP
	FLAB
	STA 0,BLC28
	ISZ ADR,2
	IWD
	STA 0,DATA,2
	OHXW
	OSP
	OSP
	LDA 1,DATA,2
	MOVS 1,0
	OASC
	LDA 0,DATA,2
	OASC
BLC22:	OSP
	OSP
	LDA 1,BLC28
	MOV # 1,1,SZR
	JMP BLC2C
	LDA 0,BLC23
	OTXT
	JMP BLC2H
BLC2C:	LDA 1,ADR,2
	LDA 0,.1
	SUBZ 0,1
	OMRK
	LDA 0,BLC2E
	OCHR
OSP
OSP

BLC2H:	DISA
BLC24:	OLN
	JMP BLC21
; CNT8 NEDTÆLLES I PASNR 2 I GNSEC

BLC23:	.+1
	.TXT @        <0>@
BLC2B:	0
BLC2E:	":

BLC28: 0
«ff»
END0:	.+1
	1B8
	0
	0
	0
	0
END1:	.+1
	.TXT @S<0><0><0><0>@
END3:	LZO
ENDC:

LDA 2,CUR
OLN

	LDA 2,END3
	LDA 1,.12
	OUTEN
	LDA 1,.1
	CLOSE
END:	LDA 1,END0
	LDA 2,END1
	SENDM
	LDA 2,CUR
	STOPP
	JMP END«ff»
DISS0:	0
DISS:	STA 3,DISS0
	LDA 0,DATA,2
	MOVZL 0,0,SZC
	DALUI
	MOVL 0,0
	MOVL 0,0
	MOVL 0,0
	LDA 1,.3
	AND 1,0,SNR
	DJJID
	SEQ 0,1
	DLDST
	DIOIN
DISSE:	JMP @ DISS0«ff»
ALUI0:	.+1
	.TXT @COM<0>NEG<0>MOV<0>INC<0>ADC<0>SUB<0>ADD<0>AND@
ALUI1:	.+1*2
	.TXT @ ZOC@
ALUI2:	.+1*2
	.TXT @ LRS@
ALUI3:	.+1
	.TXT @   <0>SKP<0>SZC<0>SNC<0>SZR<0>SNR<0>SEZ<0>SBN@
ALUI:	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.7
	AND 1,0
	MOVZL 0,0
	LDA 1,ALUI0
	ADD 1,0
	OTXT
	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0,SNR
	JMP ALUI4
	LDA 1,ALUI1
	ADD 0,1
	GETBY
	OCHR
ALUI4:	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0,SNR
	JMP ALUI5
	LDA 1,ALUI2
	ADD 0,1
	GETBY
	OCHR
ALUI5:	OSP
	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 3,.32
	LDA 1,.3
	MOVR 0,0,SNC
	JMP ALUI6
	ADD 1,3
	MOV 3,0
	OCHR
	OSP
ALUI6:	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	OKOM
	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	LDA 0,DATA,2
	LDA 1,.7
	AND 1,0,SNR
	EDISS
	OKOM
	LDA 1,ALUI3
	MOVZL 0,0
	ADD 1,0
	OTXT
	EDISS«ff»
LDST0:	.
	0
	.TXT @LDA<0>STA@
LDST:	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	MOVZL 0,0
	LDA 1,LDST0
	ADD 1,0
	OTXT
	OSP
	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0,SNC
	JMP LDST1
	LDA 0,.64
	OCHR
	OSP
LDST1:	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	OKOM
	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.1
	SNE 1,0
	JMP LDST5
	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.3
	AND 1,0,SZR
	JMP LDST6
	LDA 0,DATA,2
	MOVL 0,0
	MOVL 0,0,SZC
	JMP LDST6
	LDA 0,DATA,2
	LDA 1,.255
	AND 1,0
	LDA 3,LDST7
	LDA 1,0,3
LDST8:	SNE 0,1
	JMP LDST9
	INC 3,3
	INC 3,3
	INC 3,3
	INC 3,3
	LDA 1,0,3
	MOV 1,1,SZR
	JMP LDST8
	JMP LDST6
LDST9:	INC 3,0
	ONAM
	EDISS
LDST7:	LDTAB
LDST6:	LDA 0,DATA,2
	MOVS 0,0
	MOVL 0,0,SNC
	JMP LDST2
	LDA 0,LDST3
	OCHR
	LDA 1,.255
	LDA 0,DATA,2
	AND 1,0
	INC 1,1
	SUB 0,1
	MOV 1,0
	OHXB
	JMP LDST4
LDST3:	45
LDST2:	LDA 0,DATA,2
	LDA 1,.255
	AND 1,0
	OHXB
LDST4:	OKOM
	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	EDISS
LDST5:	LDA 0,DATA,2
	LDA 1,.255
	AND 1,0
	MOVS 0,0
	MOVL # 0,0,SZC
	ADD 1,0
	MOVS 0,0
STA 0,DATA,2
	LDA 3,ADR,2
	LDA 1,.1
	SUBZ 1,3
	ADDZ 3,0
	MOV 0,1
	LDA 0,AREL,2
	OMRK

LDKMT:

OSP
OSP
OSP
LDA 0,LDSEM
OCHR
OSP
LDA 0,DATA,2
LDA 1,.128
SGE 0,1
JMP LDSPR
LDA 0,LDMIN
OCHR
MOVZL 1,0
LDA 1,DATA,2
SUB 1,0
LDSPR:

OHXB
OKOM
LDA 0,LD49
OCHR
	EDISS	

LD49:  49
LDSEM: 59
LDMIN: 45
«ff»
JJID0:	.+1
	.TXT @JMP<0>JSR<0>ISZ<0>DSZ@
JJID6:	JJTAB
JJID:	LDA 0,DATA,2
	LDA 3,JJID6
	LDA 1,0,3
JJID7:	SNE 0,1
	JMP JJID8
	INC 3,3
	INC 3,3
	INC 3,3
	INC 3,3
	LDA 1,0,3
	MOV 1,1,SZR
	JMP JJID7
	JMP JJID9
JJID8:	INC 3,0
	ONAM
	EDISS
JJIDA:	LDA 0,DATA,2
	OHXW
	EDISS
JJID9:	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.3
	AND # 1,0,SNR
	JMP JJIDA
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	MOVZL 0,0
	LDA 1,JJID0
	ADD 1,0
	OTXT
	OSP
	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0,SNC
	JMP JJID1
	LDA 0,.64
	OCHR
	OSP
JJID1:	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.1
	SNE 0,1
	JMP JJID5
	LDA 0,DATA,2
	MOVS 0,0
	MOVL 0,0,SNC
	JMP JJID2
	LDA 0,JJID3
	OCHR
	LDA 1,.255
	LDA 0,DATA,2
	AND 1,0
	INC 1,1
	SUB 0,1
	MOV 1,0
	OHXB
	JMP JJID4
JJID3:	45
JJID2:	LDA 0,DATA,2
	LDA 1,.255
	AND 1,0
	OHXB
JJID4:	OKOM
	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	EDISS
JJID5:	LDA 0,DATA,2
	LDA 1,.255
	AND 1,0
	MOVS 0,0
	MOVL # 0,0,SZC
	ADD 1,0
	MOVS 0,0
STA 0,DATA,2
	LDA 3,ADR,2
	LDA 1,.1
	SUBZ 1,3
	ADDZ 3,0
	MOV 0,1
	LDA 0,AREL,2
	OMRK

OSP
OSP
JMP @ JJKMT

	EDISS

JJKMT: LDKMT
«ff»
IOIN0:	.+1
	.TXT @NIO<0>DIA<0>DIB<0>DIC<0>DOA<0>DOB<0>DOC<0>SKP@
IOIN1:	.+1*2
	.TXT @ SCP@
IOIN2:	.+1
	.TXT @BNBZDNDZ@
IOIN:	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.7
	AND 1,0
	MOVZL 0,0
	LDA 1,IOIN0
	ADD 1,0
	OTXT
	LDA 0,DATA,2
	MOVS 0,0
	LDA 1,.7
	AND 1,0
	SNE 1,0
	JMP IOIN3
	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0,SNR
	JMP IOIN4
	LDA 1,IOIN1
	ADD 0,1
	GETBY
	OCHR
	JMP IOIN4
IOIN3:	LDA 0,DATA,2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,IOIN2
	ADD 1,0
	MOV 0,3
	LDA 0,0,3
	MOV 0,1
	MOVS 0,0
	OCHR
	MOV 1,0
	OCHR
	OSP
	JMP IOIN5
IOIN4:	OSP
	LDA 0,DATA,2
	MOVS 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	LDA 1,.3
	AND 1,0
	LDA 1,.48
	ADD 1,0
	OCHR
	OKOM
IOIN5:	LDA 0,DATA,2
	LDA 1,.63
	AND 1,0
	LDA 1,IOIN6
	MOVZL 0,3
	ADDZ 3,0
	ADD 1,0
	ONAM
	EDISS
IOIN6:	.+1
	.TXT @000  <0>EXMEM<0>002  <0>003  <0>004  <0>ASL  <0>006  <0>007  @
	.TXT @TTI  <0>TTO  <0>PTR  <0>PTP  <0>RTC  <0>PLT  <0>CDR  <0>LPT  @  
	.TXT @DSC  <0>SPC  <0>SPC1 <0>PTR1 <0>TMX10<0>TMX11<0>TMX0 <0>TMX1 @
	.TXT @MT   <0>PTP1 <0>OCPOB<0>OCPIB<0>OCPKI<0>DISP <0>OCPAL<0>LPS  @
	.TXT @REC  <0>XMT  <0>REC1 <0>XMT1 <0>MT1  <0>CLP  <0>FPAR <0>FPAX @
	.TXT @TTI1 <0>TTO1 <0>AMX  <0>AMX1 <0>HLCR <0>HLCX <0>CDR1 <0>LPT1 @
	.TXT @SMX  <0>FDD  <0>CRP  <0>CLP1 <0>FDD1 <0>053  <0>054  <0>LPS1 @
	.TXT @DST  <0>DOT  <0>CNT  <0>DKP  <0>FPAR2<0>FPAX2<0>062  <0>CPU  @«ff»
PLN0:	0
PLN1:	0
PLN:	STA 0,PLN0
	STA 3,PLN1
	LDA 0,.10
	OCHR
	LDA 0,.13
	OCHR
	LDA 0,PLN0
	DSZ LINE,2
	JMP @ PLN1
	OFF
	JMP @ PLN1

PFF0:	0
PFF1:	0
PFF2:	0
PFF3:	.+1
	.TXT @<12><0>@
PFF5:	.+1
	.TXT @ DISKETTE DISASSEMBLER REV 2.01 25.3.84 (PHK/PL)  TRACK/SECT: <0>@
PFF6:	.+1*2
	.TXT @     <0>@
PFF7:	.+1
	.TXT @<10><13><10><0>@
PFF:	STA 0,PFF0
	STA 1,PFF1
	STA 3,PFF2
	LDA 0,PFF3
	OTXT
	LDA 1,.64
INC 1,1
INC 1,1
	STA 1,LINE,2
	LDA 0,PFF5
	OTXT
LDA 3,.1
LDA 0,XXTRA,2
SUB 3,0
OHXB
OSP
LDA 0,SECNR,2
OHXB
OSP
LDA 0,SECSE,2
OHXD
OSP
OSP

	ISZ PAGE,2
	LDA 0,PAGE,2
	LDA 1,PFF6
	BINDE
	LDA 0,PFF6
	MOVZR 0,0
	INC 0,0
	OTXT
	LDA 0,PFF7
	OTXT
	LDA 1,PFF1
	LDA 0,PFF0
	JMP @ PFF2

«ff»
PTXT0:	0
PTXT1:	0
PTXT2:	0
PTXT:	MOVZL 0,0
	STA 0,PTXT0
	STA 1,PTXT1
	STA 3,PTXT2
PTXT3:	LDA 1,PTXT0
	GETBY
	MOV 0,0,SNR
	JMP PTXT4
	OCHR
	ISZ PTXT0
	JMP PTXT3
PTXT4:	LDA 1,PTXT1
	JMP @ PTXT2

PNAM0:	0
PNAM1:	0
PNAM2:	0
PNAM3:	0
PNAM:	STA 1,PNAM0
	STA 3,PNAM1
	LDA 1,.5
	STA 1,PNAM2
	MOVZL 0,0
	STA 0,PNAM3
PNAM4:	LDA 1,PNAM3
	GETBY
	OASC
	ISZ PNAM3
	DSZ PNAM2
	JMP PNAM4
	LDA 1,PNAM0
	JMP @ PNAM1«ff»
GWD0:	0
GWD1:	0
GWD2:	0
GWD:	STA 1,GWD0
	STA 3,GWD1
DIB 0,FD1
DIB 1,FD1
MOVS 1,1
ADD 1,0

DSZ SECCO,2
JMP .+2
GNSEC
GWD9:
	LDA 1,GWD0
	LDA 2,CUR
	JMP @ GWD1


PASC0:	0
PASC1:	0
PASC:	STA 1,PASC0
	STA 3,PASC1
	LDA 1,.255
	AND 1,0
	LDA 1,.127
	SLS 0,1
	LDA 0,.32
	LDA 1,.32
	SL 1,0
	LDA 0,.32
	OCHR
	LDA 1,PASC0
	JMP @ PASC1

PMRK0:	0
PMRK1:	0
PMRK2:	0
PMRK:	STA 0,PMRK0
	STA 1,PMRK1
	STA 3,PMRK2
LDA 0,.64
INC 0,0
	OCHR
	LDA 0,PMRK1
	OHXW
	LDA 0,PMRK0
	LDA 1,PMRK1
	JMP @ PMRK2«ff»

PSP0:	0
PSP1:	0
PSP2:	0
PSP:	STA 0,PSP0
	STA 1,PSP1
	STA 3,PSP2
	LDA 0,.32
	OCHR
	LDA 1,PSP1
	LDA 0,PSP0
	JMP @ PSP2

PKOM0:	0
PKOM1:	0
PKOM2:	0
PKOM3:	44
PKOM:	STA 0,PKOM0
	STA 1,PKOM1
	STA 3,PKOM2
	LDA 0,PKOM3
	OCHR
	LDA 0,PKOM0
	LDA 1,PKOM1
	JMP @ PKOM2«ff»
PHXD0:	0
PHXD1:	0
PHXD2:	.+1*2
	.TXT @0123456789ABCDEF@
PHXD:	STA 1,PHXD0
	STA 3,PHXD1
	LDA 1,.15
	AND 1,0
	LDA 1,PHXD2
	ADD 0,1
	GETBY
	OCHR
	LDA 1,PHXD0
	JMP @ PHXD1

PHXB0:	0
PHXB1:	0
PHXB2:	0
PHXB:	STA 1,PHXB0
	STA 3,PHXB1
	STA 0,PHXB2
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	MOVR 0,0
	OHXD
	LDA 0,PHXB2
	OHXD
	LDA 1,PHXB0
	JMP @ PHXB1

PHXW0:	0
PHXW1:	0
PHXW2:	0
PHXW:	STA 0,PHXW0
	STA 1,PHXW1
	STA 3,PHXW2
	MOVS 0,0
	OHXB
	LDA 0,PHXW0
	OHXB
	LDA 1,PHXW1
	LDA 0,PHXW0
	JMP @ PHXW2

PCHR0:	LZO
PCHR1:	0
PCHR2:	0
PCHR:	STA 3,PCHR2
	STA 1,PCHR1
	LDA 2,PCHR0
	MOV 0,1
	OUTEN
	LDA 2,CUR
	LDA 1,PCHR1
	JMP @ PCHR2«ff»
SLAB0:	LATAB
SLAB:	STA 3,SLAB1
	LDA 3,SLAB0
SLAB2:	LDA 0,+0,3
	LDA 1,DATA,2
	INC # 0,0,SZR
	JMP SLAB3
JMP SLAB4

SLAB3:	SEQ 0,1
	JMP SLAB5

LDA 0,.1

	JMP @ SLAB1
SLAB6:	LDA 0,+0,3
	LDA 1,DATA,2
SLAB5:	SGE 1,0
	JMP SLAB4
	INC 3,3
	INC 3,3
	JMP SLAB2
SLAB4:	SUB 0,0
	JMP @ SLAB1
SLAB1:	0«ff»
MLAB0:	LATAB
MLAB1:	0
MLAB:	STA 3,MLAB1
	FLAB
	MOV 0,0,SZR
	JMP @ MLAB1
	LDA 3,MLAB0
	LDA 0,DATA,2
MLAB2:	LDA 1,+0,3
	SG 0,1
	JMP MLAB3
	INC 3,3
	INC 3,3
	JMP MLAB2
MLAB3:	LDA 0,MLAB0
	LDA 1,.4096
	ADD 1,0
	LDA 1,.2
	SUB 1,0
	MOV 0,2
MLAB4:	SNE 2,3
	JMP MLAB5
	LDA 0,-2,2
	STA 0,0,2
	LDA 0,-1,2
	STA 0,1,2
	SUB 1,2
	JMP MLAB4
MLAB5:	LDA 2,CUR
	LDA 0,DATA,2
	STA 0,+0,3
	LDA 0,DREL,2
	STA 0,+1,3
	JMP @ MLAB1«ff»

;GNTRA

NTRA3: 0
NTRA4: 1B6+1B7+76
NTRA:  STA 3,NTRA3
LDA 0,XXTRA,2
LDA 3,NTRA4
SLE 0,3
TERMC
DOAS 0,FD1
SKPBZ FD1
JMP .-1
LDA 0,.1
STA 0,SECNR,2
STA 0,LINE,2 ; SIDESKIFT REQ
ISZ XXTRA,2
JMP @ NTRA3

;GNSEC

NSEC0: 0
NSEC1: 0
NSEC3: 0
NSEC:
STA 0,NSEC0
STA 1,NSEC1
STA 3,NSEC3
LDA 3,.64
STA 3,SECCO,2
LDA 0,SECNR,2
LDA 3,SECSE,2
ADD 3,0
LDA 1,T27,2
SNE 1,0
GNTRA
SG 0,1
JMP NSEC4
LDA 3,T27,2 ;!!
SUB 3,0
INC 0,0

NSEC4:
LDA 3,PASNR,2
MOV # 3,3,SZR
DSZ CNT8,2
JMP .+2
TERMC
STA 0,SECNR,2
DOAS 0,FD1
SKPBZ FD1
JMP .-1
LDA 3,PASNR,2
MOV # 3,3,SZR ;!!
STA 3,LINE,2 ; SIDESK REQ I PASS2

LDA 0,NSEC0
LDA 1,NSEC1
JMP @ NSEC3

LATAB:	65535
	0
	.BLK 4098«ff»
.DUSR	GETAD=3236
.DUSR RET0=1185
.DUSR	RET1=1186
.DUSR	RET2=1187
JJTAB:	SYMB BINDE
	SYMB GETAD
	SYMB RET0
	SYMB RET1
	SYMB RET2
	SYMB BREAK
	SYMB CDELA
	SYMB CHANG
	SYMB CLOSE
	SYMB COMON
	SYMB CONBY
	SYMB CPASS
	SYMB CPRIN
	SYMB CREAT
	SYMB CSEND
	SYMB CTEST
	SYMB CTOUT
	SYMB CWANS
	SYMB DECBI
	SYMB DIVID
	SYMB ERROR
	SYMB EXECU
	SYMB FREEC
	SYMB FREES
	SYMB GETAD
	SYMB GETBY
	SYMB GETPO
	SYMB GETRE
	SYMB GOTO
	SYMB INBLO
	SYMB INCHA
	SYMB INITC
	SYMB INNAM
	SYMB INTPR
	SYMB LOOKU
	SYMB MOVE
	SYMB MULTI
	SYMB NEWCA
	SYMB NEXTO
	SYMB OPEN
	SYMB OUTBL
	SYMB OUTCH
	SYMB OUTEN
	SYMB OUTNL
	SYMB OUTOC
	SYMB OUTSP
	SYMB OUTTE
	SYMB PUTBY
	SYMB PUTRE
	SYMB RECHA
	SYMB REMOV
	SYMB RETUR
	SYMB SEARC
	SYMB SENDA
	SYMB SENDM
	SYMB SETCO
	SYMB SETEN
	SYMB SETIN
	SYMB SETPO
	SYMB SETRE
	SYMB SIGCH
	SYMB SIGGE
	SYMB SIGNA
	SYMB START
	SYMB STOPP
	SYMB TRANS
	SYMB WAIT
	SYMB WAITA
	SYMB WAITC
	SYMB WAITE
	SYMB WAITG
	SYMB WAITI
	SYMB WAITO
	SYMB WAITS
	SYMB WAITT
	SYMB WAITZ
	SYMB .CLEA
	SYMB .CLOS
	SYMB .CONB
	SYMB .DIVI
	SYMB .FREE
	SYMB .GETB
	SYMB .GETR
	SYMB .INBL
	SYMB .INCH
	SYMB .MULT
	SYMB .NEXT
	SYMB .OPEN
	SYMB .OUTB
	SYMB .OUTC
	SYMB .OUTE
	SYMB .OUTN
	SYMB .OUTO
	SYMB .OUTS
	SYMB .OUTT
	SYMB .PUTB
	SYMB .PUTR
	SYMB .REPE
	SYMB .RETU
	SYMB .SETC
	SYMB .SETI
	SYMB .SETP
	SYMB .SETR
	SYMB .TRAN
	SYMB .WAIT
	0
	0
	0
	0«ff»
LDTAB:	SYMB CUR
	SYMB TABLE
	SYMB TOPTA
	SYMB PFIRS
	SYMB RUNNI
	SYMB EXIT
	SYMB EFIRS
	SYMB FFIRS
	SYMB DELAY
	SYMB AREAP
	SYMB AFIRS
	SYMB FREQU
	SYMB MASK
	SYMB CORES
	SYMB PROGR
	SYMB RTIME
	SYMB POWIN
	SYMB CDUMP
	SYMB CPUTY
	SYMB .0
	SYMB .1
	SYMB .2
	SYMB .3
	SYMB .4
	SYMB .5
	SYMB .6
	SYMB .7
	SYMB .8
	SYMB .9
	SYMB .10
	SYMB .12
	SYMB .13
	SYMB .15
	SYMB .16
	SYMB .24
	SYMB .25
	SYMB .32
	SYMB .40
	SYMB .48
	SYMB .56
	SYMB .60
	SYMB .63
	SYMB .64
	SYMB .120
	SYMB .127
	SYMB .128
	SYMB .255
	SYMB .256
	SYMB .512
	SYMB .1024
	SYMB .2048
	SYMB .4096
	SYMB .8192
	SYMB .1638
	SYMB .3276
	SYMB .M3
	SYMB .M4
	SYMB .M16
	SYMB .M256
	0
	0
	0
	0«ff»
0 ;PASNR
0 ;CNT
52 ; ANTAL SECT CNT8
104; DOBB      CNT9

NSEC
NTRA
27
64
1
1
1
1B6+1B7
1B6+1B7 ; ^ DISKETTEDISASS-VERSION (-56 TIL -64)
	0
	PMRK
	SLAB
	MLAB
0
0
0
0
	PAS2
	BL21
0
0
0
0
	0
	0
	PFF
	0
	DISSE
	LDST
	IOIN
	JJID
	ALUI
	DISS
		0
	BLC2
0
0
	40
	PTXT
	PNAM
		0
		0
	PLN
	0
	0
	0
	0
	0
	0
	0
	0
	0
	END
	ENDC
		0
	GWD
	PASC
		0
	PHXW
	PHXB
	PHXD
	PKOM
	PSP
	PCHR«ff»
.DUSR	OCHR	=JSR @ -1,2
.DUSR	OSP	=JSR @ -2,2
.DUSR	OKOM	=JSR @ -3,2
.DUSR	OHXD	=JSR @ -4,2
.DUSR	OHXB	=JSR @ -5,2
.DUSR	OHXW	=JSR @ -6,2
.DUSR	OREL	=JSR @ -7,2
.DUSR	OASC	=JSR @ -8,2
.DUSR	IWD	=JSR @ -9,2
.DUSR	IREL	=JSR @ -10,2
.DUSR	TERMC	=JMP @ -11,2
.DUSR	TERM	=JMP @ -12,2
.DUSR	REL0	=-13
.DUSR	REL1	=-14
.DUSR	REL2	=-15
.DUSR	AREL	=-16
.DUSR	DREL	=-17
.DUSR	ADR	=-18
.DUSR	DATA	=-19
.DUSR	BLCK	=-20
.DUSR	CNT	=-21
.DUSR	OLN	=JSR @ -22,2
.DUSR	ORAD	=JSR @ -23,2
.DUSR	OLAB	=JSR @ -24,2
.DUSR	ONAM	=JSR @ -25,2
.DUSR	OTXT	=JSR @ -26,2
.DUSR	.40	=-27
.DUSR	GNBLC	=JMP @ -28,2
.DUSR	GBLC7	=JMP @ -29,2
.DUSR	GBLC2	=JMP @ -30,2
.DUSR	GUBLC	=JMP @ -31,2
.DUSR 	DISA 	=JSR @ -32,2
.DUSR	DALUI	=JMP @ -33,2
.DUSR	DJJID	=JMP @ -34,2
.DUSR	DIOIN	=JMP @ -35,2
.DUSR	DLDST	=JMP @ -36,2
.DUSR	EDISS	=JMP @ -37,2
.DUSR	GBLC6	=JMP @ -38,2
.DUSR	OFF	=JSR @ -39,2
.DUSR	LINE	=-40
.DUSR	PAGE	=-41
.DUSR	GBLC3	=JMP @ -42,2
.DUSR	GBLC5	=JMP @ -43,2
.DUSR	PASS1	=JMP @ -44,2
.DUSR	GNBL1	=JMP @ -45,2
.DUSR	GBL21	=JMP @ -46,2
.DUSR	PASS2	=JMP @ -47,2
.DUSR	GBL71	=JMP @ -48,2
.DUSR	GBL61	=JMP @ -49,2
.DUSR	GBL31	=JMP @ -50,2
.DUSR	GBL51	=JMP @ -51,2
.DUSR	CLAB	=JSR @ -52,2
.DUSR	FLAB	=JSR @ -53,2
.DUSR	OMRK	=JSR @ -54,2
.DUSR	BLCF	=-55
.DUSR  STTRA =-56
.DUSR XXTRA=-57
.DUSR STSEC =-58
.DUSR SECNR =-59
.DUSR SECSE =-60 ; 1 ELLER 7
.DUSR SECCO =-61 ; COUNT
.DUSR T27   =-62
.DUSR GNTRA = JSR @ -63,2
.DUSR GNSEC = JSR @ -64,2
.DUSR CNT9 =-65
.DUSR CNT8 = -66
.DUSR CNT  = -67
.DUSR PASNR= -68
«ff»
PCD:	.+0
	.-1
	0
	0
	.TXT @VAFDP@
	.+0
	.-1
	BUFF
	PGD
	0
	0
	42
	END
	0	
	0
	0
	0
	BEG*2
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	0
	.END PCD
«ff»
«nul»