DataMuseum.dk

top - metrics - download

    Length: 1093 (0x445)
    Types: TextFile
    Names: »f.mf«

└─⟦060c9c824⟧ Bits:30007080 DKUUG TeX 2/12/89
    └─⟦this⟧ »./babel/greek/src/f.mf« 
└─⟦52210d11f⟧ Bits:30007239 EUUGD2: TeX 3 1992-12
    └─⟦23cd347d5⟧ »unix3.0/babel.tar.Z« 
        └─⟦2fb9f645a⟧ 
            └─⟦this⟧ »babel/greek/src/f.mf« 

TextFile

if unknown gen_sigma : readfrom("gen_sigma") fi

def dims = 10.5u#,x_height#,desc_depth# enddef;
def ital = 0 enddef;
def fit_params = 0,0 enddef;

def gen_letter =
  pickup fine.nib;
  lft x4r=w-rt x8r=hround .75u; y4r=y8r=.5h;
  x6r=.5[x4r,x8r]; bot y6r=-oo;
  numeric tilt; tilt:=min(2*otilt,.5);
  filldraw stroke gr_arc.e(6,7,8)(vair,stem,tilt) ;
  filldraw stroke gr_arc.e(4,5,6)(vair,.4[vair,stem],tilt) ;
  y2+.5stem=h+o; x2+.5stem=hround(x6-1.5u);
  pos2(stem,angle((z2-z4)xscaled 2)+90);
  filldraw circ_stroke z2e...{z4'e}z4e;
  pos10(stem,180); pos11(hair,180);
  y10-.5stem=-d-o; y11=.25h; x10=x11=x6;
  x9r=.5[x10r,x8r]; top y9r=h+o;
  filldraw stroke gr_arc.e(8,20,9)(vair,.4[vair,stem],.5tilt);
  filldraw circ_stroke z10e..z11e{up}..{-z9'e}z9e;
enddef;

cmchar "Lowercase phi";
beginchar("f",dims);
this_letter; penlabels(1,2,3,4,5,6,7,8,9,10,11,12,20,21); endchar;

if boolean barebones: picture savedpicture; endinput; fi

cmchar "Lowercase sigma followed by phi";
begindoublechar(oct"006",dims);
mid_sigma; middoublechar(dims); this_letter; endchar;

picture savedpicture;