DataMuseum.dk

top - metrics - download

    Length: 2048 (0x800)
    Types: TextFile
    Names: »PPLSEARC.PRG«

└─⟦71c82d5c0⟧ Bits:30004214 LISTAID - Partslist management system
    └─⟦this⟧ »PPLSEARC.PRG« 
└─⟦9ce0f2175⟧ Bits:30004308/disk3.imd Listaid database backup
    └─⟦this⟧ »PPLSEARC.PRG« 

TextFile

*******************************************************************************
* PROCEDURE PPLSEARCH
*******************************************************************************
*
*SEARCHES IN CURRENTLY USED PPL FOR GENERIC NAME IN MGEN
*DISPLAYS SELECTED FIELDS FROM THE RECORDS FOUND
*******************************************************************************

*OPEN PPL
SET LINKAGE OFF
SET EXACT OFF
SELECT SECO
STORE $(PPLNAME,1,2)-'PPL_'-$(PPLNAME,3,4)-'.DBF' TO MPPL
USE &MPPL

*BLANK SCREEN
ERASE
SET FORMAT TO SCREEN


*SEARCH
STORE 10 TO MPOINT
DO WHILE MPOINT>1.AND.$(MGEN,MPOINT,1)=' '
   STORE MPOINT-1 TO MPOINT
   STORE $(MGEN,1,MPOINT) TO MGEN
ENDDO
LOCATE FOR GEN:NAME=MGEN

*OUTPUT HEADER
IF .NOT.MGEN$GEN:NAME
   @ 1,4 SAY 'NO ENTRIES WITH GENERIC NAME= '+MGEN
ELSE
   @ 1,4 SAY 'ENTRIES WITH GENERIC NAME= '+MGEN-':'
   @ 2,3 SAY '======================================'
   @ 4,4 SAY 'REF.C '
   @ 4,14 SAY 'GEN.NAME'
   @ 4,26 SAY 'GENERAL REMARK        VALUE       MAIN CHARACTERISTICS'
   @ 5,3 SAY '----------------------------------------------------------------;
-------------'
ENDIF

*WHILE MORE MATCHING RECORDS OUTPUT LISTING
STORE ' ' TO DUMMY
STORE 7 TO ROW
DO WHILE MGEN$GEN:NAME.AND..NOT.EOF
   @ ROW,4 SAY REF:CODE USING 'XXXXXX'
   @ ROW,14  SAY GEN:NAME USING 'XXXXXXXXXX'
   @ ROW,26  SAY GEN:REM  USING 'XXXXXXXXXXXXXXXXXXXX'
   @ ROW,48  SAY CVALUE   USING 'XXXXXXXXXX'
   @ ROW,60  SAY MAIN:CHAR USING 'XXXXXXXXXXXXXXXXXXXX'
   STORE ROW+1 TO ROW
   STORE # TO OLD
   CONTINUE

   IF ROW>19.AND.MGEN$GEN:NAME.AND.#<>OLD
      @ ROW,4 SAY 'PRESS RETURN FOR MORE OUTPUT ' GET DUMMY PICTURE 'X'
      READ
      STORE 7 TO ROW
   ENDIF
   IF #=OLD
      SKIP
   ENDIF
ENDDO
DO WHILE ROW<20
   @ ROW,0 SAY '                                                              ;
                '
   STORE ROW+1 TO ROW
ENDDO


RELEASE ROW,DUMMY
USE
SELECT PRIM
SET EXACT ON
RETURN
«eof»