⟦2b1494b5a⟧

TextFile

@setfilename ../info/functions
@node Functions, Macros, Variables, Top
@chapter Functions

  A Lisp program is composed mainly of Lisp functions.  This chapter
explains what functions are, how they accept arguments, and how to
define them.

@menu
* What Is a Function::  
* Lambda Expressions::  
* Function Names::
* Defining Functions::       
* Calling Functions::
* Mapping Functions::
* Anonymous Functions::       
* Function Cells::
* Related Topics::    
@end menu

@node What Is a Function, Lambda Expressions, Functions, Functions
@section What Is a Function

  There are two kinds of functions in GNU Emacs Lisp: they may be
primitives written in C, or they may be defined in Lisp.  In Emacs version
18.52, there are approximately 580 functions in 64 C source files, and over
2600 functions in about 145 Lisp files.

  The C-coded functions are the built-in functions of Lisp; they appear
in Lisp as primitive subr-objects.  These primitives provide the
lowest-level interfaces to editing functions or operating system
services, or in a very few cases, they exist to perform certain
important operations more quickly than a Lisp program could do them.
Primitives can be modified or added only by changing the C sources and
recompiling the editor.  This is harder than writing Lisp code, but not
impossibly hard; see @ref{Writing Emacs Primitives}.

  Most extensions to the Emacs editor are written in Lisp.  If you have
ever programmed other versions of Emacs you will find writing code for GNU
Emacs very pleasant; the Lisp provided is a true version of Lisp, and
functions that are used as editing commands do not require any special
calling sequence.

  Macros are an alternative to functions.  Macros differ from functions
in that they define new forms of Lisp syntax; they translate a Lisp
expression that you write it into an equivalent form to be evaluated
instead.  @xref{Macros}, for how to define and use macros.

  We start by defining some terminology:

@table @dfn
@item function
A @dfn{function} in general is anything that can be applied to arguments in
a Lisp program.  In some cases, we will uses it more specifically to mean
a function written in Lisp.  Special forms and macros are not functions.

@item primitive
@cindex primitive
@cindex subr
@cindex built-in function
A @dfn{primitive} is a function callable from Lisp that is written in
C, such as @code{car} and @code{cdr}.  These are sometimes called
@dfn{built-in} functions or @dfn{subrs}.

@item lambda expression
A @dfn{lambda expression} is a function written in Lisp.
These are described in the following section.
@ifinfo
@xref{Lambda Expressions}.
@end ifinfo

@item command
A @dfn{command} is advertised to the user and can be invoked by the user
with @kbd{M-x}, or bound to a key in some keymap.  Commands written in
Lisp are functions with interactive specifications (@pxref{Defining
Commands}).

@item keystroke command
A @dfn{keystroke command} is a command that is bound to a key sequence
(typically one to three keystrokes).  The distinction is made here
merely to avoid confusion with the meaning of ``command'' in non-Emacs
editors; for programmers, the distinction is normally unimportant.
@end table

@node Lambda Expressions, Function Names, What Is a Function, Functions
@section Lambda Expressions
@cindex lambda expression

  A function written in Lisp is a list that looks like this:

@example
(lambda (@var{arg-variables}@dots{})
  [@var{documentation-string}]
  [@var{interactive-declaration}]
  @var{body-forms}@dots{})
@end example

@noindent
(Such a list is called a @dfn{lambda expression} for historical reasons.)

@menu
* Lambda Components::	
* Simple Lambda::	
* Argument List::	
* Function Documentation::	
@end menu

@node Lambda Components, Simple Lambda, Lambda Expressions, Lambda Expressions
@subsection Components of a Lambda Expression

@cindex lambda list
  The first element of this list is always the symbol @code{lambda}.  This
indicates that the list is supposed to be a function.

  The second element is a list of argument variable names (symbols).  This
is called the @dfn{lambda list}.  When a Lisp function is called, the
argument values are matched up against the names in the lambda list, which
are given local bindings with the values provided.  @xref{Local Variables}.

  The documentation string is an actual string, which serves to describe
the function for the Emacs help system.  @xref{Function Documentation}.

  The interactive declaration is a list of the form @code{(interactive
@var{code-string})}.  This declares how to provide arguments if the
function is used interactively.  Functions with this declaration are called
@dfn{commands}; they can be called using @kbd{M-x} or bound to a key.
Functions not intended to be called in this way should not have interactive
declarations, so as to keep them from interfering with command completion
in @kbd{M-x}.  @xref{Defining Commands}, for how to write an interactive
declaration.

