|
DataMuseum.dkPresents historical artifacts from the history of: CP/M |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about CP/M Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 7424 (0x1d00)
Types: TextFile
Names: »LISTE4.CMD«
└─⟦871340d2f⟧ Bits:30005949 RC Organisationsplan Diskette A 15/01-86
└─⟦this⟧ »LISTE4.CMD«
*****************************************************************************
* COMMANDO FILE TIL RC ORGANISATIONS PLAN *
* NAVN : LISTE4.CMD SIDST ÆNDRET DATO: 86.01.08 KL..: 12.40 *
* KALDES I START.CMD VIA O1.MEN OG O5.MEN *
*****************************************************************************
SET TALK OFF
SET ESCAPE ON
STORE T TO LOKS
*
DO WHILE LOKS
store ' ' to SVARS
store ' ' to svar
store ' ' to ok
store ' ' to begyn
store ' ' to til
store ' ' to dagsdato
erase
text
*** RC ORGANISATIONS PLAN LISTE 4 ***
-----------------------------------------------------------------------------
RC AFDELINGER OG MEDARBEJDERE.
-----------------------------------------------------------------------------
0 = SLUT PÅ LISTE 4 OG RETUR
4 = SKRIV LISTEN
HVIS ALT ØNSKES SKREVET UD SÅ TAST $$ I FRA AFDELING,
ELLER TAST SPECIFIKT AFDELINGSNUMMER I FRA OG TIL,
ELLER TAST ET CIFFER OG $-TEGN !!!
-----------------------------------------------------------------------------
endtext
@ 19,0 say '* TAST * nummer ......................... ' get svar
read
*
if SVAR = '0'
store F to LOKS
loop
endif 8.0
*
IF !(svar) = '4'
store '4' to svars
endif a
if svars = ' '
loop
endif ej ok
*
USE ORG INDEX ORG
GO TOP
*
@ 20,0 say ' ---- udskrifts dato ................. ' get dagsdato
@ 21,0 say ' ---- FRA afdelings nummer ........... ' get begyn
@ 22,0 say ' ---- TIL afdelings nummer ........... ' get til
@ 23,0 say ' ---- OK hvis printer er klar ....... ' get ok
read
if !(OK) <> 'OK'
LOOP
ENDIF
store ' ' to fra
store ' ' to OK
store ' ' to gem
*
if $(begyn,2,1) = '$'
store $(begyn,1,1) to fra
endif
if $(begyn,1,1) <> '$' .and. fra = ' '
store begyn to fra
endif
*
if '&begyn' = '$$'
store ' ' to nogle
store ' ' to fra
store '99' to til
endif
*
if '&fra' <> ' '
store '&fra' to nogle
find '&nogle'
if # = 0
@ 23,0 say '>>>> FRA NUMMER IKKE FUNDET ! TAST RETUR <<<<' get ok
read
loop
endif
endif
*
@ 23,0 say ' **** LISTEN ER PÅ VEJ , VENT ****'
store '4' to plist
store 'AFDELING OG MEDARBEJDERE' TO PTEX1
store 'FRA AFDELINGS NUMMER .....:' TO PTEX2
store 'TIL AFDELINGS NUMMER .....:' TO PTEX3
SET CONSOLE OFF
do fside
store 99 to linie
set print on
set format to print
store ' ' to gem
store 'nex' to funk
*
DO WHILE FUNK <> ' '
*
*******************************************************************************
*** funk = nex næste record læses ***
*******************************************************************************
if funk = 'nex'
*
if linie > 60
store 01 to linie
? CHR(30)
? chr(31)
@ linie,08 say 'RC ORGANISATIONS PLAN'
store linie + 2 to linie
? CHR(30)
@ linie,08 say 'LISTE 4'
@ linie,56 say 'UDSKRIFTS DATO'
@ linie,72 say dagsdato using 'XXXXXX'
store linie + 2 to linie
@ linie,08 say 'AFD.NR'
@ linie,15 say 'AFDELINGS NAVN'
@ linie,40 say 'ANSV.'
@ linie,50 say 'STED'
@ linie,60 say 'OVERORD.AFD.'
store linie + 3 to linie
endif ny side
*
@ linie,08 say afnu using 'XX'
@ linie,15 say navn using 'XXXXXXXXXXXXXXXXXXXX'
@ linie,40 say chef using 'XXXXX'
@ linie,50 say sted using 'XXXXX'
@ linie,60 say over using 'XX'
store linie + 3 to linie
store afnu to gemafnu
store navn to gemnavn
store chef to gemchef
store sted to gemsted
store over to gemover
@ linie,15 say 'medarbejdere:'
store linie + 1 to linie
@ linie,15 say '-------------'
store linie + 2 to linie
@ linie,15 say 'NR.'
@ linie,24 say 'INIT'
@ linie,33 say 'STED'
@ linie,40 say 'PROCENT'
@ linie,50 say 'ANS.DATO'
@ linie,60 say 'AFG.DATO'
store linie + 2 to linie
store F to person
store gemafnu to mednogle
USE MED INDEX MED
find '&mednogle'
if # <> 0
store T to person
endif
*
DO WHILE PERSON
if linie > 60
store 01 to linie
? CHR(30)
? chr(31)
@ linie,01 say 'RC ORGANISATIONS PLAN'
store linie + 2 to linie
? CHR(30)
@ linie,08 say 'LISTE 4'
@ linie,56 say 'UDSKRIFTS DATO'
@ linie,72 say dagsdato using 'XXXXXX'
store linie + 2 to linie
@ linie,08 say 'AFD.NR'
@ linie,15 say 'AFDELINGS NAVN'
@ linie,40 say 'ANSV.'
@ linie,50 say 'STED'
@ linie,60 say 'OVERORD.AFD.'
store linie + 2 to linie
@ linie,08 say gemafnu using 'XX'
@ linie,15 say gemnavn using 'XXXXXXXXXXXXXXXXXXXX'
@ linie,40 say gemchef using 'XXXXX'
@ linie,50 say gemsted using 'XXXXX'
@ linie,60 say gemover using 'XX'
store linie + 3 to linie
@ linie,15 say 'medarbejdere:'
store linie + 1 to linie
@ linie,15 say '-------------'
store linie + 2 to linie
@ linie,15 say 'NR.'
@ linie,24 say 'INIT'
@ linie,33 say 'STED'
@ linie,40 say 'PROCENT'
@ linie,50 say 'ANS.DATO'
@ linie,60 say 'AFG.DATO'
store linie + 2 to linie
endif ny side
*
if init <> gemchef
@ linie,15 say manr using 'XXXXX'
@ linie,24 say init using 'XXXXX'
@ linie,33 say sted using 'XXXX'
@ linie,40 say anpr
@ linie,50 say anda using 'XXXXXX'
@ linie,60 say afda using 'XXXXXX'
store linie + 2 to linie
endif init
*
skip
if eof
store F to person
loop
endif
if afnu <> mednogle
store F to person
loop
endif
*
LOOP
ENDDO PERSON
*
USE ORG INDEX ORG
find '&gemafnu'
if # = 0
@ 23,0 say '>>>> GENLÆS ORG EJ OK ! TAST RETUR <<<<' get ok
store 'END' to funk
read
loop
endif
*
skip
if EOF
store 'END' to funk
loop
endif sidste record laest
*
if afnu > '&til'
store 'END' to funk
loop
endif afnu storre end til vaerdi
*
store 99 to linie
loop
endif nex
*
*******************************************************************************
*** funk = end slut på liste ***
*******************************************************************************
if funk = 'END'
? chr(30)
eject
set print off
set format to screen
do lside
SET CONSOLE ON
@ 23,0 say '**** LISTE 4 ER FÆRDIG ----->> TAST RETUR !!' get ok
read
store ' ' to funk
loop
endif end
*
ENDDO FUNK
ENDDO LOKS
*
release LOKS, FUNK, GEM, PLIST, PTEX1, PTEX2, PTEX3
release svar, svars, begyn, fra, til, dagsdato, mednogle, person
release gemafnu, gemchef, gemsted, gemnavn, gemover
store ' ' to ok
SET ESCAPE OFF
use
return
«eof»