DataMuseum.dk

top - metrics - download

    Length: 3584 (0xe00)
    Types: TextFile
    Names: »KONVLIN.CMD«

└─⟦7b7460039⟧ Bits:30005889 KnowledgeMan - ACP - dBase II
    └─⟦this⟧ »KONVLIN.CMD« 

TextFile

*KONVLIN
*KONVERTERER ET FORUD ANGIVET LINIEANTAL FRA EN EXTERN FIL TIL ET TILSVARENDE
*ANTAL FELTER I EEN RECORD TIL EN INTERN FIL.

ERASE
RELEASE ALL
USE
SET TALK OFF
? 'PROGRAM : KONVLIN.CMD              V.0                          JEKK/270784'
? '---------------------------------------------------------------------------'
? 'Konvertering af linier til record.'
? 'Fra en extern tekst-fil (linier) til en intern base/register'
?
? 'Fil-transport forløb :'
? '<din linie-fil>.TXT ---> EXTFIL.DBF ---> HJLPFIL.TXT ---> <din base>.DBF'
?
accept 'Hvilket navn har din linie-fil (xxxxxxxx.yyy) ? ' to extfil
if len(extfil)=0
   ? 'Ok, vi stopper programmet ...'
   return
endif
if .not. file(extfil)
   ? 'Beklager din fil <',extfil,'> eksisterer ikke .. vi stopper her !'
   return
endif
accept 'hvad hedder din base/register-fil for record  ? ' to intfil
if len(intfil)=0 .or. .not. file(intfil)
   ? 'Beklager din fil <',intfil,'> eksisterer ikke .. vi stopper her !'
   return
endif
* EXTFIL.DBF INDEHOLDER LINIER, DER ER KLAR TIL AT BLIVE KONVERTERET
* EXTFIL.TXT INDEHOLDER FILTRANSPORTEREDE LINIER FRA F.EKS. RC8000
if .not. file('extfil.dbf')
   ?'Vi skal lige have dannet filen EXTFIL.DBF, med structuren: '
   ?'name= LINIE, type= C, width= 80 ... tast herefter return 3 (TRE) gange '
   create extfil
else
   ? 'Jeg tømmer lige min fil : EXTFIL.DBF ...'
   USE EXTFIL
   COPY TO EXTFIL.$$$ STRUC
   USE
   DELETE FILE EXTFIL.DBF
   RENAME EXTFIL.$$$ TO EXTFIL.DBF
endif
? 'SÅ BEGYNDER OVERFØRSLEN AF LINIER ...'

USE EXTFIL
APPEND FROM &EXTFIL SDF
? '.Din linie-fil er overført til min linie-fil, hvorfra jeg fortsætter..'
STORE 'N' TO SVAR
DO WHILE !(SVAR)<>'J'
   GOTO TOP
   INPUT 'Hvor mange linier går der pr record ? ' to linprrec
   ? LINPRREC,' LINIER PR RECORD VIL OMFATTE F.EKS. FØLGENDE : '
? '--------------------------------------------------------------------------'
   LIST OFF WHILE #<=LINPRREC FIELD TRIM(LINIE)
? '--------------------------------------------------------------------------'
   ACCEPT 'OK .. (J/N) ? ' TO SVAR
ENDDO
? 'Ok, så konverterer vi ..'
use EXTFIL
COUNT TO LINIETOT
? LINIETOT,' LINIER, DER GIVER ',LINIETOT/LINPRREC,' NYE RECORD ...'
* ÅBEN HJÆLPE FIL HVOR MELLEM RESULTATET GEMMES UNDERVEJS, SOM SDF-RECORD
 SET ALTERNATE TO HJLPFIL.TXT
 SET ALTERNATE ON
SET CONSOLE OFF
GOTO TOP
DO WHILE .NOT. EOF
   STORE 1 TO LINIENR
   STORE ' ' TO POST
   DO WHILE LINIENR<=LINPRREC
      STORE  POST+"'"+TRIM(LINIE)+"'," TO POST
      SKIP +1
      STORE LINIENR+1 TO LINIENR
   ENDDO
   STORE LEN(POST)-2 TO RECLGD
   ? $(POST,2,RECLGD)
ENDDO

* LUK HJÆLPE FIL
 SET ALTERNATE OFF
 SET ALTERNATE TO
SET CONSOLE ON
* INDLÆS HJÆLPE FIL TIL INTERN FIL
USE &INTFIL
? 'Nu er vi klar til at overføre de konverterede linier til din base.'
ACCEPT 'Skal din base være tom før vi overfører de nye record ? (J/N) ' to svar
IF !(svar)='J'
   ACCEPT 'NB!! så tømmer vi basen. OK ? (J/N) ' TO SVAR
   IF !(svar)<>'J'
      ? 'Ja, ja ... så gør vi ikke det .. '
   ELSE
      DELETE ALL
      PACK
      ? 'NU er basen tom ..'
   ENDIF
ENDIF
? 'Din base <&intfil> tilføres de nye record ...'
APPEND FROM HJLPFIL.TXT SDF DELIMITED
? '---------------------------------------------------------------------------'
? 'Så er konverteringen overstået .. Farvel og tak.'
USE
RETURN
*
«eof»