@cindex body of function
  The rest of the elements are the @dfn{body} of the function: Lisp code to
execute, or, as a Lisp programmer would say, ``a list of Lisp forms to
evaluate''.  The value returned by the function is the value returned by
the last element of the body.

@node Simple Lambda, Argument List, Lambda Components, Lambda Expressions
@subsection A Simple Lambda-Expression Example

  Consider for example the following function:

@example
(lambda (a b c) (+ a b c))
@end example

@noindent
We can call it as follows:

@example
((lambda (a b c) (+ a b c))
 1 2 3)
@end example

@noindent
The body of this lambda expression is evaluated with the variable
@code{a} bound to 1, @code{b} bound to 2, and @code{c} bound to 3.
Evaluation of the body adds these three numbers, producing the result 6;
therefore, this call to the function returns the value 6.

  Note that the arguments can be the results of other function calls, as in
this example:

@example
((lambda (a b c) (+ a b c))
 1 (* 2 3) (- 5 4))
@end example

@noindent
Here all the arguments @code{1}, @code{(* 2 3)}, and @code{(- 5 4)} are
evaluated, left to right.  Then the function shown is applied to the
argument values 1, 6 and 1 to produce the value 8.

@node Argument List, Function Documentation, Simple Lambda, Lambda Expressions
@subsection Advanced Features of Argument Lists
@kindex wrong-number-of-arguments
@cindex function evaluation
@cindex binding arguments

Our simple sample function

@example
(lambda (a b c) (+ a b c))
@end example

@noindent
specifies three arguments, so it must be called with three arguments: if
you try to call it with only two arguments or four arguments, you will get
a @code{wrong-number-of-arguments} error.

  It is often convenient to write a function that allows certain arguments
to be omitted.  For example, the function @code{substring} accepts three
arguments---a string, the start index and the end index---but the third
argument defaults to the end of the string if you omit it.  It is also
convenient for certain functions to accept an indefinite number of
arguments, as the functions @code{and} and @code{+} do.

@cindex optional arguments
@cindex rest arguments
@kindex &optional
@kindex &rest
  To specify optional arguments that may be omitted when a function
is called, simply include the keyword @code{&optional} before the optional
arguments.  To specify a list of zero or more extra arguments, include the
keyword @code{&rest} before one final argument.

  The complete syntax for an argument list is as follows:

@example
(@var{required-vars}@dots{}
 [&optional @var{optional-vars}@dots{}]
 [&rest @var{rest-var}])
@end example

@noindent
The square brackets indicate that the @code{&optional} and @code{&rest}
clauses, and the variables that follow them, are optional.  The
@var{documentation-string} and @var{interactive-declaration} are described
later.

  A call to the function requires one actual argument for each of the
@var{required-vars}.  There may be actual arguments for zero or more of the
@var{optional-vars}, and there cannot be any more actual arguments than
these unless @code{&rest} exists.  In that case, there may be any number of
extra actual arguments.

  If actual arguments for the optional and rest variables are omitted,
then they always default to @code{nil}.  However, the body of the function
is free to consider @code{nil} an abbreviation for some other meaningful
value.  This is what @code{substring} does; @code{nil} as the third argument
means to use the length of the string supplied.  There is no way for the
function to distinguish between an explicit argument of @code{nil} and
an omitted argument.

@quotation
@cindex Common Lisp optional arguments
@b{Common Lisp Note:} Common Lisp allows the function to specify what
default values will be used when an optional argument is omitted; GNU Emacs
Lisp always uses @code{nil}.
@end quotation

  For example, an argument list that looks like this:

@example
(a b &optional c d &rest e)
@end example

@noindent
binds @var{a} and @var{b} to the first two actual arguments, which are
required.  If one or two more arguments are included, @var{c} and @var{d}
are bound to them respectively; any arguments after the first four are
collected into a list and @var{e} is bound to that list.  If there are only
two arguments, @var{c} is @code{nil}; if two or three arguments, @var{d} is
@code{nil}; if less than four arguments, @var{e} is @code{nil}.

  There is no way to have required arguments following optional ones---it
would not make sense.  To see why this must be so, suppose that @var{c} in
the example were optional and @var{d} were required.  If three actual
arguments are given; then what should be bound to the third argument?
Similarly, it makes no sense to have any arguments after a @code{&rest}
argument.

  Here are some examples of argument lists:

