|
DataMuseum.dkPresents historical artifacts from the history of: CR80 Hard and Floppy Disks |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about CR80 Hard and Floppy Disks Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 1966 (0x7ae)
Types: TextFile
Names: »MS5110.S«, »~ORPHAN_0x0041«
└─⟦93791531c⟧ Bits:30005105 8" CR80 Floppy CR80FD_0064 ( VOL:SCC.V MSS Directory: MS1.D )
└─⟦185cc4db7⟧
└─⟦this⟧ »~ORPHAN_0x0041«
└─⟦b5acf5c79⟧ Bits:30005104 8" CR80 Floppy CR80FD_0063 ( VOL: SCC.V MSS Directory: MS2.D )
└─⟦f918199fd⟧
└─⟦this⟧ »MS2.D!MS5110.S«
MESSAGE <:MS5110.S V810326:>
;-----------------------------------------------------------------------
; SUBROUTINE MS5110
; WRITE MSG_ID TO TABBUF.
;
; REGISTERS CALL EXIT
; R4 LINK DEST
; R0,R1,R2,R3,R5 - DEST
; R6,R7 NOT USED
;
; INPUT: IOTYP.SRCIO,SCCID,SERNO
; OUTPUT: BYTES TO TABBUF
; EXIT TO: LINK+0 (OK)
;-----------------------------------------------------------------------
MS5110: ; WRITE MSG_ID TO TABBUF:
MOV R4 RL5000 ; SAVE RETURN LINK
MODC SRCIO ; PROVIDE SOURCE
MOV IOTYP R0 ; GET TYPE.SOURCE
IBN R0 IOBFIX ; IF FIKS RECORDS
; I.E. INTERNAL CONVERSION
MODC <:AS:>-<:NF:> ; THEN USE 'AS'
MOVC <:NF:> R1 ; ELSE USE 'NF'
MOV SCCID R0 ; GET SCCID ('P' OR 'Q')
SWP R0 ; POSITION INTERMEDIATE
SRLL R01 8 ; POSITION BYTES
; 0=P OR Q
; 1,2= AS OR NF
; 3=ZERO
MOVC TABBUF R4 ; GET DESTINATION ADDR
MOVL R01 X4 ; STORE IN TABBUF
CLR 3. X4 ; INSERT ZEROES AFTER DIGITS
MOV SERNO R0 ; GET SERIAL NUMBER
SHS R0 10000 ; IF OUTSIDE RANGE
IEQ R0 0 ;
JMPI S4 MIE200 ; THEN MSC ERROR
MOVC 0 R1 ; CLEAR 16 MOST SIGN BITS
MOVC 3 R2 ; SETUP TO WRITE 3 DIGITS
MOVC 3 R5 ; SET BUF INDEX TO 3
JMPI S4 MI4100 ; WRITE INTEGER
JMPI RL5000 ;R RETURN