DataMuseum.dk

Presents historical artifacts from the history of:

RegneCentralen RC3600/RC7000

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about RegneCentralen RC3600/RC7000

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - download

⟦a834bdd4a⟧ TextFile

    Length: 10240 (0x2800)
    Types: TextFile
    Names: »P5AFR«

Derivation

└─⟦f319a9c26⟧ Bits:30001791 SG0011 Floppy
    └─⟦this⟧

TextFile


; P4AFR
; ***** AFPUDSET UDGAVE AF P3AFR DER KØRER KORREKT PR. 9.5.83
; 11.5.83 - 12.5.83
; FÆRDIG
; 15- 16.5.83 DIVERSE FORBEDR:   FORKL, _, <60>, FEJLTEST *** 
; FÆRDIG

 
; UDVIKLET: PLFD1 10-14.12.82 -> P1AFR 5-26.2.83 (KØRTE IKKE) ->
;         P2AFR CA 4-9.5.83 -> P3AFR (REV INPUT) 9.5.83 -> P4AFR 11-12.5.83 ***

; PROGRAMMET ER   A B S O L U T    F A R L I G T  !!!
; OG MAN KAN GØRE A L T MED EN DISKETTE I $FD1

.TITL  FD1RT
.NREL
.RDXO 16
.RDX 10
.TXTM 1
.TXTN 1
PGDS:  1B0+1B5+1B15
	LAB00
	0
	PCDS-PGDS
	.TXT 'FD1RT'
LAB00:
.TXT "<10>PROGRAM TIL AT RETTE $FD1 (NOT WRI-PRO)  ***  F A R L I G T ***<13><10>
               MAN KAN ØDELÆGGE MEGET!<13><10>
INDTAST 2 TEGN PR BYTE, HEXKODE (00 TIL FF) ELLER TASTTEGN (MED FOREG. SPACE!)<13><10>
FØRSTE BYTE OPFATTES SOM NUMMER PÅ FØRSTE BYTE (2 TEGN HEXKODE 00-7F)<13><10>
               SLUT MED RETURN OG KONTROLLER RETTELSEN !!!!<13><10>
NÆSTE SECTOR:  TRYK BLOT RETURN<13><10>
FOREG. SECTOR: TRYK _ FØR RETURN<13><10>
FÆRDIG:        TRYK <60> FØR RETURN<13><10>
                                                PL  16.5.83<0>"



 
«ff»

LPZ11: .TXT 'TTY<0><0><0>'; TTY OUTPUTZONE (SUBSID LPT)
      Z
     0
     1
     65535
     DEAD
     1
     1
     0
     LPS1
     73
     0
     0
     LPB1*2
     LPB1*2
     LPS1
     132
     0
     .BLK ZAUX
 LPS1: 0
     0
     0
     0
     LPS1
     0
     LPB1*2
 LPB1: .BLK 66
 LPZON: .TXT  'TTY<0><0><0>' 
     Z 
     0 
     1 
     65535 
     DEAD 
     1 
     1 
     0 
     LPS0 
     73 
     0 
     0 
     LPB0*2 
     LPB0*2 
     LPS0 
     132 
     0 
     .BLK  ZAUX 
 LPS0:  0 
     0 
     0 
     0 
     LPS0 
     0 
     LPB0*2 
 LPB0:  .BLK  66 
     .DUSR FD1=52 

