DataMuseum.dk

top - download

    Length: 2976 (0xba0)
    Types: TextFile
    Notes: C.LAGER3
    Names: »C.LAGER3«

└─⟦714f3848e⟧ Bits:30006597 ALM Copy 24.9.79
    └─ ⟦this⟧ »BASIC::C.LAGER3« 

TextFile

«ff»
  0010 REM PL OCT 79 LAGERANALYSE TIL TERMINAL! «so»C.LAGER3
  0020 REM LAGERANALYSE /BRUG CALL"GMEM",ADR,DATA/ DISASS. V. CB
  0030 PAGE=132
  0040 CLOSE 
  0045 LET STED=2
  0050 PROC LBL
  0060   LET L$="           "
  0070   LET A$="######                                            "
  0080   FOR J=0 TO 1
  0090     LET L$(J*32+STED,J*32+32+STED)=A$
  0100   NEXT J
  0110 ENDPROC
  0120 LET LMAX=64
  0270 PROC RAD
  0280   LET D$="0000"
  0290   FOR II=1 TO 4
  0300     LET H=X DIV 16; C=X MOD 16; X=H; C=C+48
  0310     IF C>57 THEN LET C=C+7
  0320     LET D$(5-II)=CHR(C)
  0330   NEXT II
  0340 ENDPROC
  0350 DIM D$(4),E$(4),V(4),W(4)
  0360 DIM A$(34)
  0370 DIM INSTR$(256,17),SKIP$(8,4),CARRY$(4),SHIFT$(4),F$(4),T$(8),OUT$(20)
  0380 OPEN FILE(1,1)"SYMBFIL"
  0390 FOR I=1 TO 256
  0400   READ FILE(1)INSTR$(I)
  0410 NEXT I
  0420 FOR I=1 TO 8
  0430   READ FILE(1)SKIP$(I)
  0440 NEXT I
  0450 CLOSE FILE(1)
  0460 LET CARRY$=" ZOC"; SHIFT$=" LRS"; F$=" SCP"; T$="BNBZDNDZ"
  0470 REM 15.9.79
  0480 LET NNNN=128
  0490 DIM L$(160)
  0500 INPUT "STARTADRESSE: ",IP1
  0550 PRINT USING "<10>ADR: ######       (PAGE ###.#)     ########<10>",IP1,IP1/256,IP1+20
  0560 FOR ADR=IP1 TO IP1+19
  0580   EXEC LBL
  0590   FOR J=0 TO 1
  0600     LET I=ADR+J*20
  0610     CALL "GMEM",I,B
  0620     LET X=B; W(J+1)=B
  0630     EXEC RAD
  0660     LET BB=B; OUT$=INSTR$(B DIV 256+1),"                   "; OUT$(20)="*"; L$(J*32+9,J*32+12)=D$
  0670     REM
  0680     IF B>32767 THEN 
  0690       LET OUT$(4)=CARRY$(B MOD 64 DIV 16+1)
  0700       LET OUT$(4+(OUT$(4)<>" "))=SHIFT$(B MOD 256 DIV 64+1)
  0710       LET OUT$(6)=CHR(32+B MOD 16 DIV 8*5)
  0720       LET OUT$(13,16)=SKIP$(B MOD 8+1),"     "
  0730       LET OUT$(20)="#"; BB=10
  0740     ELSE
  0750       IF B>24575 THEN 
  0760         IF OUT$(1)<>"S" AND OUT$(1)<>"F" THEN LET OUT$(4)=F$(B MOD 256 DIV 64+1)
  0770         IF OUT$(1)="S" THEN LET OUT$(4,5)=T$(B MOD 256 DIV 64+1,B MOD 256 DIV 64+2),"  "
  0780         IF OUT$(1,4)="FEJL" THEN LET OUT$=" #                   *"; BB=10
  0790         IF OUT$(1)<>"F" THEN LET BB=B MOD 64
  0800       ELSE
  0810         LET BB=B MOD 256-(B MOD 1024 DIV 256<>0)*(B MOD 256>127)*256
  0820         IF B>16384 AND B<24064 THEN 
  0830           LET XB=B MOD 256
  0840           IF (XB<94 AND XB>44) OR XB=32 OR XB=0 THEN 
  0850             IF XB=0 OR XB=46 THEN LET XB=42
  0860             LET OUT$(19,20)=CHR(B DIV 256),CHR(XB)
  0870           ENDIF
  0880         ENDIF
  0885         IF B<256 THEN LET OUT$="###                *"; BB=B
  0890       ENDIF
  0900     ENDIF
  0910     LET L$(J*32+1)=CHR(I MOD 10+48); L$(J*32+14,J*32+31)=OUT$(1,7),OUT$(10,20); V(J+1)=BB
  0920   NEXT J
  0930   LET L$=L$(1,128)
  0940   PRINT USING L$(1,LMAX),W(1),V(1),W(2),V(2)
  0950 NEXT ADR
  0970 GOTO 0500
  0980 FOR KK=1 TO 128
  0990   PRINT KK;L$(KK),
  1000 NEXT KK
«nul»