|
DataMuseum.dkPresents historical artifacts from the history of: CR80 Hard and Floppy Disks |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about CR80 Hard and Floppy Disks Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 2740 (0xab4)
Types: TextFile
Names: »MS6010.S«, »~ORPHAN_0x0043«
└─⟦93791531c⟧ Bits:30005105 8" CR80 Floppy CR80FD_0064 ( VOL:SCC.V MSS Directory: MS1.D )
└─⟦185cc4db7⟧
└─⟦this⟧ »~ORPHAN_0x0043«
└─⟦b5acf5c79⟧ Bits:30005104 8" CR80 Floppy CR80FD_0063 ( VOL: SCC.V MSS Directory: MS2.D )
└─⟦f918199fd⟧
└─⟦this⟧ »MS2.D!MS6010.S«
MESSAGE <:MS6010.S V810325:>
;-----------------------------------------------------------------------
; SUBROUTINE MS6010
; WRITE SMF LINE 1
;
; REGISTERS CALL EXIT
; R4 LINK DEST
; R0-R7 - DEST
;
; INPUT: APRECE
; OUTPUT: OBJECT FILE 1ST RECORD, AIDREF
; EXIT TO: LINK+0 (OK)
;-----------------------------------------------------------------------
MS6010: ; WRITE SMF LINE 1:
MOV R4 RL6000 ; SAVE RETURN LINK
MOVC OBJIO R6 ; GET OUTPUT FILE
JMP S5 MS6012 ; ACCESS PRECEDENCE LETTER TABLE
0 ; ILLEGAL
<:Z:> ; FLASH
0 ; ILLEGAL
<:O:> ; ORDINARY
<:P:> ; PRIORITY
0 ; ILLEGAL
<:R:> ; ROUTINE
0 ; ILLEGAL
MS6012: ;
MOV APRECE R0 ; GET ACTION PRECEDENCE
MOVC ERCPRC R2 ; GET ERROR CODE JUST IN CASE
IHS R0 8 ; IF ILLEGAL
JMPI S4 MI8000 ; THEN CALL INTERCEPT
ADD R0 R5 ; GET PROGREL ADDR OF LETTER
MVP X5 R0 ; GET VALUE OF PREC LETTER
IEQ R0 0 ; IF ILLEGAL
JMPI S4 MI8000 ; THEN CALL INTERCEPT
JMPI S4 MI2010 ; WRITE CHARACTER
MOVC <: :> R0 ; GET SPACE
JMPI S4 MI2010 ; WRITE CHARACTER
JMPI S4 MI5100 ; WRITE DAYTIME GROUP TO TABBUF
MOVC TABBUF R5 ;
MOVC OBJIO R6 ; GET OUTPUT FILE
JMPI S4 MI300B ; WRITE DTG TO OBJECT FILE
JMP S5 MS6014 ; ACCESS SMF 'C' CONST
<: MSG ID :> ; SMF 'C'
0 ; STRING TERMINATOR
MS6014: ;
JMPI S4 MI300P ; WRITE PGREL DATA STRING
JMPI S4 MI3700 ; PROVIDE FILE INDEX
MOV R0 AIDREF ; SAVE AS MSG_ID REF
JMPI S4 MI5110 ; WRITE MSG ID TO TABBUF
MOVC TABBUF R5 ;
MOVC OBJIO R6 ; GET OUTPUT FILE
JMPI S4 MI300B ; WRITE MSG ID TO OBJECT FILE
MOVC LFCHAR R0 ; GET 'LF'
JMPI S4 MI2010 ; TERMINATE LINE
JMPI RL6000 ; RETURN G