DataMuseum.dk

top - metrics - download

    Length: 4864 (0x1300)
    Types: TextFile
    Names: »MANUF.MOD«

└─⟦6ae1c04a5⟧ Bits:30004364 SW1656 IFPS/Personal Version 2.10 release 1.1
    └─⟦this⟧ »MANUF.MOD« 

TextFile

COLUMNS 1..12,TOTAL
ØØ
ØØ  This model simulates a materials requirements planning process
ØØ  where a production must be planned and adjusted for seasonal   
ØØ  production demand.  The focus of the analysis is on the labor
ØØ  requirements necessary to meet the production schedule.  The
ØØ  model allows for adjustments to demand and makes decisions on
ØØ  layoffs and overtime that would be required.
ØØ
ØØ    PRODUCT REQUIREMENTS AND INVENTORY
ØØ
BASE PRODUCTION=MEAN(SALESÆ1Å,SALESÆ12Å)
SMOOTHED PRODUCTION=IF BASE PRODUCTION .GT. SALES .AND. PEAK = -1 '
                    .AND. LAYOFF KEY = -1 THEN PRODUCT REQUIREMENTS - '
                    BEGINNING INVENTORY ELSE '
                    BASE PRODUCTION * SMOOTHING FACTOR
PRODUCT REQUIREMENTS=SALES + SAFETY STOCK
BEGINNING INVENTORY=SAFETY STOCK,PREVIOUS ENDING INVENTORY
ENDING INVENTORY=BEGINNING INVENTORY + TOTAL PRODUCTION - '
                 PRODUCT REQUIREMENTS + SAFETY STOCK
INVENTORY CARRYING COSTS=(BEGINNING INVENTORY + ENDING INVENTORY) / 2 * '
                         INVENTORY RATE
ØØ
ØØ    PRODUCT AVAILABILITY
ØØ
BASE PRODUCT AVAILABLE = BEGINNING INVENTORY + SMOOTHED PRODUCTION
SHORTFALL=PRODUCT REQUIREMENTS - BASE PRODUCT AVAILABLE
EXCESS PRODUCT REQUIRED = MAXIMUM(0,SHORTFALL)
TOTAL PRODUCTION=IF INEFFICIENCY HOURS .GT. 0 '
                 THEN (REGULAR HOURS + OVERTIME HOURS - '
                 INEFFICIENCY HOURS + SLACK HOURS) * UNITS PER HOUR ELSE '
                 (REGULAR HOURS + OVERTIME HOURS) * UNITS PER HOUR
ØØ
ØØ    PLANNING FOR PRODUCTION INCREASES
ØØ
SMOOTHED TEST=BASE PRODUCTION * SMOOTHING FACTOR
BEGINNING INVENTORY TEST=INITIAL INVENTORY,PREVIOUS ENDING INVENTORY TEST
ENDING INVENTORY TEST=BEGINNING INVENTORY TEST + SMOOTHED TEST - SALES
BASE AVAILABLE TEST=BEGINNING INVENTORY TEST + SMOOTHED TEST
TEST=MAXIMUM(PRODUCT REQUIREMENTS - BASE AVAILABLE TEST,0)
ADJUSTED TEST=IF FUTURE TEST > 0 THEN FUTURE TEST - TEST ELSE 0
CUMULATIVE TEST=ADJUSTED TEST + PREVIOUS
PLANNED SHORTFALL=CUMULATIVE TESTÆ12Å / 12
PLANNED SHORTFALL HOURS=IF FUTURE BEGINNING INVENTORY TEST .LE. 0 .AND. '
                        FUTURE ENDING INVENTORY TEST .GE. 0 THEN 0 ELSE '
                        PLANNED SHORTFALL / UNITS PER HOUR
PLANNED SHORTFALL LABOR= IF NEW HIRE KEY = 1 THEN '
                         ROUND(PLANNED SHORTFALL HOURS/HOURS PER MONTH) '
                         ELSE 0