@example
((lambda (n) (1+ n))                ;One parameter:
 1)                                 ;requires exactly one argument
     @result{} 2
((lambda (n &optional n1)           ;One parameter and one optional:
         (if n1 (+ n n1) (1+ n)))   ;1 or 2 arguments.
 1 2)
     @result{} 3
((lambda (n &rest ns)                ;One parameter and &rest:
         (+ n (apply '+ ns)))        ;1 or more arguments.
 1 2 3 4 5)
     @result{} 15
@end example

@node Function Documentation,  , Argument List, Lambda Expressions
@subsection Documentation Strings of Functions
@cindex documentation of function

  A lambda expression may optionally have a @dfn{documentation string} just
after the lambda list.  This string does not affect execution of the
function; it is a kind of comment, but a systematized comment which
actually appears inside the Lisp world and can be used by the Emacs help
system.  @xref{Documentation}, for how the @var{documentation-string} is
displayed for the user.

  It is a good idea to provide documentation strings for all commands, and
for all other functions in your program that users of your program should
know about; internal functions might as well have only comments, since they
don't take up any room when your program is loaded.

  The first line of the documentation string should be complete in itself,
because @code{apropos} displays just this first line.  It should consist
of one or two complete sentences that summarize the function's purpose.

  The start of the documentation string is usually indented; since these
spaces come before the starting double-quote, they are not part of the
string.  Some people make a practice of indenting any additional lines of
the string so that the text lines up.  @emph{This is a mistake.} The
indentation of the following lines is inside the string; what looks nice in
the source code will look ugly in the help system.

  You may wonder how the documentation string could be optional, since
there are required components of the function that follow it (the body).
Since evaluation of a string returns that string, without any side effects,
it has no effect if it is not the last form in the body.  Thus, in
practice, there is no confusion between the first form of the body and the
documentation string; if the only body form is a string then it serves both
as the return value and as the documentation.

@node Function Names, Defining Functions, Lambda Expressions, Functions
@section How a Function Can Have a Name

  In most computer languages, every function has a name; the idea of a
function without a name is nonsensical.  In Lisp, a function in the
strictest sense has no name.  It is simply a list whose first element is
@code{lambda}, or a primitive subr-object.

  However, a symbol can serve as the name of a function.  This happens when
you put the function in the symbol's @dfn{function cell}.  Then the symbol
itself becomes a valid, callable function, equivalent to the list or
subr-object that its function cell refers to.  The contents of the function
cell is also spoken of as the symbol's @dfn{function definition}.

  In practice, nearly all functions are given names in this way and
referred to through their names.  For example, the symbol @code{car} works
as a function and does what it does because the primitive subr-object
@code{#<subr car>} is stored in its function cell.

  We give functions names because it is more convenient to refer to them by
their names in other functions.  For a primitive subr-object such as
@code{#<subr car>}, that is the only way you can refer to them: there is no
read syntax for such objects.  For functions written in Lisp, the name
makes it possible to refer to the function without including a copy of it.
Also, a function with a name can refer to itself---it can be recursive.
Writing the function's own name is much more convenient than making the
function point to itself (something which is not impossible but which has
various disadvantages in practice).

  Functions are often identified with the symbols used to name them.  For
example, we often speak of ``the function @code{car}'', not distinguishing
between the symbol @code{car} and the primitive subr-object that is its
function definition.  For most purposes, there is no need to distinguish.

  Even so, keep in mind that a function need not have a unique name.  While
a given function object @emph{usually} appears in the function cell of only
one symbol, this is just a matter of convenience.  It is very easy to store
it in several symbols using @code{fset}; then each of the symbols is
equally well a name for the same function.

@node Defining Functions, Calling Functions, Function Names, Functions
@section Defining Named Functions
@cindex function definition

  The usual way to create a function written in Lisp is to give it a name
at the same time.  This is called @dfn{defining a function}, and it is done
with the @code{defun} special form.

@defspec defun name parameter-list body-forms
@code{defun} is the usual way to define new Lisp functions.  It
defines the symbol @var{name} as a function which looks like this:

@example
(lambda @var{parameter-list} . @var{body-forms})
@end example

This lambda expression is stored in the function cell of @var{name}.
The value returned by evaluating the @code{defun} form is @var{name},
but usually we ignore this value.

As described previously (@pxref{Lambda Expressions}),
@var{parameter-list} is a list of parameter names and may include the
keywords @code{&optional} and @code{&rest}.  Also, the first two forms
in @var{body-forms} may be a documentation string and an interactive
declaration.

Note that the same @var{name} may also be used as a global variable
since the value cell is independent of the function cell.  But take
precautions against unintentionally redefining functions since
@code{defun} will even redefine primitive functions such as @code{car}
without any hesitation or notification.

@example
(defun foo () 5)
     @result{} foo
(foo)
     @result{} 5

(defun bar (a &optional b &rest c)
    (list a b c))
     @result{} bar
(bar 1 2 3 4 5)
     @result{} (1 2 (3 4 5))
(bar 1)
     @result{} (1 nil nil)
(bar)
@error{} Wrong number of arguments.

(defun capitalize-backwards ()
  "This function makes the last letter of a word upper-case."
  (interactive)
  (backward-word 1)
  (forward-word 1)
  (backward-char 1)
  (capitalize-word 1))
     @result{} capitalize-backwards
@end example
@end defspec

@node Calling Functions, Mapping Functions, Defining Functions, Control Structures
@section Function Invocation

@cindex function invocation
  Defining functions is only half the battle.  Functions don't do
anything until you @dfn{call} them, which means, tell them to run.  This
process is also known as @dfn{invocation}.

  The most common way of invoking a function is simply to evaluate a
list.  For example, evaluating the list @code{(concat "a" "b")} calls
the function @code{concat}.  @xref{Evaluation}, for a description of
evaluation in general.

  When you evaluate a list, you have to specify the function name in
your program.  This means that the choice of which function to call is
made when you write the program.  Usually that's just what you want.
Occasionally you need to decide at run time which function to call.
Then you can use the functions @code{apply} and @code{funcall}.

@defun funcall function &rest arguments
@code{funcall} calls @var{function} with @var{arguments}, and returns
whatever @var{function} returns.

Since @code{funcall} is a function, all of its arguments, including
@var{function}, are evaluated before @code{funcall} is called.  This
means that you can use any expression to come up with the function to be
called.  It also means that @code{funcall} does not see the expressions
you write for the @var{arguments}, only their values.

The @var{arguments} are @emph{not} evaluated a second time in the act of
calling @var{function}.  @code{funcall} enters the normal procedure for
calling a function at the place where the arguments have already been
evaluated.
  
@var{function} must be either a Lisp function or a primitive function.
Special forms and macros are not allowed, because they make sense only
when given the ``unevaluated'' argument expressions.  @code{funcall}
cannot give these because, as we saw above, it never sees them in the
first place.

@example
(setq f 'list)
     @result{} list
(funcall f 'x 'y 'z)
     @result{} (x y z)
(funcall f 'x 'y '(z))
     @result{} (x y (z))
(funcall 'and t nil)
@error{} Invalid function: #<subr and>
@end example

Compare this example with that of @code{apply}.
@end defun

@defun apply function &rest arguments
@code{apply} calls @var{function} with @var{arguments}, just like
@code{funcall} but with one difference: the last of @var{arguments} is a
list of arguments to give to @var{function}, rather than a single
argument.  We also say that this list is @dfn{appended} to the other
arguments.

@code{apply} returns the result of that call to @var{function}.  As with
@code{funcall}, @var{function} must either be a Lisp function or a
primitive function; special forms and macros do not make sense to apply.

@example
(setq f 'list)
     @result{} list
(apply f 'x 'y 'z)
@error{} Wrong type argument: listp, z
(apply f 'x 'y '(z))
     @result{} (x y z)
(apply f '(x y z))
     @result{} (x y z)

;; @r{Remove empty lists from a list of possibly empty lists.}
@findex append @r{example}
(apply 'append '((a b c) nil (x y z) nil))
     @result{} (a b c x y z)
@end example
@end defun

@node Mapping Functions, Anonymous Functions, Calling Functions, Control Structures
@section Mapping Functions

  A @dfn{mapping function} applies a given function to each element of a
list or other collection.  Emacs Lisp has three such functions: two,
@code{mapcar} and @code{mapconcat}, which scan a list, are described
here.  (The third function is @code{mapatoms}; @pxref{Creating and
Interning Symbols}.)

@defun mapcar function sequence
@code{mapcar} applies @var{function} to each element of @var{sequence} in
turn.  The results are made into a @code{nil}-terminated list.

The argument @var{sequence} may be a list, a vector or a string.  The
result is always a list.  The length of the result is the same as the
length of @var{sequence}.

For example: 

@example
(mapcar 'car '((a b) (c d) (e f)))
     @result{} (a c e)
(mapcar '1+ [1 2 3])
     @result{} (2 3 4)
(mapcar char-to-string "abc")
     @result{} ("a" "b" "c")

;; @r{Call each function in @code{my-hooks}.}
(mapcar 'funcall my-hooks)

@findex apply @r{example}
(defun mapcar* (f &rest args)
  "Apply FUNCTION to successive cars of all ARGS, until one ends.
Return the list of results."
  (cons (apply f (mapcar 'car args))       ; @r{Apply function to @sc{car}s.}
        (let ((rest (mapcar 'cdr args)))
          (if (not (memq 'nil rest))
              (apply 'mapcar* f rest)))))  ; @r{Do the same for @sc{cdr}s.}

(mapcar* 'cons '(a b c) '(1 2 3 4))
     @result{} ((a . 1) (b . 2) (c . 3))
@end example
@end defun

@defun mapconcat function sequence separator
@code{mapconcat} applies @var{function} to each element of
@var{sequence}: the results, which must be strings, are concatenated.
Between each pair of result strings, @code{mapconcat} inserts the string
@var{separator}.  Usually @var{separator} contains a space or comma or
other suitable punctuation.

@var{function} must be a function that can take one argument and
returns a string.
  
@example
(mapconcat 'symbol-name
           '(The cat in the hat)
           " ")
     @result{} "The cat in the hat"

(mapconcat (function (lambda (x) (format "%c" (1+ x))))
           "HAL-8000"
           "")
     @result{} "IBM.9111"
@end example
@end defun

@node Anonymous Functions, Function Cells, Mapping Functions, Functions
@section Some Functions Don't Have Names

  In Lisp, a function is a list with a certain format (or a subroutine);
names are ``extra''.  Although usually functions are defined with
@code{defun} and given names at the same time, it is occasionally more
concise to use an anonymous function---a list that starts with
@code{lambda}.

  Any method of creating such a list makes a valid function.  Even this:

@example
(setq silly (append '(lambda (x)) (list (list '+ (* 3 4) 'x))))
     @result{} (lambda (x) (+ 12 x))
@end example

@noindent
Now the value of the variable @code{silly} is an anonymous function which
adds 12 to its argument.  Here is how we might call this function:

@example
(funcall silly 1)
     @result{} 13
@end example

@noindent
(It does @emph{not} work to write @code{(silly 1)}, because this function
is not the @emph{function definition} of @code{silly}.  We have not given
@code{silly} any function definition, just a value as a variable.)

But most of the time, anonymous functions are constants which appear in
your program.  For example, you might want to pass one as an argument
to the function @code{mapcar}, which applies any given function to each
element of a list.  Here we pass an anonymous function that multiplies
a number by two:

@example
(defun double-each (list)
  (mapcar '(lambda (x) (* 2 x)) list))
     @result{} double-each
(double-each '(2 11))
     @result{} (4 22)
@end example

In such cases, we usually use @code{function} instead of simple quotation.

@defspec function function-object
@cindex anonymous functions
@cindex function quoting
This special form returns @var{function-object} without evaluating it.
In this, it is equivalent to @code{quote}.  However, it serves as a
note to the Emacs Lisp compiler that @var{function-object} is intended
to be used only as a function, and therefore can safely be compiled.
@xref{Quoting}, for comparison.
@end defspec

Using @code{function} instead of @code{quote} makes a difference inside a
function or macro that you are going to compile.  For example:

@example
(defun double-each (list)
  (mapcar (function (lambda (x) (* 2 x))) list))
     @result{} double-each
(double-each '(2 11))
     @result{} (4 22)
@end example

@noindent
If this definition of @code{double-each} is compiled, the anonymous
function is compiled as well.  In the previous definition, above, the
argument passed to @code{mapcar} is the precise list shown:

@example
(lambda (arg) (+ arg 5))
@end example

@noindent
This is because the Lisp compiler cannot assume this list is a function,
even though it looks like one, and it does not know what @code{mapcar}
does with the list.  Perhaps @code{mapcar} will check that the @sc{car}
of the third element is the symbol @code{+}!  We use @code{function} to
tell the compiler to go ahead and compile.

We also often write @code{function} instead of @code{quote} when quoting
the name of a function, but then it is just a sort of comment.

@example
(function car) @equiv{} (quote car) @equiv{} 'car
@end example

@node Function Cells, Related Topics, Anonymous Functions, Functions
@section Accessing Function Cell Contents

  The @dfn{function definition} of a symbol is the object stored in the
function cell of the symbol.  The functions described here access, test,
and set the function cell of symbols.

@defun symbol-function symbol
@cindex void-function error
Returns the object in the function cell of @var{symbol}.  If the
symbol's function cell is void, a @code{void-function} error is
signaled.

This function does not check that the object is a legitimate function.

@example
(defun bar (n) (+ n 2))
     @result{} bar
(symbol-function 'bar)
     @result{} (lambda (n) (+ n 2))
(fset 'baz 'bar)
     @result{} bar
(symbol-function 'baz)
     @result{} bar
@end example
@end defun

@defun subrp object
@cindex subroutine
@cindex primitive
@cindex built-in
This function returns @code{t} if @var{object} is a built-in function
(i.e. a Lisp primitive).

@example
(subrp 'message)                ; @r{@code{message} is a symbol,}
     @result{} nil                   ; @r{not a subr object.}
(subrp (symbol-function 'message))
     @result{} t
@end example
@end defun

  If you have never given a symbol any function definition, we say that
that symbol's function cell is @dfn{void}.  In other words, the function
cell does not have any Lisp object in it.  If you try to call this symbol
as a function, the result is a @code{void-function} error.

  Note that void is not the same as @code{nil} or the symbol @code{void}.
The symbols @code{nil} and @code{void} are Lisp objects, and can be stored
into a function cell just as any other object can be (and they can be valid
functions if you define them in turn with @code{defun}); but they are
@emph{something}.  A void function cell contains no object whatever.

  You can test the voidness of a symbol's function definition with
@code{fboundp}.  After you have given a symbol a function definition, you
can make it void once more using @code{fmakunbound}.

@defun fboundp symbol
Returns @code{t} if the symbol has some value (any non-void object) in
its function cell, @code{nil} otherwise.  It does not check that the
value is a legitimate function.
@end defun

@defun fmakunbound symbol
This function sets the symbol's function pointer to be ``void'' (not
the @emph{symbol} @code{void}), so that any attempt to access this
cell will cause a @code{void-function} error.  (See also
@code{makunbound}, in @ref{Local Variables}.)

@example
(defun foo (x) x)
     @result{} x
(fmakunbound 'foo)
     @result{} x
(foo 1)
@error{} Symbol's function definition is void: foo
@end example
@end defun

@defun fset symbol object
This function sets the function cell of @var{symbol} to be
@var{object}.  The result is @var{object}.  Normally @var{object}
should be a function or the name of one, but this is not checked.

There are three normal uses of this function:

@itemize @bullet
@item
Copying one symbol's function definition to another.  (In other words,
making an alias.)

@item
Giving a symbol a function definition that is not a list and
therefore cannot be made with @code{defun}.

@item
In constructs for defining or altering functions.  If @code{defun}
were not a primitive, it could be written in Lisp (as a macro) using
@code{fset}.
@end itemize

Here are examples of the first two uses:

@example
;; @r{Give @code{first} the same definition @code{car} has.}
(fset 'first (symbol-function 'car))
     @result{} #<subr car>
(first '(1 2 3))
     @result{} 1

;; @r{Make the symbol @code{car} the function definition of @code{xfirst}.}
(fset 'xfirst 'car)
     @result{} car
(xfirst '(1 2 3))
     @result{} 1
(symbol-function 'xfirst)
     @result{} car
(symbol-function (symbol-function 'xfirst))
     @result{} #<subr car>
@end example
@end defun

@node Related Topics,, Function Cells, Functions
@section Other Topics Related to Functions

  Here is a table of several functions that do things related to
function calling and function definitions.

@table @code
@item apply
@xref{Calling Functions}.

@item funcall
@xref{Calling Functions}.

@item eval
@xref{Eval}.

@item mapatoms
@xref{Creating and Interning Symbols}.

@item mapcar
@xref{Mapping Functions}.

@item mapconcat
@xref{Mapping Functions}.

@item documentation
@xref{Documentation}.

@item interactive
@xref{Interactive Call}.

@item call-interactively
@xref{Interactive Call}.

@item interactive-p
@xref{Interactive Call}.

@item commandp
@xref{Command Overview}.

@item autoload
@xref{Autoload}.

@item ignore
@xref{Key Lookup}.

@item undefined
@xref{Key Lookup}.
@end table
DataMuseum.dk

DKUUG/EUUG Conference tapes

⟦2b1494b5a⟧ TextFile

Derivation

TextFile