TPIL: 95
T60:  60
DEAD2: DEAD
 LPZ99: LPZON
 G: 71
 DECRT: 0
 DECOD:
     STA 3,DECRT
     LDA 3,G
     SL 1,3
     JMP INFIN ; STOP INP
     LDA 3,.48
     SGE 1,3
     JMP INFIN ; STOP INP
     LDA 3,.64
     SG 1,3
     JMP EJ7
     LDA 3,.7
     SUB 3,1
 EJ7:
     LDA 3,.48
     SG 1,3
     MOV 3,1
     SUB 3,1 
     STA 1,HEXXX
     JMP @ DECRT
     
     
 OMRRT: 0
 OMR:
     STA 3,OMRRT
     LDA 1,ADR1
     MOVZL 1,1
     MOVZL 1,1
     MOVZL 1,1
     MOVZL 1,1
     LDA 0,ADR2
     ADD 0,1
     JMP @ OMRRT
     
 ADR1: 0
 ADR2: 0
     
 INRET:
     ; HENTE STARTNUMMER I FØRDSTE BYTE (<128)
     LDA 3,.0
     STA 3,NOIN
     INCHAR
	; 16.5.83:
	LDA 3,TPIL
	SNE 1,3
	JMP TILB
	LDA 3,T60
	SNE 1,3
	JMP @ DEAD2
     JSR DECOD
     STA 1,ADR1
     INCHAR
     JSR DECOD
     STA 1,ADR2
     JSR OMR
     LDA 3,.128
     SL 1,3
     JMP INFIN ; STOP INP
     LDA 3,.1
     STA 3,NOIN
     STA 1,BEGXX ; START BYTEADR RELATIVT TIL BUFFER AREAL BEG (BYTE ADR) PÅ BBBB
     ; HENTE FLG / DATA
     ; (DER TESTES PÅ AT TEGN IKKE ER < 48 OG IKKE > F 
     ; ... HVIS 1.TEGN SPACE DA BYTE DIREKTE !)
 INLOP:
     
     INCHAR
     LDA 3,.32
     SNE 1,3
     JMP TEXTX
     JSR DECOD
     STA 1,ADR1
     INCHAR
     JSR DECOD
     STA 1,ADR2
     JSR OMR
     STA 1,DATAX
     JMP INUD
     
 TEXTX:
     INCHAR
     STA 1,DATAX ; IGEN!
     
 INUD:
     LDA 3,BBB11 @
     MOV 1,0
     LDA 1,BEGXX
     ADD 3,1
     PUTBYTE ; TIL BUFFERAREAL
     ISZ BEGXX
     LDA 2,LPZ99
     ; 12.5:
     LDA 3,T300
     LDA 1,BEGXX
     SLE 1,3
     JMP INFIN ; STOP INP
     JMP INLOP
     
 INFIN:
     JMP @ RERES
     
 RERES: RERET
 DATAX: 0
 HEXXX: 0
 BBB11: BBBB
 BEGXX: 0
     
 NOIN: 0 ; 0=INTET INPUT / 1=INPUT ÆNDR
     
     -8
VIR98: SECTO ; SÅDAN!!
SEC98: VIR2
VIR97: VIR
TILB:   ; 16.5.83
	DSZ @ VIR98
	DSZ @ VIR98
	JMP .+1
	LDA 3,@ VIR98
	STA 3, @ VIR97
	INC 3,3
	STA 3,@ SEC98
	JMP INFIN
     
 TRCCC: TRACK
 LPZ41: LPZ11
 TX0B: TX00B
 TX1B: TX01B
