DataMuseum.dk

top - metrics - download

    Length: 2144 (0x860)
    Types: TextFile
    Notes: UNIX file
    Names: »groups«

└─⟦26887b7e0⟧ Bits:30009717 Comet 32 harddisk image
    └─⟦28c352965⟧ »/a« UNIX Filesystem
        └─⟦this⟧ »sys/build/groups« 

TextFile

#! /bin/csh -f

set noglob

if (-f $subs/usergrps) source $subs/usergrps
if (! $?groups) set groups = ()
set groups = ( `echoln $groups | sort -t: -n +1` )
if (! $?defgroup) set defgroup = ""
if (! $?defhome) set defhome = ""
if (! -f $subs/autohelp) source $build/shogrps

while (1)
	set nam = `ask grpnam "Give user group name:"`
	switch ($nam)
	case quit:
		exit(1)
	case show:
		source $build/shogrps
		continue
	case done:
		break
	endsw
	set line = ( `grep "^${nam}:" $subs/group | sed -e 's/:/ /g'` )
	if ($#line > 0) then
		echo "Standard group number $line[3]"
	endif
	set num = `ask grpnum "Give group number for $nam (or delete):"`
	switch ($num)
	case quit:
		exit(1)
	case delete:
		set groups = ( `echoln $groups | grep -v "^${nam}:"` )
		source $build/shogrps
		continue
	endsw
	if ($#line > 0) then
		if ($num != $line[3]) then
			echo "Cannot modify standard group number"
			continue
		endif
	else
		if ($num < 50) then
			echo "A new group must have number at least 50"
			continue
		endif
	endif
	set groups = ( `echoln $groups | egrep -v "^${nam}:|:${num}:"` )
	set hom = `ask grphome "Give group home directory for ${nam}:"`
	if ($hom == quit) exit(1)
	set groups = ($groups "${nam}:${num}:${hom}")
	set groups = ( `echoln $groups | sort -t: -n +1` )
	source $build/shogrps
end

echo ""
echo "Done with specific groups... now specify the defaults"

while (1)
	set num = `ask defgrp "Give default user group number:"`
	switch ($num)
	case quit:
		exit(1)
	case show:
		source $build/shogrps
		continue
	endsw
	echoln $groups | grep ":${num}:" > /dev/null
	if ($status) then
		echo "No user group $num"
		continue
	endif
	set defgroup = $num
	break
end
while (1)
	set hom = `ask defhome "Give default group home directory:"`
	switch ($hom)
	case quit:
		exit(1)
	case show:
		source $build/shogrps
		continue
	endsw
	set defhome = $hom
	break
end

source $build/wrigrps
echo ""
echo "Here's what our groups look like:"
source $build/shogrps
switch (`ask yngroups "Are you satisfied with the choices?"`)
case quit:
	exit(1)
case no:
	echo "Ok, let's start all over again..."
	exec groups
	exit(1)
endsw

source $build/nuconf