DataMuseum.dk

top - metrics - download

    Length: 4096 (0x1000)
    Types: TextFile
    Names: »STATBHDL.CMD«

└─⟦7b7460039⟧ Bits:30005889 KnowledgeMan - ACP - dBase II
    └─⟦this⟧ »STATBHDL.CMD« 

TextFile

* PROGRAM : STATBHDL.CMD       V. 1.0                     JEKK/070884
set talk off
ERASE
? 'TOTAL BATCH-KØRSEL AF PROJEKT-STATUS SKÆRMBILLEDER OVERFØRT VIA ACP'
? 'TIL FILEN STATUS.LOG'
IF .NOT. FILE('STATUS.LOG')
    ? '*** STATUS.LOG FILEN FINDES IKKE  ... VI STOPPER HER! '
    RETURN
ENDIF
IF FILE('STATXXX.DBF')
   DELETE FILE STATXXX.DBF
ENDIF
IF FILE('KEY1.DBF')
   DELETE FILE KEY1.DBF
ENDIF
IF FILE('KEY2.DBF')
   DELETE FILE KEY2.DBF
ENDIF
? 'Det forudsættes, at printeren er klar med A4HØJ !!!!'
ACCEPT 'Tast status-uge (ååuu) ? ' TO STATUGE
IF .NOT. FILE('STATUS.DBF')
    ? 'DBASE FILEN STATUS.DBF FINDES IKKE ...'
    ? 'DEN SKAL VÆRE CREATET MED FØLGENDE STRUCTUR :'
    ? ' LINIE     ,C     ,80'
    ? ' PNR       ,C     ,6'
    ? ' UGE       ,C     ,2'
    ? ' REVNR     ,C     ,5'
    ? ' REVUGE    ,C     ,5'
    ? ' PNAVN     ,C     ,20'
    ? ' PLEDER    ,C     ,5'
    ? ' AFD       ,C     ,2'
    ? ' VURDUGE   ,C     ,5'
    ? ' PSLUT     ,C     ,7'
    ? ' AKTNR     ,C     ,4'
    ? ' ANAVN     ,C     ,28'
    ? ' INIT      ,C     ,5'
    ? ' PLAN      ,N     ,7   ,1'
    ? ' FORBR     ,N     ,7   ,1'
    ? ' REST      ,N     ,7   ,1'
    ? ' PB        ,C     ,1'
    ? ' PBUGE     ,C     ,2'
    ? ' KOMBIKEY1 ,C     ,15  sammensat af PLEDER+PNR+INIT'
    ? ' KOMBIKEY2 ,C     ,11  sammensat af INIT+PNR'
    RETURN
ENDIF
? 'start på indlæsning ..'
USE STATUS.DBF
copy to help.dbf struc
? '..'
use
delete file status.dbf
rename help.dbf to status.dbf
? '...'
USE STATUS.DBF
APPEND FROM STATUS.LOG SDF
? 'Nu er status.log overført til status.dbf'
? 'De status-projekt-orienterede felter udfyldes nu ...'
GOTO TOP
 store ' ' to mpnr,muge,mrevnr,mrevuge,mpnavn,mpleder,mafd,mvurduge,mpslut
DO WHILE .NOT. EOF
   skip
IF LINIE='Status'
   store $(linie,20, 6) to mpnr
   store $(linie,69, 2) to muge
   skip
   store $(linie,14, 3) to mrevnr
   store $(linie,21, 5) to mrevuge
   skip 2
   store $(linie, 1,20) to mpnavn
   store $(linie,36, 4) to mpleder
   store $(linie,49, 2) to mafd
   store $(linie,58, 5) to mvurduge
   store $(linie,72, 7) to mpslut
   skip 4
endif
if len(trim($(linie,36,4)))>1 .and. $(linie,38,1)<>'*' ;
 .and. val($(linie,41,7))<>0;
  .and. val($(linie,57,7))<>0
STORE LINIE TO LI
repl pnr with mpnr;
 uge with muge;
 revnr with mrevnr;
 revuge with mrevuge;
 pnavn with mpnavn;
 pleder with mpleder;
 afd with mafd;
 vurduge with mvurduge;
 pslut with mpslut
repl aktnr with $(li,1,4);
 anavn with $(li,6,20);
 init with $(li,36,4);
 plan with val($(li,41,7));
 forbr with val($(li,49,7));
 rest with val($(li,57,7));
 pb with $(li,65,1);
 pbuge with $(li,66,2);
 KOMBIKEY1 WITH PLEDER+PNR+INIT;
        KOMBIKEY2 WITH INIT+PNR
endif
enddo
? 'så er felterne udfyldt.'
? '..'
 ? 'vi fjerner lige de overflødige linier fra status-skærmbilled-hovederne ..'
 goto top
copy to statcop for rest<>0
use
rename status.dbf to statxxx.dbf
rename statcop.dbf to status.dbf
 ? 'sådan, det var det ..'
use status
? 'index-filer til kombikey-felterne etableres nu'
? 'start på key1 -'
index on kombikey1 to key1
? 'sådan..'
? 'start på key2 -'
index on kombikey2 to key2
? 'sådan'
? '--'
? 'Vi komprimerer på key1 .. nu'
use status index key1
total to key1.dbf on kombikey1
? 'herefter på key2 ... nu'
use status index key2
total to key2 on kombikey2
? '.....'
   set heading to &statuge
   use key1
   report form key1 to print
   use key2
   report form key2 to print
   ? 'det var alt for denne gang ..'
return
«eof»