ØØ
ØØ    RESULTING LABOR REQUIREMENTS
ØØ
BASE HOURS=SMOOTHED PRODUCTION / UNITS PER HOUR
BASE LABOR=ROUNDUP(BASE HOURS/HOURS PER MONTH)
BASE OVERTIME AVAILABLE=BASE HOURS * MAX OVERTIME
ØØ
EXCESS HOURS REQUIRED=EXCESS PRODUCT REQUIRED / UNITS PER HOUR + '
                      PLANNED SHORTFALL HOURS
ADDL LABOR NEEDED=IF EXCESS HOURS REQUIRED .GE. BASE OVERTIME AVAILABLE '    
                  THEN ROUNDUP((EXCESS HOURS REQUIRED - '
                  BASE OVERTIME AVAILABLE) / OVERTIME PER MONTH) + '
                  PLANNED SHORTFALL LABOR ELSE PLANNED SHORTFALL LABOR
TOTAL LABOR=BASE LABOR + ADDL LABOR NEEDED
LABOR CHANGE=TOTAL LABOR - INITIAL WORKERS,'
             TOTAL LABOR - PREVIOUS TOTAL LABOR
LABOR CHANGE COST=IF LABOR CHANGE .GE. 0 THEN LABOR CHANGE * HIRE COSTS '
                  ELSE -1 * LABOR CHANGE * LAYOFF COSTS
INEFFICIENCY HOURS=IF LABOR CHANGE > 0 THEN LABOR CHANGE * '
                   EFFICIENCY LOSS ELSE 0
ØØ
ØØ    COST AND HOURS TOTALS
ØØ
TOTAL COST=REGULAR LABOR COST + PREMIUM LABOR COST + LABOR CHANGE COST + '
           INVENTORY CARRYING COSTS
CUMULATIVE TOTAL COST=PREVIOUS + TOTAL COST
ØØ
REGULAR HOURS = BASE HOURS AVAILABLE
SLACK HOURS = MAXIMUM(0,REGULAR HOURS - '
              (BASE HOURS - EXCESS HOURS REQUIRED))
OVERTIME HOURS=MAXIMUM(0,TOTAL HOURS REQUIRED-BASE HOURS AVAILABLE)
TOTAL HOURS REQUIRED=BASE HOURS+EXCESS HOURS REQUIRED+INEFFICIENCY HOURS
BASE HOURS AVAILABLE=(BASE LABOR + ADDL LABOR NEEDED) * 160
REGULAR LABOR COST=REGULAR HOURS * REGULAR WAGE RATE
PREMIUM LABOR COST=OVERTIME HOURS * PREMIUM WAGE RATE
TOTAL LABOR COST=REGULAR LABOR COST + PREMIUM LABOR COST + '
                 LABOR CHANGE COST
ØØ
ØØ    TOTAL COLUMN DEFINITIONS
ØØ
REDEFINE TOTAL=SUM(Æ1Å .. Æ12Å)
ØØ
ØØ DATA INPUTS:
SALES=DATA
PEAK=DATA  
MAX OVERTIME=DATA
HIRE COSTS=DATA
NEW HIRE EFFICIENCY=DATA
LAYOFF COSTS=DATA
OVERTIME PREMIUM=DATA
INITIAL WORKERS=DATA
INVENTORY RATE=DATA
INITIAL INVENTORY=DATA 
SAFETY STOCK=DATA 
UNITS PER HOUR=DATA
REGULAR WAGE RATE=DATA
NEW HIRE KEY=DATA
HOURS PER MONTH=DATA
SMOOTHING FACTOR=DATA
LAYOFF KEY=DATA
OVERTIME PER MONTH=HOURS PER MONTH * (1 + MAX OVERTIME)
PREMIUM WAGE RATE=REGULAR WAGE RATE * (1 + OVERTIME PREMIUM)
EFFICIENCY LOSS=(1-NEW HIRE EFFICIENCY) * HOURS PER MONTH
«eof»