DataMuseum.dk

top - download

    Length: 3072 (0xc00)
    Types: TextFile
    Names: »VASP«

└─⟦7028332c6⟧ Bits:30001795 SG0015 Floppy
    └─ ⟦this⟧ »/VASP« 
└─⟦8b5200720⟧ Bits:30001802 SG0022 Floppy
    └─ ⟦this⟧ »/VASP« 

TextFile

; SP DRIVER TIL 1/2 TERM 02
; 9600 BAUD, 2 STOP, 7 DATA, NO PARITY
; AMX CH. 2
;
; IKKE TESTET MED AMX-DRIVER INDE !!!!
;
; INITIERER SELV OVENSTÅENDE PARAMETRE
; HANDSHAKE VIA RTS OG RFS PÅ AMX
;
;
	.TITL	VASP
	.NREL
	.RDXO	16
	.RDX	10
	.TXTM	1
	.DUSR	AMX=42
	
PGDS:	1B0+1B1+1B7+1
	PGM
	0
	PCDS-PGDS
	.TXT 	'SP<0><0><0>'

PGM:  	SUB 1,1	; STD DRIVER BRK.
	MOVZL 0,0,SNC
	STA 1,RESER,2
ST:	JSR WAMX	; SÆTN. SOM DENNE ER NØDV. FOR AMX. ELLERS KAN DEN IKKE FØLGE MED
	LDA 0,C0230	; INIT AF PARAMS (BAUD,STOP,DATA OG PAR. BITS)
	DOC 0,AMX
	JSR WAMX
	LDA 0,C021D
	DOC 0,AMX
	JSR WAMX
	LDA 0,C0208	; SÆT DTR ON, MODEM SIGNAL TIL PRINTER.
	DOA 0,AMX
	JSR WAMX
	LDA 0,C0202	; START TRANSMITMODE (SENDER) (DET ER JO DET DET DREJER SIG OM !!)
	DOA 0,AMX
   	LDA 2,CUR	; STD FOR DRIVER, SIDE 196 PP DOMUS REF.
	NEXTO
	SETRE
	JMP P4
P1:	LDA 1,ADDRE,2
	GETBY
P2:	LDA 1,C0205	; HENT MODEM STATUS OG SMID VÆK
	JSR WAMX	; RESET'ER AMX-HARDWARE ABS. NØDV.
	DOA 1,AMX
	JSR WAMX
	DIA 1,AMX
	MOVL 1,1	; (K)
	MOVL 1,1,SNC	; (K)
	JMP P3		; (K)
	SUB 1,1		; (K)
	LDA 2,.24	; (K)
	WAITI		; (K)
	JMP P1		; (K)
P3:	LDA 1,C0207	; HVIS OUTPUT BUFFER TOM, SEND CHR. ELLERS PRØV IGEN.
	JSR WAMX
	DOA 1,AMX
	JSR WAMX
	DIA 1,AMX
	MOVL 1,1
	MOVL 1,1,SNC
	JMP P1
	LDA 1,.127	; FJERN ØVERSTE 9 BIT, OG LÆG CHNR*256 TIL (7*256)
	AND 1,0
	LDA 1,.2
	MOVS 1,1
	ADD 0,1
	JSR WAMX
	DOB 1,AMX	; SEND CHR. (POKKERS BESVÆR AT SLIPPE AF MED DEN...)
	ISZ ADDRE,2
	DSZ COUNT,2
	JMP P1
P4:	SUB 0,0		; STD DRIVER...
	RETUR
	JMP ST
WAMX:	JMP .+1
	JMP .+1
	JMP .+1
	JMP .+1
	JMP .+1
	JMP .+1
	JMP .+1
	JMP .+1
	JMP +0,3
C0202:	514
C0208:	520
C0230:	560
C021D:	541
C0205:	517
C0207:	519
PCDS:	0
	0
	0
	PCDSE-PCDS
	.TXT 'SP<0><0><0>'
	.+0
	.-1
	0
	PGDS
	0
	0
	52
	PGM	
	PCDS
	0
	PCDS
	0
	PGM*2
	0
	0
	0
	0
	0
	0
	0
	0
	0
PCDSE:	
	.END PCDS
«ff»
«nul»