DataMuseum.dk

top - metrics - download

    Length: 1980 (0x7bc)
    Types: TextFile
    Names: »tgrind«

└─⟦52210d11f⟧ Bits:30007239 EUUGD2: TeX 3 1992-12
    └─⟦6abfa5b66⟧ »utils/tgrind.tar.Z« 
        └─⟦02e344965⟧ 
            └─⟦this⟧ »tgrind« 

TextFile

#! /bin/csh
# Script to grind nice program listings using TeX.
#
# $Header: tgrind,v 1.2 88/07/05 05:16:32 van Exp $
#
# written Feb, 1985 by Van Jacobson, Lawrence Berkeley Laboratory (adapted
# from the 4.2bsd "vgrind" script).
#
# Since TeX output handling is site dependent, you'll have to edit this
# file to get output to your local typesetting device(s).  Our site uses
# the flags "-v" (versatec output), "-q" (qms output) and "-k" (keep dvi file)
# to route output.  Put something appropriate to your site at the "PUT OUTPUT
# HANDLING..." comment at the end of this script.  If you've already dealt
# with this in your local tex command, just change the -v/q/k (or whatever)
# cases in the first "switch" to set variable "texoptions" appropriately.
#
set b=/usr/local/lib/tfontedpr
set tex=/usr/local/tex
set options=
set texoptions=
set files=
set head=""
set format=""
set output=""
top:
if ($#argv > 0) then
    switch ($1:q)

    case -d:
	if ($#argv < 2) then
	    echo "tgrind: $1:q option must have argument"
	    goto done
	else
	    set options = ($options $1:q $2)
	    shift
	    shift
	    goto top
	endif
			
    case -f:
	set format="Y"
	set options = "$options $1:q"
	shift
	goto top

    case -h:
	if ($#argv < 2) then
	    echo "tgrind: $1:q option must have argument"
	    goto done
	else
	    set head="$2"
	    shift
	    shift
	    goto top
	endif

    case -P*:
	set output="$1"
	shift
	goto top

    case -*:
	set options = "$options $1:q"
	shift
	goto top

    default:
	set files = "$files $1:q"
	shift
	goto top
    endsw
endif

if ("$format" == "Y") then
	if ("$head" != "") then
		$b $options -h "$head" $files
	else
		$b $options $files
	endif

else
	onintr done

	if ("$head" != "") then
		$b $options -h "$head" $files >/tmp/$$.tex
	else
		$b $options $files >/tmp/$$.tex
	endif
	cd /tmp
	$tex $texoptions $$.tex >& /dev/null < /dev/null
	# PUT OUTPUT HANDLING COMMANDS HERE.
	lpr $output -d $$.dvi
done:
	rm -f $$.tex $$.log $$.dvi
endif