DataMuseum.dk

top - metrics - download

    Length: 1686 (0x696)
    Types: TextFile
    Names: »punkd.mf«

└─⟦52210d11f⟧ Bits:30007239 EUUGD2: TeX 3 1992-12
    └─⟦c319c2751⟧ »unix3.0/TeX3.0.tar.Z« 
        └─⟦036c765ac⟧ 
            └─⟦this⟧ »TeX3.0/MFcontrib/metafonts/punk/punkd.mf« 
└─⟦060c9c824⟧ Bits:30007080 DKUUG TeX 2/12/89
    └─⟦this⟧ »./tex82/MFcontrib/metafonts/punk/punkd.mf« 
└─⟦52210d11f⟧ Bits:30007239 EUUGD2: TeX 3 1992-12
    └─⟦63303ae94⟧ »unix3.14/TeX3.14.tar.Z« 
        └─⟦c58930e5c⟧ 
            └─⟦this⟧ »TeX3.14/MFcontrib/metafonts/punk/punkd.mf« 

TextFile

% Punk digits

beginpunkchar("0",9,.5,1);
z1=pp(.5w,h); z2=pp(u,.55h); z3=pp(.5w,0); z4=pp(w-u,.55h);
pd z1; draw z1{curl 2}..z2..z3..z4..z1; % bowl
endchar;

beginpunkchar("1",9,.3,1);
z1=pp(2u,.7h); z2=pp(.6w,h); z3=pp(.6w,0);
pd z1; pd z3; draw z1--z2--z3; % serif and stem
endchar;

beginpunkchar("2",9,1,1);
z1=pp(2u,.7h); z2=pp(.5w,h); z3=pp(w-u,.6h); z4=pp(u,0); z5=pp(w-2u,0);
pd z1; pd z5; draw z1..z2..z3..z4--z5; % stroke
endchar;

beginpunkchar("3",9,.5,.5);
z1=pp(2u,.7h); z2=pp(.5w,h); z3=pp(w-u,.5[y2,y4]);
z4=pp(.5w-u,.55h); z5=pp(w-u,.5[y4,y6]); z6=pp(.5w,0); z7=pp(1.5u,.2h);
pd z1; pd z7; draw z1..z2..z3..z4&z4..z5..z6..z7;	% arcs
endchar;

beginpunkchar("4",9,1,1);
z1=pp(w-u,.3h); z2=pp(u,.3h); z3=pp(2/3w,h); z4=pp(2/3w,0);
pd z1; pd z4; draw z1--z2--z3--z4; % stem and diagonals
endchar;

beginpunkchar("5",9,.5,.5);
z1=pp(w-2u,h); z2=pp(2u,h); z3=pp(u,.7h); z4=pp(w-u,.5[y3,y5]);
z5=pp(.5w,0); z6=pp(u,.2h);
pd z1; pd z6; draw z1--z2--z3..z4..z5..z6; % stroke
endchar;

beginpunkchar("6",9,1,1);
z1=pp(2/3w,h); z2=pp(u,.3h); z3=pp(.5w,0); z4=pp(w-u,.3h); z5=pp(.6w,.6h);
z6=pp z2; pd z1; pd z6; draw z1..z2..z3..z4..z5--z6; % stroke
endchar;

beginpunkchar("7",9,.5,1);
z1=pp(2u,h); z2=pp(w-.5u,h); z3=pp(.4w,0);
pd z1; pd z3; draw z1--z2&z2..z3{down}; % stroke
endchar;

beginpunkchar("8",9,.5,.5);
z1=pp(.5w,h); z2=pp(u,.5[y1,y3]); z3=pp(.5w,.6h); z4=pp(w-u,.5[y3,y5]);
z5=pp(.5w,0); z6=pp(u,.5[y5,y3]); z7=pp(w-u,.5[y1,y3]);
pd z1; draw z1{curl 8}..z2..z3..z4..z5..z6..z3..z7..z1; % stroke
endchar;

beginpunkchar("9",9,1,1);
z1=pp(1/3w,0); z2=pp(w-u,.7h); z3=pp(.5w,h); z4=pp(u,.7h); z5=pp(.5w,.4h);
pd z1; pd z5; draw z1..z2..z3..z4..z5; % stroke
endchar;