|
DataMuseum.dkPresents historical artifacts from the history of: CR80 Hard and Floppy Disks |
This is an automatic "excavation" of a thematic subset of
See our Wiki for more about CR80 Hard and Floppy Disks Excavated with: AutoArchaeologist - Free & Open Source Software. |
top - metrics - download
Length: 2658 (0xa62)
Types: TextFile
Names: »MSD300.S«
└─⟦b5acf5c79⟧ Bits:30005104 8" CR80 Floppy CR80FD_0063 ( VOL: SCC.V MSS Directory: MS2.D )
└─⟦f918199fd⟧
└─⟦this⟧ »MS2.D!MSD300.S«
MESSAGE <:MSD300.S V810325:>
;-----------------------------------------------------------------------
; SUBROUTINE MSD300
; START CONVERSION.
;
; REGISTERS CALL EXIT
; R0,R1,R2,R6 - DEST
; R4 LINK DEST
; R3,R5,R7 NOT USED
;
; INPUT: SRCFD,OBJFD,TMPFD,CONVTP
; OUTPUT: SRCIO,OBJIO,TEMPIO
; REMAINING BASE LESS PROCEDURE PARAMETERS (CLEARED)
; EXIT TO: LINK+0 (OK)
;-----------------------------------------------------------------------
MSD300: ; START CONVERSION:
MOVC MS1STZ R1 ; GET START ADDR
MOVC MSCNTZ R2 ; GET COUNT
MSD302: ; CLEAR BASE FROM START AND OUT
MOVC 0 X1 ; CLEAR BASE ELEMENT
ADDC 1 R1 ; STEP INDEX
SOB R2 MSD302 ; LOOPBACK TILL DONE
MOV R2 ERCODE ; CLEAR ERROR RETURN CODES
MOV R2 ERLINE ;
MOV R4 RLD000 ; SAVE RETURN LINK
JMPI S4 MI1200 ; GET ACCEPTANCE TIME
MSD308: ;SETUP 3 IOCB'S:
; SRCIO:
MOVC SRCIO R6 ; GET IOCB ADDR
MOV SRCFD R0 ; GET FILE DESCRIPTOR
MOVC SRCBUF R1 ; GET BUFFER ADDR
MOV CONVTP R2 ; GET CONVERSION TYPE
IGE R2 2 ; IF TYPES 2,3, OR 4
MODC 1<IOBFIX ; THEN USE FIKS RECORDS
MOVC 0 R2 ; ELSE NICS RECORDS
JMP S4 MSD130 ; SETUP IOCB
; OBJIO:
MOVC OBJIO R6 ; GET IOCB ADDR
MOV OBJFD R0 ; GET FILE DESCRIPTOR
MOVC OBJBUF R1 ; GET BUFFER ADDR
MOV CONVTP R2 ; GET CONVERSION TYPE
INE R2 2 ; IF TYPES 0,1,3, OR 4
MODC 1<IOBFIX ; THEN USE FIKS RECORDS
MOVC 0 R2 ; ELSE NICS RECORDS
JMP S4 MSD130 ; SETUP IOCB
; TEMPIO:
MOVC TEMPIO R6 ; GET IOCB ADDR
MOV TMPFD R0 ; GET FILE DESCRIPTOR
MOVC TMPBUF R1 ; GET BUFFER ADDR
MOVC 0 R2 ; NO RECORD FORMAT
JMP S4 MSD130 ; SETUP IOCB
;END IOCB'S
JMPI RLD000 ;R RETURN