DataMuseum.dk

top - metrics - download

    Length: 1596 (0x63c)
    Types: TextFile
    Notes: UNIX file
    Names: »main«

└─⟦26887b7e0⟧ Bits:30009717 Comet 32 harddisk image
    └─⟦28c352965⟧ »/a« UNIX Filesystem
        └─⟦this⟧ »sys/build/main« 

TextFile

#! /bin/csh -f

source /sys/build/.buildrc
@ iflag = 0
while ($#argv != 0)
	switch ($argv[1])
	case -i:
		@ iflag = 1
		breaksw
	default:
		echo "Unknown flag: $argv[1]"
		exit(1)
	endsw
	shift
end
if ($iflag) then
	source $build/cutesy
else
	echo ""
	echo "    Type 'intro' for an introduction."
endif

set maxstep = `awk -f $build/awksteps $subs/steps`

while (1)
	set ans = `ask main "Build what?"`
	switch ($ans)
	case quit:
		echo "Type 'exit' to exit the build program."
		continue
	case exit:
		exit(0)
	case list:
		sed -e 's/.*://' $subs/steps
		continue
	case autohelp:
		if (-f $subs/autohelp) then
			echo "automatic help off"
			rm -f $subs/autohelp
		else
			echo "automatic help on"
			echo "" > $subs/autohelp
		endif
		continue
	case standout:
		if (-f $subs/standout) then
			setenv SO ''
			setenv SE ''
			echo "standout mode off"
			rm -f $subs/standout
		else
			setenv SO "`curse -so`"
			setenv SE "`curse -se`"
			if ($status) continue
			echo "standout mode on"
			echo "" > $subs/standout
		endif
		continue
	case all:
		set step = 01
		breaksw
	default:
		if (1 <= $ans && $ans <= $maxstep) then
			set step = $ans
		else
			echo "Step $ans doesn't exist."
			continue
		endif
	endsw
	while ($step <= $maxstep)
		set line = `sed -e "/$step/\\!d" $subs/steps`
		set prog = $line[1]
		echo ""
		echo "Step $line[3-]"
		switch (`ask $prog "Continue?"`)
		case quit:
			break
		case no:
			breaksw
		case y:
		case yes:
			$build/$prog
			if ($status) break
		endsw
		set step = `echo $step | awk '{ printf("%02d", $1+1) }'`
	end
	echo "Back to top level of build..."
end