|
DataMuseum.dkPresents historical artifacts from the history of: Zilog MCZ Floppy Disks |
This is an automatic "excavation" of a thematic subset of
Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - download
Length: 6538 (0x198a)
Types: TextFile
Names: »AER.FORMAT.SYMB.BP«
└─⟦70e1b4124⟧ Bits:30006818 8" ZilogMCZ floppy NThun_0020 (21/5-82 MAPDAT AEROTRIANGULERING COPYRIGHT VIAK A/S)
└─ ⟦this⟧ »AER.FORMAT.SYMB.BP«
10 REM AER.FORMAT ZILOG
11 SYSTEM "AUTOCROFF"
12 SYSTEM "WARNOFF"
PROGRAMMET LESER FILER REGISTRERT I AUTOGRAF/REGVERK OG
OMFORMATTERER DISSE TIL DET FORMATET SOM BENYTTES I AERO-
TRIANGULERINGSPROGRAMMET TIL NGO.
PROGRAMMET BER OM FILNAVN PA DATAFILEN, DERETTER LESES F0RSTE
RECORD, DET TESTES OM DENNE ER MODELLNR., HVIS IKKE MA DETTE
GIS. DERETTER BER PROGRAMMET OM FILNAVN FOR MODELLDOKUMENTASJON.
PROJEKSJONSSENTERETS KOORDINATER LESES FRA DENNE FILEN.
20 DIM A$(80),S1$(1),A1$(80),B9$(27),F$(32),G0$(32),B$(300,27),M$(6),G$(1),S$(1)
30 LET N%=1
50 LET G$="5"
60 DEF FNC$(L%,K% )= CHR$(27)+"Y"+CHR$(31+L%)+CHR$(31+K%)
90 REM -----------------
100 PRINT CHR$(27);"E"
CLEAR SKJERM
110 PRINT FNC$(5,1);"GI FILNAVN FOR FERDIG FORMATERTE DATA :__________________";FNC$(5,40);
120 LINPUT "",F$
200 DOEND
300 REM ------------
310 PRINT FNC$(8,1);"GI FILNAVN FOR REGISTRERTE DATA :_____________________";FNC$(8,34);
320 LINPUT "",A$
330 FILE #2;A$+";ACC=IN",C%
340 IF C%<>0 THEN DO
350 PRINT CHR$(7)
360 PRINT FNC$(22,1);"FEIL I FILNAVN/FILEN FINNES I K K E !!"
370 PRINT FNC$(23,1);"TRYKK RETURN FOR A FORTSETTE";
380 LINPUT "",A$
390 PRINT FNC$(22,1);" ";
391 PRINT FNC$(23,1);" ";
392 GOTO 300
399 DOEND
500 REM --------------
NA ER VI KLAR TIL A LESE RECORDS FRA FILEN
510 LINPUT #2;A$
515 IF EOF(2) THEN 9000
SLUTT PA DATA PA DENNE FILEN
525 REM -------------
527 IF A$(20,24)="MODNR" THEN DO
530 LET M$=A$(10,15)
540 GOTO 600
541 DOEND
542 REM -----------
545 PRINT FNC$(11,1);"GI MODELLNR. :______";FNC$(11,15);
550 LINPUT "",M$
555 IF LEN(M$)<>6 THEN DO
560 PRINT CHR$(7)
565 PRINT FNC$(22,1);"FEIL ANTALL SIFFER, TRYKK RETURN FOR A FORTSETTE";
570 LINPUT "",S$
575 PRINT FNC$(22,1);" ";
580 GOTO 542
585 DOEND
600 REM -----------
650 GOSUB 8000
FA MED PROJEKSJONSSENTERET
700 REM ----------
705 LINPUT #2;A$
706 IF EOF(2) THEN GOSUB 1000
707 IF EOF(2) THEN 9000
710 IF A$(20,24)="MODNR" THEN DO
712 GOSUB 9500
714 GOTO 525
716 DOEND
720 IF A$(20,21)="TP" THEN 7000
725 IF A$(20,21)="PP" THEN 6500
730 IF A$(20,21)="FP" THEN 6000
740 IF A$(20,21)="AN" THEN 5000
750 IF A$(20,21)="VA" THEN 4000
755 IF A$(20,21)="NY" THEN 3000
760 GOTO 700
1000 REM ---------------
RUTINEN FOR UTLESING P] FIL
1010 LET N%=N%+1
1020 IF N%>300 ! S1$="N" THEN 1100
1030 RETURN
1100 REM --------
1105 LET N%=N%-1
1110 FILE #1;F$
1115 REM ---------
1120 LINPUT #1;A$
1125 IF EOF(1) THEN 1200
1130 GOTO 1115
1200 REM ---------
1210 FOR I1%=1 TO N%
1220 PRINT #1;B$(I1%)
1230 NEXT I1%
1240 LET N%=1
1245 CLOSE #1
1250 RETURN
2000 REM ------------
RUTINEN FOR ] INITIALISERE B$
2010 LET B$(N%)=" "
2020 RETURN
3000 REM -------------
RUTINEN SETTER OPP FORMATET FOR NYPUNKT
3010 GOSUB 2000
INITIALISER B$
3020 LET B$(N%,3,6)=A$(12,15)
3040 LET B$(N%,8,13)=A$(29,34)
3050 LET B$(N%,15,20)=A$(42,47)
3060 LET B$(N%,22,27)=A$(55,63)
3070 GOSUB 1000
3080 GOTO 700
4000 REM --------------
DENNE RUTINEN SETTER OPP FORMATET FOR ANNET
4010 GOSUB 2000
INITIALISER B$
4020 LET B$(N%,1,1)="9"
4030 LET B$(N%,2,6)=A$(11,15)
4040 LET B$(N%,8,13)=A$(29,34)
4050 LET B$(N%,15,20)=A$(42,47)
4060 LET B$(N%,22,27)=A$(55,63)
4190 GOSUB 1000
4199 GOTO 700
5000 REM --------------
DENNE RUTINEN SETTER OPP FORMATET FOR ANNET
5010 GOSUB 2000
INITIALISER B$
5020 LET B$(N%,1,1)=G$
5030 LET B$(N%,2,2)="8"
5040 LET B$(N%,3,6)=A$(12,15)
5045 LET B$(N%,8,13)=A$(29,34)
5050 LET B$(N%,15,20)=A$(42,47)
5060 LET B$(N%,22,27)=A$(55,63)
5190 GOSUB 1000
5199 GOTO 700
6000 REM -------------
RUTINEN ER FOREL0PIG EN RETTERUTINE FOR FEIL REGISTRERINGER
AV NYPUNKT REGISTRERT SOM FPPKT
6010 GOTO 3000
6500 REM ---------------
DENNE RUTINEN SETTER OPP FORMATET FOR PP
6510 GOSUB 2000
6520 LET B$(N%,1,1)=G$
6530 LET B$(N%,2,2)="4"
6540 IF A$(24,24)="T" THEN B$(N%,2,2)="5"
DET VAR TOPP SIGNAL
6550 GOTO 7200
RESTEN AV RUTINEN ER IDENTISK MED TP-RUTINE
7000 REM -------------
DENNE RUTINEN SETTER OPP FORMATET FOR TP
7010 GOSUB 2000
INITIALISER B$
7020 LET B$(N%,1,1)=G$
7030 IF A$(22,23)="VA" THEN DO
7040 LET B$(N%,2,2)="2"
7050 IF A$(24,24)="T" THEN B$(N%,2,2)="3"
DET VAR TOPP-PUNKT
7060 GOTO 7200
7070 DOEND
7100 LET B$(N%,2,2)="0"
ANTAR SIGNALFOT
7110 IF A$(24,24)="P" THEN B$(N%,2,2)="1"
DET VAR TOPP
7200 REM --------
7210 LET B$(N%,3,6)=A$(12,15)
7225 FOR I%=3 TO 6
7230 IF B$(N%,I%,I%)=" " THEN B$(N%,I%,I%)="0"
7235 NEXT I%
7240 LET B$(N%,8,13)=A$(29,34)
7250 LET B$(N%,15,20)=A$(42,47)
7260 LET B$(N%,22,27)=A$(55,63)
7270 GOSUB 1000
7280 GOTO 700
8000 REM -----------------
DENNE RUTINEN LESER FRA DOKUMENTASJONSFILENE OG SETTER FORMATET
FOR PROJEKSJONSSENTERET
8001 GOSUB 2000
8002 LET B$(N%,1,6)=M$
8003 GOSUB 1000
8005 PRINT CHR$(27);"E"
8010 PRINT FNC$(5,1);"********** P R O J E K S J O N S S E N T E R ***********"
8015 PRINT FNC$(7,1);"********* MODELLNR :";M$;" ************"
8020 REM ----------
8030 PRINT FNC$(9,1);"GI FILNAVN FOR GITTERMALING :______________________ (";G0$;")";FNC$(9,30);
8040 LINPUT "",A$
8045 IF A$="" THEN A$=G0$
8046 IF A$<>"" THEN G0$=A$
8050 FILE #9;A$+";ACC=IN",C%
8060 IF C%>0 THEN DO
8065 PRINT CHR$(7)
8070 PRINT FNC$(22,1);"FEIL I FILNAVN/FILEN EKSISTERER FRA F0R"
8075 PRINT FNC$(23,1);"TRYKK RETURN FOR A FORTSETTE";
8080 LINPUT "",A$
8090 GOTO 8020
8095 DOEND
8230 LET I%=1
8235 REM -----------
8240 LINPUT #9;A$
8255 IF I%=64 THEN 8400
8315 LET I%=I%+1
8320 GOTO 8235
8400 REM ---------
8410 LINPUT #9;A$
8415 LINPUT #9;A1$
8417 CLOSE #9
NA HAR VI F]TT DEN RECORD VI SKAL HA
8420 GOSUB 2000
8425 LET B9$=" "
8430 LET B9$(3,4)="00"
8440 LET B9$(1,2)=M$(1,2)
8450 LET B9$(5,6)=M$(5,6)
8460 LET B9$(8,13)=A$(10,15)
8470 LET B9$(15,20)=A$(21,26)
8480 LET B9$(22,27)=A$(32,37)
8485 LET B$(N%)=B9$
8490 GOSUB 1000
S] TAR VI ANDRE BILDET
8500 LET B9$(1,2)=M$(3,4)
8560 LET B9$(8,13)=A1$(10,15)
8570 LET B9$(15,20)=A1$(21,26)
8580 LET B9$(22,27)=A1$(32,37)
8585 LET B$(N%)=B9$
8590 GOSUB 1000
8599 RETURN
9000 REM --------------
RUTINE FOR ] ]PNE FLERE FILER
9010 PRINT CHR$(27);"E"
9020 PRINT FNC$(5,1);"SKAL FLERE FILER FORMATTERES ? (J/N) :_";FNC$(5,39);
9030 LINPUT "",S1$
9040 IF S1$<>"J" & S1$<>"N" THEN DO
9050 PRINT CHR$(7)
9060 GOTO 9020
9070 DOEND
9075 GOSUB 9500
9080 IF S1$="J" THEN 300
9100 END
9500 REM -------------
SUBRUTINE FOR ] SETTE SLUTT MODELL
9510 LET B$(N%)=" -99 0 0 0"
9520 GOSUB 1000
9530 RETURN