DataMuseum.dk

top - metrics - download

    Length: 1245 (0x4dd)
    Types: TextFile
    Notes: UNIX file
    Names: »filsys«

└─⟦26887b7e0⟧ Bits:30009717 Comet 32 harddisk image
    └─⟦28c352965⟧ »/a« UNIX Filesystem
        └─⟦this⟧ »sys/build/filsys« 

TextFile

#! /bin/csh -f

getprtb
if ($status) exit(1)
if (! -f $subs/partab) then
	echo "No partition info - cannot continue"
	exit(0)
endif
source $subs/partab

if (! -f $subs/autohelp) then
	echo ""
	echo "Type first 'h' (help) to next question."
endif

while (1)
	set part = `ask partsys "Give partition (dc1d to dc1h):"`
	switch ($part)
	case quit:
		echo "Skipping write of partition info"
		exit(1)
	case show:
		source $build/shoprtb
		continue
	case dc1[d-h]:
		eval @ size = \$$part\[1\] / 2
		breaksw
	case done:
		break
	endsw
	if ($size == 0) then
		echo "Partition $part has size 0 - cannot make a file system"
		continue
	endif
	echo "Partition $part - $size kilobytes"
	switch (`ask ynmkfs "All data in $part will be destroyed - continue?"`)
	case yes:
		breaksw
	default:
		continue
	endsw
	echo ""
	echo "Executing: mkfs /dev/r$part $size"
	echo "This is not a test - sleeping 10 seconds before proceeding"
	sleep 10
	mkfs /dev/r$part $size
	if ($status) then
		echo "Error in mkfs - are partition sizes correct?"
		continue
	endif
	echo ""
	echo "Executing: fsck -p /dev/r$part"
	fsck -p /dev/r$part
	if ($status) then
		echo "Excessive errors in $part - try again"
		continue
	endif
	set ${part}[2] = filsys
end

source $build/wriprtb