DataMuseum.dk

top - metrics - download

    Length: 3840 (0xf00)
    Types: TextFile
    Names: »OPDAT.CMD«

└─⟦871340d2f⟧ Bits:30005949 RC Organisationsplan Diskette A 15/01-86
    └─⟦this⟧ »OPDAT.CMD« 

TextFile

*****************************************************************************
*    COMMANDO FILE TIL  RC    ORGANISATIONS PLAN                            *
*    NAVN : OPDAT.CMD     SIDST ÆNDRET DATO: 86.01.07   KL..: 14.35         *
*    KALDES FRA START.CMD VIA O1.MEN OG O2.MEN                              *
*****************************************************************************
USE
set escape on
store '  ' to ok
set talk off
use
erase
? ' ***   RC    ORGANISATIONS PLAN                 OPDATERING  O 2   ***'
? ' --------------------------------------------------------------------'
? ' ***   fjerner alle afdelings oplysninger som navne m.m.          ***'
? ' '
? ' 1. SKAL DER STARTES HELT FORFRA MED NULSTILLING  ?'
accept '     SÅ TAST  NY  ELLER  FORTRYD  SÅ RETUR  ........... ' to ok
if !(OK) <> 'NY'
    erase
    return
endif
*
store '  ' to ok
? ' '
? ' 2. DE GAMLE REGISTRE SKAL NULSTILLES          ,  VENT !'
set talk on
? ' '
? '    5  FILER SKAL SLETTES   ( DELETES )              '
? ' '
DELETE FILE ORG.NDX
DELETE FILE PLAN.NDX
DELETE FILE AFDTOT.NDX
*
use ORG
copy to orgwork structure
use
delete file ORG
rename orgwork to ORG
use ORG
index on AFNU + OVER to ORG
*
use AFDTOT
copy to aftowork structure
use
delete file AFDTOT
rename aftowork to AFDTOT
use AFDTOT
*
? ' '
? ' 3. OG SÅ TOTAL PÅ AFDELINGS-NR I AFDTOT       ,  VENT !'
? ' '
use med index med
total on afnu to afdtot fields afnu, sted for afnu < '99'
? ' '
? ' 4. LAV INDEX PÅ AFDELINGS-NR TIL AFDTOT       ,  VENT !'
? ' '
use afdtot
index on afnu to afdtot
? ' '
? ' 5. HENT OPLYSNINGER FRA DUMMY DATABASE        ,  VENT !'
? ' '
use org index org
append from dummy
? ' '
? ' 6. OPDATERING AF ORGANISATIONS DATABASE       ,  VENT !'
? ' '
set talk off
use afdtot index afdtot
go top
store afnu to nogle
store sted to wsted
store 1 to diflast
store 0 to difok
store 0 to difny
store T to nif
DO WHILE NIF
use org index org
find '&nogle'
 if # = 0
    append blank
    replace afnu with nogle
    replace sted with wsted
    replace navn with '     '
    replace chef with '     '
    replace over with '  '
    ? ' afdelings nummer oprettet  ............... '      , nogle
    store difny + 1 to difny
 else
   if sted <> wsted
      replace sted with wsted
   endif sted
   store difok + 1 to difok
 endif
*
use afdtot index afdtot
find '&nogle'
 if # = 0
    ? ' '
    ? ' antal læste afdelinger  .................. '      , diflast
    ? ' antal ok    afdelinger  .................. '      , difok
    ? ' antal nye   afdelinger  .................. '      , difny
    ? ' >>> FEJL  ved næste læs af AFDTOT  ......  tast retur '
    ? ' '
    wait
    store F to nif
    return
 endif
 skip 1
 if eof 
    store F to nif
    ? ' '
    ? ' antal læste afdelinger  .................. '      , diflast
    ? ' antal ok    afdelinger  .................. '      , difok
    ? ' antal nye   afdelinger  .................. '      , difny
    ? ' '
 endif eof
 store diflast + 1 to diflast
 store afnu to nogle
 store sted to wsted
loop
enddo nif
release nogle, slet, nif, diflast, difok, difslet, difny, wsted
*
? ' '
? ' 7. LAV INDEX PÅ AFDELINGSNUMMER               ,  VENT !'
? ' '
use org
set talk on
index on AFNU + OVER to ORG
? ' '
set talk off
*
? ' '
? ' 8. SLUT OPDATERING   RC ORGANISATIONS  PLAN          '
? '    HUSK AJOURFØR AFDELINGS OPLYSNINGER INDEN        !'
? '         FUNKTION 3 PÅ SKÆRMBILLEDE O 2 UDFØRES      !'
? '                                            TAST RETUR'
? ' -----------------------------------------------------'
set console off
wait
set console on
set escape off
store '  ' to ok
return
«eof»