DataMuseum.dk

Presents historical artifacts from the history of:

CR80 Hard and Floppy Disks

This is an automatic "excavation" of a thematic subset of
artifacts from Datamuseum.dk's BitArchive.

See our Wiki for more about CR80 Hard and Floppy Disks

Excavated with: AutoArchaeologist - Free & Open Source Software. 

top - metrics - download

⟦15e65c72a⟧ TextFile

    Length: 2390 (0x956)
    Types: TextFile
    Names: »INMP«

Derivation

└─⟦80dc9b589⟧ Bits:30005096 8" CR80 Floppy CR80FD_0053 ( HMDIR 6 VOL: BACKUP MD: CPM.D From: HMDIR*CPM.D )
    └─⟦08785f861⟧ 
        └─⟦this⟧ »CPM.D!INMP«

TextFile

;-----------------------------------------------------------------------
; PROCEDURE "INBOUND_NARRATIVE_MESSAGE-PROCESSING"(INMP).
;
; NARRATIVE:
; INMP IS INVOKED BY CPMED,WHEN 'INPUT ACTIV' AND AN INBOUND NARRA-
; TIVE MESSAGE HAS BEEN DEQUEUED FROM QUEUE 'MDQ'.
; THE MSGID (CMSGID) IS CONVERTED TO INTERNAL SCC FORMAT,AND LOADED
; TO THE MTCB (CMTCB),WHICH SUBSEQUENTLY IS ENQUEUED IN THE RESPEC-
; TIVELY CONVERSION QUEUE CQ2,CQ3 OR CQ4,AS DESIGNATED BY 'CCHNO'.
; IF IT IS A MESSAGE TO NICS-TARE,IT IS ACCOUNTED FOR BY CALL TO "NMACCNT"
; "NAR.MSG_ACCNT".
;
; CALLS TO:    CASCII
;              NMACCNT
;              MON MIO,MPUTMTCB/MENQQE
;
; REGISTER USE:       ENTRY              EXIT
;                     R5=LINK            R0-R7 DESTROYED
;
; RETURNS:     LINK+0:DONE
;              UREXXX:ERROR
;-----------------------------------------------------------------------
INMP:                                ;BEGIN INMP
         MOV          R5  RLN100     ;   SAVE LINK
         MOVC  CMSGID            R1  ;
         MOVC  MPRWD4+MPMDQ      R7  ;   GET REF.TO MSGID.MPMDQ
         MODC  MSGIDL                ;
         MOVM         X1         X7  ;   COPY CMSGID TO MSGID.MPMDQ
         MOV   CCHNO             R0  ;   (R7 NOW REF.TO MPRWD7)
         IEQ          R0  CH2        ;   IF AN OUTBOUND MSG  THEN
         JMP          S5  ONMACCNT   ;     "OUTB.NAR.MSG_ACCNT"
         SLL          R0  8          ;
         ADDC  CANMIM            R0  ;   R0:=CHNO<8+CAT
         MOV          R0         X7  ;   LOAD CAT+CHNO
         ADDC  -MSGIDL           R7  ;
         JMP          S5  CASCII     ;   "CONVERT ASCII=>BINARY"
         MOV   CMTCBX            R0  ;   RETRIEVE MTCBX
         MOVC  MPMDQ             R4  ;
         MON   MIO,MPUTMTCB          ;   "LOAD MTCB"(R0=MTCBX)
         JMPI  &      S4  URE001     ;E  X0:ERROR,REPORT ERROR
                                     ;   X1:MTCB LOADED WITH MPMDQ
         MOD   CCHNO                 ;
         MOV   XQDCQ             R4  ;   GET QDCB(CCHNO)
         MON   MIO,MENQQE            ;   "ENQUEUE"(R0=MTCBX,R4=QBCB)
         JMPI  &      S4  URE001     ;E  X0:ERROR,REPORT ERROR
                                     ;   X1:MTCB ENQUEUED
         JMPI             RLN100     ;   RETURN LINK+0
                                     ;END INMP
;-----------------------------------------------------------------------