T300: 200
 T26: 26
     .TXT "  BIRTH  "
 BIRTH:
     MOV 1,2 
     «ff»
     LDA 1,+7,2  
     STA 1,TRCCC @ 
     LDA 1,8,2
     MOV # 1,1,SNR
     JMP BI2
     LDA 1,10,2
     LDA 2,T26
     SLE 1,2
     JMP BI2
     STA 1,VIR
     LDA 3,.1
     SUB 3,1
     STA 1,SECTO
 BI2: LDA 2,LPZ41
     LDA 0,.3 
     OPEN 
     LDA 0,.1B6 
        DOAS 0,FD1 ; >>>
     SKPBZ FD1 
     JMP .-1 
     JMP FIRST
 NTRACK:
     SUB 0,0
     STA 0,SECTO
     INC 0,0
     STA 0,VIR
 FIRST:  LDA 0,TRACK 
     LDA 3,.1B7 
     LDA 1,.1B6 
     ADD 3,1 
     ADD 0,1 
        DOAS  1,FD1  ; >>>
     SKPBZ FD1 
     JMP .-1 
     LDA 1,.12
     OUTCHAR
     LDA 0,TX0B @
     OUTTEXT
     OUTNL 
     LDA 0,FJOR 
     OUTTEXT 
     OUTSP 
     LDA 0,TX1B @ 
     OUTTE 
     LDA 0,TRACK 
     LDA 2,CUR 
     LDA 1,ARB2 
     BINDE 
     LDA 2,LPZ21
     LDA 0,ARB2 
     INC 0,0 
     INC 0,0 
     INC 0,0 
     OUTTE 
     OUTNL 
     OUTNL 
 NSECT: ISZ SECTO
 SSECT: 	LDA 0,.3
     LDA 2,LPZ21
     OPEN
     LDA 1,TRACK
     LDA 3,.1B7
     LDA 0,.1B6
     ADD 3,1
     ADD 0,1
         DOAS 1,FD1 ; >>>> 
     SKPBZ FD1
     JMP .-1
 NORN: LDA 0,SECTO 
     LDA 1,SYVOG 
     SUB # 0,1,SNR 
     JMP NYTR @ 
     LDA 0,VIR
         DOAS  0,FD1  ; >>>> 
     SKPBZ FD1 
     JMP .-1 
     LDA 2,CUR 
     LDA 1,ARB2 
     BINDE 
     LDA 2,LPZ21
     LDA 0,ARB2 
     INC 0,0 
     INC 0,0 
     INC 0,0 
     OUTTE 
     LDA 1,KOLON 
     OUTEN 
     LDA 1,BBBB
     STA 1,BBB
     LDA 0,.4
     STA 0,LIN22
     JMP NCH3
 NCH2:
     OUTSP
     OUTSP
     OUTSP
 NCH3:
     LDA 0,.32 
     STA 0,CH 
 NCHR:  DIB 1,FD1  ; <<<< !!!!
     LDA 0,.255
     AND 1,0
     STA 0,BY
     LDA 1,BBB
     PUTBYTE
     ISZ BBB
     
     LDA 2,LPZ21
     LDA 1,BY
     MOV # 1,1,SNR
     JMP B127
     
     LDA 1,BY
     LDA 0,.32 ; EJ T47=31 !
     LDA 3,T126
     SUBZ # 1,3,SZC
     SUBZ # 0,1,SNC
     JMP EJASC
     OUTSP
     LDA 1,BY
     OUTCH
     JMP NESTE
     
 .TXT "HER:"
 TTT24: 240
 TRACK: 0
 LIN22: 4
 KOLON: 58
 SYVOG: 27
 NYTR: NYTRA
 VIR: 1
 FJOR: LAB00*2
 ARB2: ARB27*2
 BBBB: BOMR*2
 BBB:  -1
 BKTR: 0
 SECTO: 0
 LPZ21: LPZ11
 LPZO1: LPZON
 CH: 0
 BY:  0
 T47: 31
 T126: 126
     .TXT 'SLUT'
     
