DataMuseum.dk

top - metrics - download

    Length: 3641 (0xe39)
    Types: TextFile
    Names: »lasergnu«

└─⟦52210d11f⟧ Bits:30007239 EUUGD2: TeX 3 1992-12
    └─⟦c319c2751⟧ »unix3.0/TeX3.0.tar.Z« 
        └─⟦036c765ac⟧ 
            └─⟦this⟧ »TeX3.0/TeXcontrib/gnutex/lasergnu« 

TextFile

#! /bin/csh -f
#
# Print gnutex output on an Imagen laser printer.

# Plot-program-independent stuff
set iflags = ()		# arguments given to ipr
set hold = "inputbin 1"	# hold == manual => Hold output; feed paper manually.
			# Default is to feed paper automatically.
set print_banner = on	# Print a banner page unless told otherwise.
unset input_file	# the plot input command file
set output_file = ()	# the output file (used only by the old laserism)
set plot_args = ()	# arguments to the plotting program (if any)
unset plot_command	# command line arguments may be plot commands
if !($?LASER) then
	set LASER = "imagen018"
endif
set printer = (-P$LASER)	# Default printer set by shell variable LASER.

# File for plot commands
set TMP=/tmp/gnu$$
onintr cleanup

# default is tektronix mode for printer
set setterm="set terminal tek40xx"
set setsize=""
set LANG="-Ltektronix"

# Loop through the command-line arguments.

top:
	if ($#argv > 0) then

		switch ("$argv[1]")

		case -b*:	# Do not print a banner page.
		case -J*:	# Compatible with imprint.
			set print_banner = off
			shift argv
			goto top

		case -f?*:	# Specify file containing plot commands
			set input_file = `echo $argv[1] | sed 's/^-f//'`
			shift argv
			goto top

		case -f:	# Specify file containing plot commands
			shift argv
			if ($#argv > 0) then
				set input_file = ($argv[1])
				shift argv
			else
				echo "Usage: -f file ..."
				echo "Type    lasergnu -help    for help."
				exit (1)
			endif
			goto top

		case -t?*:	# Specify title of plot
			echo set title \""`echo $argv[1] | sed 's/^-t//'`"\" >> $TMP
			shift argv
			goto top

		case -t:	# Specify title of plot
			shift argv
			if ($#argv > 0) then
				echo set title \""$1"\" >> $TMP
				shift argv
			else
				echo "Usage: -t title ..."
				echo "Type    lasergnu -help    for help."
				exit (1)
			endif
			goto top
		case -hold:	# Hold output; feed the paper manually.
			set hold = "inputbin manual"
			shift argv
			goto top

          case -help:
			echo "usage: lasergnu [-Pprinter] [-b] [-l] [-t title] [-f file] ['plot command']...."
			exit(1)

		case -l:
			set plot_args = ($plot_args -l)
			shift argv
			goto top

		case -P?*:	# Set the printer, exactly as by itroff.
			set printer = $argv[1]
			shift argv
			goto top

		case -P:	# Set the printer, exactly as by itroff.
			shift argv
			if ($#argv > 0) then
				set printer = (-P$argv[1])
				shift argv
			else
				echo "Usage: -P printer ..."
				echo "Type    lasergnu -help    for help."
				exit (1)
			endif
			goto top

                # use impress instead of tektronix language
                case -I:
	   		 set setterm="set term imagen"
#	   		 set setsize="set size 4,3"
	   		 set setsize="set size 9,6.5"
	   		 set LANG=""
			 shift argv
	   		 goto top

		case -?*:
			echo "I do not recognize option $argv[1]."
			echo "usage: lasergnu [-Pprinter] [-b] [-l] [-t title] [-f file] ['plot command']...."
			exit (1)

		default:
	          echo "$argv[1]"	>> $TMP
			set plot_command=1
			shift argv
			goto top

		endsw
	endif

# If input file is specified AND command line contains plot commands, then
#	do command line args first, then plot commands in input file.
if ($?input_file) then
	cat $input_file >> $TMP
endif
# The printer is whatever printer was last specified,
# or the default printer if none was specified.

set iflags = ($iflags $printer)

if ($LANG == -Ltektronix) set plot_args=($plot_args -p)

(echo $setterm; echo $setsize; cat $TMP) \
	   | gnutex $plot_args | /usr/local/bin/ipr $LANG \
	   $iflags -f gnutex \
	   -D"jobheader $print_banner" \
	   -D"program lasergnu"

cleanup:
rm $TMP