«ff»
EJASC:
     LDA 0,TTT24
     LDA 1,BY
     ANDZR 0,1
     MOVZR 1,1
     MOVZR 1,1
     MOVZR 1,1
     
     LDA 0,.10
     LDA 3,.7
     SUBO # 0,1,SNC
     ADD 3,1
     MOV # 1,1,SNR
     LDA 1,TM2
     LDA 3,.48
     ADD 3,1
     OUTCH
     
     LDA 0,.15
     LDA 1,BY
     AND 0,1
     LDA 0,.10
     LDA 3,.7
     SUBO # 0,1,SNC
     ADD 3,1
     LDA 3,.48
     ADD 3,1
     OUTEND
     JMP NESTE
     
 B127:
    LDA 1,T96
     OUTCH
     OUTSP
     
 NESTE:
 
     DSZ CH 
     JMP NCHR 
     OUTNL
     DSZ LIN22
     JMP NCH2
     	LDA 0,TTTT
     	OUTTEXT
     	OUTNL
     
     
     ; L Æ S N I N G S KL U T
     
     LDA 0,VIR
     LDA 1,.1 ; ANGIVER SECTIONSTEP
     ADD 1,0
     LDA 1,SEKSO
     SG 0,1
     JMP .+3
     SUB 1,0
     JMP .-3
     STA 0,VIR2
     
     LDA 2,LPZ21
     LDA 1,.64
     OUTEN
     LDA 2,LPZO1 ; TEST ELLERS VÆK
     LDA 0,.1
     OPEN
     SETPOS ; FORSØH 13.2.83
     JMP @ INRES
 INRES: INRET
 NOIN1: NOIN
 .TXT "  INPUT  "
 RERET:
 
     LDA 1,.128
     STA 1,BKTR
     LDA 1,BBBB
     STA 1,BBB
     
     LDA 3,NOIN1 @
     MOV # 3,3,SNR ; NOIN=1 BETYDER AT RETTELSE FORETAGES
     JMP EJAEN
     
	; 16.5.83 AFTEN
	LDA 2,LPZ21
	DIA 0,FD1
	MOV 0,0,SNR
	JMP ALTOK
	OUTOCTAL
	LDA 0,TTFJL
	OUTTEXT
	OUTNL
	ALTOK:

     DIC 3,FD1 ; <<<<
 U2: 
     LDA 1,BBB
     GETBY
         DOB 0,FD1 ; >>>>
     ISZ BBB
     DSZ BKTR
     JMP U2
     LDA 0,.1B7;
     LDA 1,SECTO 
     ADD 0,1
         DIC 0 ,FD1 ; <<<<
         DOAS 1,FD1 ; >>>> OUT BUFFER
    SKPBZ FD1
    JMP .-1
	; 16.5.83
	DIA 0,FD1  ; <<<< KONTROL
	MOV # 0,0,SNR
	JMP SSEC @
	LDA 2,LPZ21
	OUTOCTAL
	LDA 0,TTFJL
	OUTTEXT
     JMP SSEC @ ; KONTROLUDSKRIFT !!
     
     
 EJAEN: 
    LDA 1,VIR2
     STA 1,VIR11 @
     LDA 0,SEKS1
     SUB # 0,1,SNR
     JMP DEAD1
     JMP NSEC @ 
 NSEC: NSECT
 SSEC: SSECT
 VIR2: 0
 VIR11: VIR
 SEKSO:26
 FD1T: FD1
 TTTT: TTBB*2
 
 TM2: -2
 T96: 46
 T240: 240
 .TXT 'NYTR'
 NYTRA: ISZ @ TRRCK 
 LDA 0,@ TRRCK 
     LDA 1,SYVOH 
     SUB 0,1,SNR 
     JMP DEAD 
     JMP NTRC @ 
 NTRC: NTRAC
 TRRCK: TRACK
 LPZ31: LPZ21
 SYVOH: 77 
 SEKS1: 27
 
DEAD1: DEAD
TTFJL:  .+1*2
	.TXT " FEJLSTATUS <10><0>"
     -1
     -1
 BOMR: .BLK 100
 -1
     -1
     0
     0
    0
«ff»

     .TXT 'DEAD'
 DEAD:
     LDA 2,LPZ31 @ 
     LDA 1,.1
     CLOSE
	; 16.5.83:
	LDA 1,DE1
	LDA 2,DE2
	SENDM
     LDA     2,CUR 
     STOPP 
     JMP     -1,1
     BI2
     
	DE1: .+1
	1B8
	0
	0
	0
	DE2: .+1
	.TXT "S<0><0><0><0><0>"
 ARB27:     .BLK    5 
 TX00B:   .+1*2 
 .TXT @<96>123456789ABCDEF................ !"#$%&'()@
 .TXT #*+,-./0123456789:;<60>=>?<13><10>#
 .TXT 1@ABCDEFGHIJKLMNOPQRSTUVWXYZÆØÅ^.@ABCDEFGHIJKLMNOPQRSTUVWXYZÆØÅ..
     <10><10><10><0>1
 TTBB:
 .TXT "   !       .       :       .       !       .       :       .       !<0>"
 TX01B: .+1*2
 .TXT '<10>TRACK NO:<0>' 
 BUFF1:   .+0 
     .-1 
     BUFF2 
     10 
     PCDS 
     0 
     0 
     0 
     0 
     0 
 BUFF2:   .+0 
     .-1 
     0 
     10 
     PCDS 
     0 
     0 
     0 
     0 
     0 
 PCDS:.+0 
     .-1 
     0 
     0 
     .TXT    'FD1RT' 
     .+0 
     .-1 
     BUFF1 
     PGDS 
     0 
     0 
     33 
     DEAD 
     0 
     0 
     0 
     
     0
     BIRTH*2
     0
     1
     2
     3
     4
     5
     6
     .END PCDS
     
     
     
     «ff»
«nul»